User:Wiljes/NFDI

NFDI consortia

How many accepted NFDI consortia are there?

SELECT (COUNT(DISTINCT(?p)) AS ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de," . }
}

Try it!

Give me all proposed NFDI consortia!

SELECT ?konsortiumLabel ?konsortium
WHERE {
   ?konsortium wdt:P31 wd:Q98270492 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" }
} ORDER BY ?konsortiumLabel

Try it!

Give me all accepted NFDI consortia!

SELECT ?konsortiumLabel ?konsortium
WHERE {
   ?konsortium wdt:P31 wd:Q98270496 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" }
} ORDER BY ?konsortiumLabel

Try it!

...+ more info, speaker, inception date and GEPRIS-ID!

SELECT  ?p ?pLabel ?pAltLabel ?pDescription ?speaker ?speakerLabel ?inception ?gepris ?geprisURL
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  OPTIONAL { ?p wdt:P4870 ?gepris }
  BIND (CONCAT("https://gepris.dfg.de/gepris/projekt/", ?gepris) AS ?geprisURL)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?inception) ASC(?pLabel)

Try it!

...with contact infos!

SELECT ?p ?pLabel ?gepris ?website ?email ?twitter ?mastodon ?linkedin ?zenodo ?github ?gitlab ?youtube WHERE {
  ?p wdt:P31 wd:Q98270496.
  OPTIONAL { ?p wdt:P571 ?inception. }
  OPTIONAL { ?p wdt:P488 ?speaker. }
  OPTIONAL { ?p wdt:P4870 ?gepris. }
  OPTIONAL { ?p wdt:P968 ?email. }
  OPTIONAL { ?p wdt:P856 ?website. }
  OPTIONAL { ?p wdt:P9934 ?zenodo. }
  OPTIONAL { ?p wdt:P4264 ?linkedin. }
  OPTIONAL { ?p wdt:P2002 ?twitter. }
  OPTIONAL { ?p wdt:P2037 ?github. }
  OPTIONAL { ?p wdt:P8827 ?gitlab. }
  OPTIONAL { ?p wdt:P4033 ?mastodon. }
  OPTIONAL { ?p wdt:P2397 ?youtube. }
  BIND(CONCAT("https://gepris.dfg.de/gepris/projekt/", ?gepris) AS ?geprisURL)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
ORDER BY (?pLabel)

Try it!

Also show applicant institution!

SELECT  ?p ?pLabel ?pAltLabel ?pDescription ?speaker ?speakerLabel ?applicant ?applicantLabel ?inception
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?applicant .
  ?statement pq:P3831 wd:Q54875338 .  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?inception) ASC(?pLabel)

Try it!

[IMPORTANT] Show all Consortia and all Affiliated Organisation including their role (applicant, co-applicant, participant)!

SELECT DISTINCT ?p ?pLabel ?affiliationTypeLabel ?w ?wLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

...only members of the Leibniz Association

SELECT DISTINCT ?p ?pLabel ?affiliationTypeLabel ?w ?wLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  ?w wdt:P463 wd:Q680090 .   # members od Leibniz association only
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

...as a Map

#defaultView:Map
SELECT DISTINCT ?p ?pLabel ?affiliationTypeLabel ?w ?wLabel ?geo
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  OPTIONAL {?w wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

...aggregated numbers of applicants, co-applicants and participants of the individual consortia

SELECT DISTINCT ?pLabel ?affiliationType ?affiliationTypeLabel (COUNT(DISTINCT(?w)) AS ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  #?statement ?affiliationType wd:Q105906738 .  # Show only co-applicants
  #?statement ?affiliationType wd:Q105906860 .  # Show only participants
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?affiliationType ?affiliationTypeLabel ?pLabel
ORDER BY ASC(?pLabel) DESC(?affiliationTypeLabel)

Try it!

...total numbers of applicants, co-applicants and participants of all consortia

SELECT DISTINCT ?affiliationTypeLabel (COUNT(DISTINCT(?w)) AS ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?affiliationTypeLabel

Try it!

Give me all accepted NFDI consortia that have a Wikipedia page!

(currentöy: none)

SELECT ?inception ?p ?pLabel ?pAltLabel ?pDescription ?wikipediaeintrag
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  OPTIONAL { ?p wdt:P571 ?inception }
  ?wikipediaeintrag schema:about ?p .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?inception) ASC(?pLabel)

Try it!

Give me all accepted NFDI consortia that have a zenodo Communities ID !

SELECT  ?p ?pLabel ?zenodoid
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p wdt:P9934 ?zenodoid .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel)

Try it!

How many (co-)applicants of accepted consortia are there?

SELECT (COUNT(?w) AS ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}

Try it!

Give me the total number of (co-)applicant institutions of accepted consortia!

SELECT (COUNT(DISTINCT(?w)) AS ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}

Try it!

Show all (Co-)Applicant Institutions as a Map!

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  OPTIONAL {?w wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Give me a list of all (co-)applicants and the consortia they are members of!

SELECT ?wLabel ?w ?pLabel ?p
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Show only Applicants and Co-Applicants!

SELECT  ?p ?pLabel ?affiliationTypeLabel ?w ?wLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  {?statement pq:P3831 wd:Q54875338} UNION {?statement pq:P3831 wd:Q105906738}
  OPTIONAL {?statement pq:P3831 ?affiliationType}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

Which Persons are working for accepted consortia?

SELECT  ?person ?personLabel ?p ?pLabel 
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?person wdt:P108 ?p . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?personLabel)

Try it!

Gib mir alle Konsortien mit den beteiligten Konsortialpartnern!

SELECT ?p ?pLabel ?w ?wLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?pLabel) ASC(?wLabel)

Try it!

Gib mir alle Konsortien, sortiert nach Anzahl der jeweils beteiligten Konsortialpartner!

SELECT ?p ?pLabel ?pDescription ?inception (COUNT(?w) AS ?number) 
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
    OPTIONAL { ?p wdt:P571 ?inception }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?p ?pLabel ?pDescription ?inception
ORDER BY DESC(?number)

Try it!

Give me the number of applicants, co-applicants and participants for each consortium!

SELECT  ?p ?pLabel ?affiliationTypeLabel (COUNT(?organisation) as ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?organisation .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?p ?pLabel ?affiliationType ?affiliationTypeLabel
ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel)

Try it!

Give me the total numbers of applicants, co-applicants and participants!

SELECT  ?affiliationTypeLabel (COUNT(DISTINCT ?organisation) as ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?organisation .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?affiliationType ?affiliationTypeLabel
ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel)

Try it!

Welche Städte haben die meisten Konsortialbeteiligungen?

SELECT ?aLabel (COUNT(DISTINCT(?p)) AS ?number) 
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  ?w wdt:P131* ?a .
  ?a  wdt:P31/wdt:P279* wd:Q515 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?a ?aLabel
ORDER BY DESC(?number) ASC(?aLabel)

Try it!

Give me the detailed data of the previous query!

SELECT DISTINCT ?aLabel ?a ?wLabel ?w ?pLabel ?p
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  ?w wdt:P131* ?a .
  ?a  wdt:P31/wdt:P279* wd:Q515 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
}
ORDER BY ASC(?aLabel) ASC(?wLabel) ASC(?pLabel)

Try it!

Aus welchen Bundesländern stammen die meisten Konsortialbeteiligungen?

SELECT ?aLabel (COUNT(*) AS ?number)
WHERE { 
  {
    SELECT ?a ?w ?p
    WHERE {  
      ?p wdt:P31 wd:Q98270496 . 
      ?p wdt:P1416 ?w .
      OPTIONAL {
      ?w wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY (?aLabel)
ORDER BY DESC(?number)

Try it!

Give me the detailed data of the previous query!

Achtung: evtl. Timeout! ggf. Noch mal starten.

SELECT ?aLabel ?wLabel ?pLabel
WHERE 
{  
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  OPTIONAL {
    ?w wdt:P131+ ?a .
    ?a  wdt:P31 wd:Q1221156 .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?aLabel) ASC(?wLabel) ASC(?pLabel)

Try it!

From which Bundesland come the most (co-)applicants?

SELECT ?aLabel (COUNT (DISTINCT ?p) AS ?number)
WHERE { 
  {
    SELECT ?a ?w ?p
    WHERE {  
      ?p wdt:P31 wd:Q98270496 . 
      ?p wdt:P1416 ?w .
      OPTIONAL {
      ?w wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?aLabel
ORDER BY DESC(?number)

Try it!

[Housecleaning] Show detailed data of previous query

To identify those (co-)applicants that are not attributed to a Bundesland.

SELECT ?a ?aLabel ?p ?pLabel ?w ?wLabel
WHERE { 
  {
    SELECT ?a ?w ?p
    WHERE {  
      ?p wdt:P31 wd:Q98270496 . 
      ?p wdt:P1416 ?w .
      OPTIONAL {
      ?w wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?aLabel) ASC(?pLanbel) ASC(?wLabel)

Try it!

...show as a bubble chart

#defaultView:BubbleChart
SELECT ?aLabel ?a (COUNT (DISTINCT ?p) AS ?number)
WHERE { 
  {
    SELECT ?a ?w ?p
    WHERE {  
      ?p wdt:P31 wd:Q98270496 . 
      ?p wdt:P1416 ?w .
      OPTIONAL {
      ?w wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?aLabel ?a
ORDER BY DESC(?number)

Try it!

[Housecleaning] Give me the detailed data of the previous query!

Achtung: evtl. Timeout! ggf. Noch mal starten.

SELECT DISTINCT ?aLabel ?wLabel ?pLabel
WHERE 
{  
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  OPTIONAL {
    ?w wdt:P131+ ?a .
    ?a  wdt:P31 wd:Q1221156 .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?aLabel) ASC(?wLabel) ASC(?pLabel)

Try it!

...show as a graph

#defaultView:Graph
SELECT ?a ?aLabel ?apicture ?p ?pLabel ?ppicture ("EC0000" AS ?rgb)
WHERE 
{  
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  OPTIONAL {
    ?w wdt:P131+ ?a .
    ?a  wdt:P31 wd:Q1221156 .
    ?a wdt:P41 ?apicture .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?aLabel) ASC(?wLabel) ASC(?pLabel)

Try it!

Welche Institutionen haben die meisten Konsortialbeteiligungen?

SELECT ?wLabel (COUNT(?p) AS ?number) ?w
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel
ORDER BY DESC(?number) ASC(?wLabel)

Try it!

As a Bubble-Chart

#defaultView:BubbleChart
SELECT ?w ?wLabel (COUNT(?p) AS ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel
ORDER BY DESC(?number) ASC(?wLabel)

Try it!

Gib mir alle als Konsortialpartner an Konsortien beteiligten Institutionen sowie die Konsortien, an denen diese beteiligt sind!

SELECT DISTINCT ?wLabel ?pLabel
WHERE 
{  
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?wLabel) ASC(?pLabel)

Try it!

[Housecleaning] Gib mir alle an Konsortien beteiligten Institutionen, die (noch) keine "Zuordnung zu einer Verwaltungseinheit" haben!

SELECT DISTINCT ?wLabel ?w
WHERE 
{  
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  FILTER NOT EXISTS {
    ?w wdt:P131 ?a .
    # ?a  wdt:P31 wd:Q1221156 .
  } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?wLabel)

Try it!

Show all participants that were added after the proposal!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel ?start
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  ?statement pq:P3831 ?affiliationType . 
  ?statement pq:P580 ?start .
  FILTER EXISTS { ?statement pq:P3831 wd:Q105906860 .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel) ASC(?affiliationTypeLabel) ASC(?pLabel)

Try it!

Anbindung Wirtschaft

Give me all members of DECHEMA!

SELECT ?instance ?instanceLabel ?instanceDescription
WHERE {
  ?instance wdt:P463 wd:Q896265 .
    SERVICE wikibase:label {bd:serviceParam wikibase:language "en,de"}
  } ORDER BY DESC(?instanceLabel)

Try it!

Gib mir alle (Co-)Applicants, gruppiert nach Rechtsform, z.B. eingetragenen Verein (e.V.)!

SELECT ?w ?wLabel ?p ?pLabel ?rechtsformLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  ?w wdt:P1454 ?rechtsform .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?rechtsformLabel) ASC(?wLabel) ASC(?pLabel)

Try it!

Gib mir alle Rechtsformen von NFDI-Beteiligten, sortiert nach Anzahl!

SELECT ?rechtsformLabel (COUNT(DISTINCT ?w) AS ?number)
WHERE 
{
  { ?w wdt:P463 wd:Q105757481 . } UNION 
  {
    ?p wdt:P31 wd:Q98270496 . 
    ?p wdt:P1416 ?w .
  }
  OPTIONAL {?w wdt:P1454 ?rechtsform .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?rechtsform ?rechtsformLabel
ORDER BY DESC(?number)

Try it!

Gib mir alle Wirtschaftsunternehmen, die direkt an NFDI beteiligt sind!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  {?w wdt:P31 wd:Q4830453} UNION {?w wdt:P31 wd:Q6881511} UNION {?w wdt:P31 wd:Q460178}
  BIND(IF(! Bound(?affiliationType), "NFDI-Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Gib mir alle Wirtschaftsunternehmen, die Mitglieder von Organisationen sind, die an NFDI beteiligt sind!

SELECT DISTINCT ?w1 ?w1Label ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  ?w1 wdt:P463 ?w .
  {?w1 wdt:P31 wd:Q4830453} UNION {?w1 wdt:P31 wd:Q6881511} UNION {?w1 wdt:P31 wd:Q460178}
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  BIND(IF(! Bound(?affiliationType), "NFDI-Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?w1Label) ASC(?wLabel)

Try it!

Persons in NFDI

Give me all persons who are working for NFDI!

(Comment: Data is not yet complete.)

SELECT ?p ?pLabel
WHERE 
{
  ?p wdt:P31 wd:Q5 .
  {?p wdt:P101 wd:Q61658497} UNION {?p wdt:P108 ?a; wdt:P31 wd:Q98270496}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de," . }
}

Try it!

Graphs

Give me all consortia and their fields of work! (as a Graph)

(Comment: Data is not yet complete.)

#defaultView:Graph
SELECT ?w ?wLabel  ?p ?pLabel ("EC0000" AS ?rgb)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P101 ?w .
  FILTER(?p != wd:Q96678462)
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Show the NFDI as an expandable graph!

Hint: Click on node to expand the graph!

#defaultView:Graph
SELECT ?p ?pLabel ?s ?sLabel
WHERE 
{
  ?s ?p ?o 
  FILTER(?s = wd:Q61658497 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
}

Try it!

Which organisations are (co-)applicants or participants in which NFDI consortia? (Graph)

#defaultView:Graph
SELECT ?w ?wLabel ?wpicture ?p ?pLabel ?ppicture ("EC0000" AS ?rgb)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  FILTER NOT EXISTS {?w  wdt:P31 wd:Q98270496 }  # do nit display consortia associations to Base4NFDI
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...with circular nodes.

#defaultView:Graph
SELECT ?p ?pLabel ?rgb ?number2  ?w ?wLabel (5 AS ?number1) 
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  BIND(10 AS ?number2)
  BIND("EC0000" AS ?rgb)
  BIND("hallo" AS ?pLabel)
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

... participants only

(Anmerkung: Daten noch unvollständig)

#defaultView:Graph
SELECT ?w ?wLabel ?wpicture ?p ?pLabel ?ppicture ("EC0000" AS ?rgb)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P710 ?w .
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

... (co-)applicants and participants

#defaultView:Graph
SELECT ?w ?wLabel ?wpicture ?p ?pLabel ?ppicture ("EC0000" AS ?rgb)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  {{?p wdt:P1416 ?w} UNION {?p wdt:P710 ?w}}
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Members of the Association (e.V.)

Give me all members of the NFDI association!

SELECT DISTINCT ?w ?wLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...with additional info

SELECT DISTINCT ?w ?wLabel (SAMPLE(?directorLabel) AS ?directorLabel) (SAMPLE(?website) AS ?website) (SAMPLE(?email) AS ?email) (SAMPLE(?foundingdate) AS ?founded) (SAMPLE(?ror) AS ?ror) (SAMPLE(?logo) AS ?logo) (SAMPLE(?zenodo) AS ?zenodo) (SAMPLE(?linkedin) AS ?linkedin) (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?github) AS ?github) (SAMPLE(?gitlab) AS ?gitlab) (SAMPLE(?mastodon) AS ?mastodon) (SAMPLE(?youtube) AS ?youtube)     
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL { ?w wdt:P6782 ?ror . }
  OPTIONAL { ?w wdt:P968 ?email. }
  OPTIONAL { ?w wdt:P856 ?website. }
  OPTIONAL { ?w wdt:P9934 ?zenodo. }
  OPTIONAL { ?w wdt:P4264 ?linkedin. }
  OPTIONAL { ?w wdt:P2002 ?twitter. }
  OPTIONAL { ?w wdt:P2037 ?github. }
  OPTIONAL { ?w wdt:P8827 ?gitlab. }
  OPTIONAL { ?w wdt:P4033 ?mastodon. }
  OPTIONAL { ?w wdt:P2397 ?youtube. }
  OPTIONAL { ?w wdt:P571 ?foundingdate. }
  OPTIONAL { ?w  wdt:P1647*/wdt:P1037  ?director . ?director rdfs:label ?directorLabel . }
  OPTIONAL { ?w wdt:P154 ?logo . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel ORDER BY ASC(?wLabel)

Try it!

...for Excel-Import with NFDI-Wiki

SELECT DISTINCT ?w ?wLabel ?website
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {?w wdt:P856 ?website .}
  OPTIONAL {?w wdt:P2002 ?twitteraccount .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...by number of people

#defaultView:BubbleChart
SELECT DISTINCT ?w ?wLabel ?number
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {?w wdt:P1128 ?number .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY DESC(?number)

Try it!

...by founding date

SELECT DISTINCT  ?foundingdate ?w ?wLabel ?wDescription
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {?w wdt:P571 ?foundingdate .}
  OPTIONAL { ?w wdt:P154 ?logo . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?foundingdate)

Try it!

...by founding date (as a timeline)

#defaultView:Timeline
SELECT DISTINCT ?wLabel ?foundingdate ?logo
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {?w wdt:P571 ?foundingdate .}
  OPTIONAL { ?w wdt:P154 ?logo . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY DESC(?foundingdate)

Try it!

...HAWs onlys

SELECT DISTINCT ?w ?wLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31 wd:Q1365560 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Give me all members that are also (co-)participants!

SELECT DISTINCT ?w ?wLabel ?p ?pLabel
WHERE 
{
    ?w wdt:P463 wd:Q105757481 .
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Give me all consortia members that are not yet members of the association!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
    ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  ?statement pq:P3831 ?affiliationType .
  FILTER NOT EXISTS {?w wdt:P463 wd:Q105757481 .} 
  #FILTER NOT EXISTS {?w wdt:P463+ wd:Q105757481 .} 
  #FILTER NOT EXISTS {?w wdt:P361/wdt:P463 wd:Q105757481 .} 
  #FILTER NOT EXISTS {?w wdt:P749/wdt:P463 wd:Q105757481 .} 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY DESC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

Give me all members that are not (co-)applicants!

SELECT DISTINCT ?w ?wLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  FILTER NOT EXISTS {
    ?p wdt:P31 wd:Q98270496 . 
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    {?statement pq:P3831 wd:Q54875338} UNION {?statement pq:P3831 wd:Q105906738}
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

[Housecleaning] Members of NFDI

This query shows organisations that have incorrectly been set as members of National Research Data Infrastructure (Q61658497) instead of German National Research Data Infrastructure (NFDI) e.V. (Q105757481) List should be empty.

SELECT DISTINCT ?wLabel ?w
WHERE 
{
  ?w wdt:P463 wd:Q61658497 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

... in a timeline orderd by founding dates

#defaultView:Timeline
SELECT DISTINCT ?w ?wLabel ?wDate
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P571 ?wDate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wDate)

Try it!

Give me all logos of members of NFDI e.V.!

#defaultView:ImageGrid
SELECT DISTINCT ?logo
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P154 ?logo .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}

Try it!

Give me the most common Rechtsform of NFDI members!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {?w wdt:P1454 ?aggregate .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

Give me the most common Classes of NFDI members!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(DISTINCT ?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31 ?aggregate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

...incl. parent classes

SELECT DISTINCT ?aggregate ?aggregateLabel (count(DISTINCT ?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31/wdt:P279* ?aggregate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

...as a Graph

#defaultView:Graph
SELECT ?w ?wLabel ?p ?pLabel ("EC0000" AS ?rgb)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31 ?p .
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}

Try it!

Give me all members who are universities!

SELECT DISTINCT ?w ?wLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31/wdt:P279* wd:Q3918 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} 
ORDER BY DESC(?wLabel)

Try it!

Give me all members of NFDI e.V. with a ROR-ID!

SELECT DISTINCT ?wLabel ?w ?ror
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P6782 ?ror .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Show all members on a map!

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
   ?w wdt:P463 wd:Q105757481 .
   {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .} UNION {?w wdt:P276 ?ort . ?ort wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

How many members come from the Bundesländer?

SELECT ?aLabel (COUNT (DISTINCT ?p) AS ?number)
WHERE { 
  {
    SELECT ?a ?p
    WHERE {  
      ?p wdt:P463 wd:Q105757481 . 
      OPTIONAL {
      ?p wdt:P159/wdt:P131*|wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?aLabel
ORDER BY DESC(?number)

Try it!

[Housecleaning] Show detailed info of previous query.

To identify those members that are not attributed to a Bundesland

SELECT DISTINCT ?a ?aLabel ?p ?pLabel
WHERE { 
  {
    SELECT ?a ?p
    WHERE {  
      ?p wdt:P463 wd:Q105757481 . 
      OPTIONAL {
      ?p wdt:P159/wdt:P131*|wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}
ORDER BY ASC(?aLabel) ASC(?pLabel)

Try it!

[Housecleaning] Show me all members from outside Germany (or NULL)!

List should be empty (?)

SELECT ?a ?aLabel ?p ?pLabel
WHERE { 
  {
    SELECT ?a ?p
    WHERE {  
      ?p wdt:P463 wd:Q105757481 . 
      FILTER NOT EXISTS {?p wdt:P17 wd:Q183 .}
      OPTIONAL {
      ?p wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}
ORDER BY ASC(?aLabel) ASC(?pLabel)

Try it!

Members of members of NFDI

Give me the organisations that NFDI members are members of, ordered by number of members!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P463 ?aggregate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

...as a graph

#defaultView:Graph
SELECT DISTINCT ?p ?pLabel ?w ?wLabel ("EC0000" AS ?rgb)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P463 ?p .
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}

Try it!

...as a tree

#defaultView:Tree
SELECT DISTINCT ?p ?pLabel ?w ?wLabel 
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P463 ?p .
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel)

Try it!

Give me the upper organisations that NFDI members belong to, ordered by number members!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P749 ?aggregate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

Give me all members of members of NFDI, ordered by number of members!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w ^wdt:P463 ?aggregate .
  FILTER NOT EXISTS {?aggregate wdt:P31 wd:Q5}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

Give me all members of members of NFDI!

SELECT DISTINCT ?item ?itemLabel ?linkTo ?linkToLabel {
  ?item wdt:P463 wd:Q105757481 .
  ?item ^wdt:P463 ?linkTo .
  FILTER NOT EXISTS {?linkTo wdt:P31 wd:Q5}
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en" }
} ORDER BY ASC(?itemLabel) ASC(?linkToLabel)

Try it!

...only those that are companies (show as tree)!

#defaultView:Tree
SELECT DISTINCT ?item ?itemLabel ?itemPic ?linkTo ?linkToLabel ?linkToPic
{
  ?item wdt:P463 wd:Q105757481 .
  ?item ^wdt:P463 ?linkTo .
  {?linkTo wdt:P31/wdt:P279* wd:Q4830453 } UNION {?linkTo wdt:P31/wdt:P279* wd:Q6881511}
  FILTER NOT EXISTS {?linkTo wdt:P31 wd:Q5}
  FILTER NOT EXISTS {?linkTo wdt:P31/wdt:P279* wd:Q2085381}
  OPTIONAL { ?item wdt:P154 ?itemPic }
  OPTIONAL { ?linkTo wdt:P154 ?linkToPic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en" }
} ORDER BY ASC(?itemLabel) ASC(?linkToLabel)

Try it!

...as a Graph

#defaultView:Graph
SELECT ?item ?itemLabel ?linkTo ?linkToLabel {
  ?item wdt:P463 wd:Q105757481
  OPTIONAL { ?item wdt:P463 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en" }
} ORDER BY ASC(?itemLabel)

Try it!

Give me all organizations that NFDI members are also members of

SELECT ?item ?itemLabel ?linkTo ?linkToLabel {
  ?item wdt:P463 wd:Q105757481
  OPTIONAL { ?item wdt:P463 ?linkTo}
  ?item wdt:P31/wdt:P279 wd:Q43229 .
  ?linkTo wdt:P31/wdt:P279 wd:Q43229 .
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de" }
} ORDER BY ASC(?itemLabel) ASC(?linkToLabel)

Try it!

Give me all organzations that are members of NFDI-organzations!

SELECT DISTINCT ?w1 ?w1Label ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  ?w1 wdt:P463 ?w .
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  FILTER NOT EXISTS {?w1 wdt:P31 wd:Q5}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?w1Label) ASC(?wLabel)

Try it!

DFN e.V.

Give me all members of DFN e.V.!

SELECT DISTINCT ?wLabel ?w
WHERE 
{
  ?w wdt:P463 wd:Q2514863 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Which (co-)applicant institutions are members of DFN?

SELECT DISTINCT ?wLabel ?w
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  ?w wdt:P463 wd:Q2514863 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Which (co-)applicant institutions are NOT members of DFN?

SELECT DISTINCT ?wLabel ?w
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  FILTER NOT EXISTS {?w wdt:P463 wd:Q2514863 .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Which members of NFDI e.V. are also members of DFN e.V.?

SELECT DISTINCT ?pLabel ?p
WHERE 
{
  ?p wdt:P463 wd:Q105757481 .
  {?p wdt:P463 wd:Q2514863} UNION {?p wdt:P1416 wd:Q2514863}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

TMF – Technologie- und Methodenplattform für die vernetzte medizinische Forschung e.V.

Give me all members of TMF e.V.!

(Comment: Data is not yet complete.)

SELECT DISTINCT ?wLabel ?w
WHERE 
{
  ?w wdt:P463 wd:Q1718834 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Allianz-Initiative in der NFDI

Gib mir alle Mitgliedersorganisationen der Allianz-Initiative!

SELECT DISTINCT ?verbund ?verbundLabel
WHERE 
{
  ?verbund wdt:P463 wd:Q1783362 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?verbundLabel)

Try it!

Gib mir alle Mitgliedersorganisationen der Allianz-Initiative und die Anzahl ihrer Mitglieder!

SELECT DISTINCT ?verbund ?verbundLabel (count(DISTINCT ?organisation) AS ?mitgliederzahl)
WHERE 
{
  ?verbund wdt:P463 wd:Q1783362 .
  {
    {?organisation wdt:P137* ?verbund} 
    UNION {?organisation wdt:P463+ ?verbund}
  }
  ?organisation wdt:P31/wdt:P279* wd:Q43229 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?verbund ?verbundLabel
ORDER BY DESC(?mitgliederzahl) ASC(?verbundLabel)

Try it!

Gib mir alle Unter-Organisationen der Allianz-Initiative! (außer Personen)

SELECT DISTINCT ?verbund ?verbundLabel ?organisation ?organisationLabel
WHERE 
{
  ?verbund wdt:P463 wd:Q1783362 .
  {
    {?organisation wdt:P137* ?verbund} 
    UNION {?organisation wdt:P463+ ?verbund}
  }
  ?organisation wdt:P31/wdt:P279* wd:Q43229 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
}
ORDER BY ASC(?verbundLabel) ASC(?organisationLabel)

Try it!

Welche Mitglieder der Allianz-Initiative sind an welchen NFDI-Konsortien beteiligt?

SELECT DISTINCT ?verbund ?verbundLabel ?organisation ?organisationLabel ?consortium ?consortiumLabel
WHERE 
{
  ?consortium wdt:P31 wd:Q98270496 . 
  ?consortium wdt:P1416 ?organisation .
  {
    {?organisation wdt:P137* ?verbund} 
    UNION {?organisation wdt:P463+ ?verbund}
  }
  ?verbund wdt:P463 wd:Q1783362 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?verbundLabel) ASC(?organisationLabel) ASC(?consortiumLabel)

Try it!

... as a Graph

#defaultView:Graph
SELECT  ?consortium ?consortiumLabel ?verbund ?verbundLabel  ("EC0000" AS ?rgb)
WHERE 
{
  ?consortium wdt:P31 wd:Q98270496 . 
  ?consortium wdt:P1416 ?organisation .
  {
    {?organisation wdt:P137* ?verbund} 
    UNION {?organisation wdt:P463+ ?verbund}
  }
  ?verbund wdt:P463 wd:Q1783362 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?verbundLabel) ASC(?organisationLabel) ASC(?consortiumLabel)

Try it!

Social Media

Give me all accepted NFDI consortia that have a Twitter-Account, ordered by number of followers!

SELECT  ?p ?pLabel ?twitteraccount ?follower
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  OPTIONAL { ?p wdt:P8687 ?follower }
  ?p wdt:P2002 ?twitteraccount .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY DESC(?follower)

Try it!

Give me all members of NFDI e.V. that have a Twitter account, ordered by number of followers!

SELECT  ?p ?pLabel ?twitteraccount ?follower
WHERE 
{
  ?p wdt:P463 wd:Q105757481 .
  OPTIONAL { ?p wdt:P8687 ?follower }
  ?p wdt:P2002 ?twitteraccount .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY DESC(?follower)

Try it!

Persons

Give me all persons who work for NFDI!

SELECT DISTINCT ?person ?personLabel ?pic ?p ?pLabel  WHERE {
  {?person wdt:P108 ?p . 
   ?p wdt:P31 wd:Q98270496 .} UNION {?person wdt:P108 wd:Q105757481}
  OPTIONAL { ?person wdt:P18 ?pic }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" }
} ORDER BY ?personLabel ?pLabel

Try it!

Data for Gephi-Visualization of Consortia and their contributing organizations

Nodes (basic)

(Konsortien und Konsortialbeteiligte)

SELECT DISTINCT (?node AS ?Id) ?Label
WHERE {
  {
    ?node wdt:P31 wd:Q98270496 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 . 
    ?p wdt:P1416 ?node .  
  }
  ?node rdfs:label ?Label .
  FILTER (lang(?Label) = 'de')
} ORDER BY ASC(?nodeLabel)

Try it!

...(advanced)

(Konsortien und Konsortialbeteiligte)

SELECT DISTINCT (?node AS ?Id) ?Label ?Weight
WHERE {
  {
    ?node wdt:P31 wd:Q98270496 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 . 
    ?p wdt:P1416 ?node .  
  }
  OPTIONAL { FILTER (EXISTS { ?node wdt:P31 wd:Q98270496 })
      BIND("2" AS ?Weight)
  } 
  OPTIONAL { FILTER (NOT EXISTS { ?node wdt:P31 wd:Q98270496 })
      BIND("1" AS ?Weight)
  } 
  ?node rdfs:label ?Label .
  FILTER (lang(?Label) = 'de')
} ORDER BY ASC(?nodeLabel)

Try it!

Edges (basic)

SELECT DISTINCT (?p as ?Source) (?w AS ?Target)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
}

Try it!

... (advanced)

SELECT DISTINCT (?w as $Source) (?p AS $Target) ("Directed" AS ?Type) (?affiliationTypeLabel AS ?Label) ?Weight
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  OPTIONAL { 
    ?statement pq:P3831 ?affiliationType . 
    ?affiliationType rdfs:label ?affiliationTypeLabel 
    OPTIONAL { FILTER (?affiliationTypeLabel = "Beteiligter"@de)
      BIND("1" AS ?Weight)
    } 
    OPTIONAL { FILTER (?affiliationTypeLabel = "Mitantragsteller"@de)
      BIND("2" AS ?Weight)
    } 
    OPTIONAL { FILTER (?affiliationTypeLabel = "Bewerber"@de)
      BIND("3" AS ?Weight)
    } 
  }  

  FILTER (lang(?affiliationTypeLabel) = 'de')
} ORDER BY ASC(?affiliationTypeLabel)

Try it!

Adjacency

SELECT DISTINCT ?wLabel ?pLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  OPTIONAL { ?w wdt:P154 ?wpicture }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Data for Gephi visualization of consortia and their fields of work

Nodes

SELECT DISTINCT (?node AS ?Id) ?Label ?Weight
WHERE 
{
  { 
    ?node wdt:P31 wd:Q98270496 .
  } UNION { 
    ?p wdt:P31 wd:Q98270496 .
    ?p wdt:P101 ?node . 
  }
  FILTER(?node != wd:Q96678462)
  ?node rdfs:label ?Label .
  OPTIONAL { FILTER (EXISTS { ?node wdt:P31 wd:Q98270496 })
      BIND("2" AS ?Weight)
  } 
  OPTIONAL { FILTER (NOT EXISTS { ?node wdt:P31 wd:Q98270496 })
      BIND("1" AS ?Weight)
  } 
  FILTER (lang(?Label) = 'de')
} ORDER BY ASC(?nodeLabel)

Try it!

Edges

SELECT DISTINCT (?p as ?Source) (?w AS ?Target) ("Undirected" AS ?Type)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P101 ?w .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}

Try it!

Overview

Statistics

SELECT (COUNT(DISTINCT(?consortium)) AS ?consortia) (COUNT(DISTINCT(?section)) AS ?sections) (COUNT(DISTINCT(?member)) AS ?members) (COUNT(DISTINCT(?applicant)) AS ?applicants)
WHERE 
{
  SELECT ?consortium ?member ?section ?applicant
  WHERE {
    ?consortium wdt:P31 wd:Q98270496 . 
    { 
      SELECT ?member ?section ?applicant
        WHERE {
        ?member wdt:P463 wd:Q105757481 .
    { 
      SELECT ?section ?applicant
        WHERE {
        ?section wdt:P31 wd:Q111582288 .
    { 
      SELECT (?organisation AS ?applicant)
        WHERE {
          ?p wdt:P31 wd:Q98270496 .
          ?p p:P1416 ?statement .
          ?statement ps:P1416 ?organisation .
          ?statement pq:P3831 wd:Q54875338 . 
        }
     }
        }
     }
        }
     }
  }
}

Try it!

Give me all organizations that contribute to NFDI!

SELECT DISTINCT  ?w ?wLabel
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  OPTIONAL {?w wdt:P4871 ?wGeprisID} 
  OPTIONAL {?w wdt:P6782 ?wRORID} 
  FILTER NOT EXISTS {?w  wdt:P31 wd:Q98270496 }  # do nit display consortia associations to Base4NFDI
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Give me all organizations that contribute to NFDI & their respective roles! [IMPORTANT]

SELECT DISTINCT ?wGeprisID  ?wRORID ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  OPTIONAL {?w wdt:P4871 ?wGeprisID} 
  OPTIONAL {?w wdt:P6782 ?wRORID} 
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...also with classes, including parent classes!

SELECT DISTINCT ?class ?classLabel ?wGeprisID  ?wRORID ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
  {
    SELECT DISTINCT ?class ?wGeprisID  ?wRORID ?w ?affiliationType ?p WHERE {  
      {
        ?w wdt:P463 wd:Q105757481 .
        ?w wdt:P31/wdt:P279* ?class .
      } UNION {
        ?p wdt:P31 wd:Q98270496 .
        ?p p:P1416 ?statement .
        ?statement ps:P1416 ?w .
        ?w wdt:P31/wdt:P279* ?class .
        OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
      }
    }
  }
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
} ORDER BY ASC(?classLabel) ASC(?wLabel)

Try it!

...as a Map

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .} UNION {?w wdt:P361+ ?parentOrganization . ?parentOrganization wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...as a Map and only from Schleswig-Holstein

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
    ?w wdt:P131+ ?bundesland . 
    ?bundesland  wdt:P31 wd:Q1221156 .
     OPTIONAL { ?w wdt:P625 ?geo }
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    ?w wdt:P131+ ?bundesland . 
    ?bundesland  wdt:P31 wd:Q1221156 .
    OPTIONAL { ?w wdt:P625 ?geo }
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  FILTER (?bundesland = wd:Q1194)
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...the same but shorter Code

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?w .
  }
  {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .} UNION {?w wdt:P361+ ?parentOrganization . ?parentOrganization wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...maximum of one dot per member

#defaultView:Map
SELECT DISTINCT ?w ?wLabel (SAMPLE(?geo) AS ?geo) 
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?w .
  }
  {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .} UNION {?w wdt:P361+ ?parentOrganization . ?parentOrganization wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel 
ORDER BY ASC(?wLabel)

Try it!

...only those from NRW

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
  }
  {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
  FILTER EXISTS { ?w wdt:P131+ wd:Q1198 }
}

Try it!

...only those from Berlin or Brandenburg

#defaultView:Map
#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
  }
  {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
  FILTER EXISTS {{ ?w wdt:P131+ wd:Q64 } UNION { ?w wdt:P131+ wd:Q1208}}
}

Try it!

..Libraries only

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  ?w wdt:P31/wdt:P279* wd:Q7075 . 
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

..HAWs only

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  ?w wdt:P31 wd:Q1365560 .
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...like the previous, but with additional "part of" to also capture independent partcipants

ändert aber nichts, d.h. bringt nichts neues.

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  {{?w wdt:P31 wd:Q1365560} UNION {?w wdt:P361+ ?x . ?x wdt:P31 wd:Q1365560.}}
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...applicants only

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
     ?w wdt:P463 wd:XXXQ105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
    ?statement pq:P3831 wd:Q54875338 .
  }
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...(co-)applicants only

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
     ?w wdt:P463 wd:XXXQ105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
    { ?statement pq:P3831 wd:Q54875338 } UNION { ?statement pq:P3831 wd:Q105906738 }
  }
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...(co-)applicants + participants only

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
     ?w wdt:P463 wd:XXXQ105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
    { ?statement pq:P3831 wd:Q54875338 } UNION { ?statement pq:P3831 wd:Q105906738 } UNION { ?statement pq:P3831 wd:Q105906860 }
  }
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...HAWs only!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
    ?w wdt:P31 wd:Q1365560 .
    BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

...as a map!

#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  {?w wdt:P625 ?geo} UNION {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

Member Organisations

SELECT DISTINCT ?w ?wLabel ?bundeslandLabel ?rechtsformLabel (SAMPLE(?leitungname) AS ?leitungname) (SAMPLE(?website) AS ?website)  ?email ?telefon (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?facebook) AS ?facebook) ?rorid ?lobbyregister (SAMPLE(?beschaeftigte) AS ?beschaeftigte) (SAMPLE(?gruendung) AS ?gruendung)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {?w wdt:P10301 ?lobbyregister }
  OPTIONAL {?w wdt:P856 ?website .}
  OPTIONAL {?w wdt:P2002 ?twitter .}
  OPTIONAL {?w wdt:P2769 ?budget .}
  OPTIONAL {?w wdt:P6782 ?rorid .}
  OPTIONAL {?w wdt:P9934 ?zenodoid }
  OPTIONAL {?w wdt:P2013 ?facebook }
  OPTIONAL {?w wdt:P1329 ?telefon }
  OPTIONAL {?w wdt:P571 ?gruendung }
  OPTIONAL {?w wdt:P1128 ?beschaeftigte }
  OPTIONAL {?w wdt:P1454 ?rechtsform}
  OPTIONAL {?w wdt:P968 ?email}
  OPTIONAL {?w wdt:P11647*/wdt:P1037 ?leitung . ?leitung rdfs:label ?leitungname .}
  OPTIONAL {
      ?w wdt:P131+ ?bundesland .
      ?bundesland  wdt:P31 wd:Q1221156 .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
} GROUP BY ?w ?wLabel ?wAltLabel ?wDescription ?bundeslandLabel ?rechtsformLabel ?telefon ?rorid ?lobbyregister ?email
ORDER BY ASC(?wLabel)

Try it!

(Co-)Applicans and Participants of Consortia

SELECT DISTINCT ?w ?wLabel ?bundeslandLabel ?rechtsformLabel (SAMPLE(?leitungname) AS ?leitungname) (SAMPLE(?website) AS ?website)  ?email ?telefon (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?facebook) AS ?facebook) ?rorid ?lobbyregister (SAMPLE(?beschaeftigte) AS ?beschaeftigte) (SAMPLE(?gruendung) AS ?gruendung)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
  ?p wdt:P1416 ?w .
  OPTIONAL {?w wdt:P10301 ?lobbyregister }
  OPTIONAL {?w wdt:P856 ?website .}
  OPTIONAL {?w wdt:P2002 ?twitter .}
  OPTIONAL {?w wdt:P2769 ?budget .}
  OPTIONAL {?w wdt:P6782 ?rorid .}
  OPTIONAL {?w wdt:P9934 ?zenodoid }
  OPTIONAL {?w wdt:P2013 ?facebook }
  OPTIONAL {?w wdt:P1329 ?telefon }
  OPTIONAL {?w wdt:P571 ?gruendung }
  OPTIONAL {?w wdt:P1128 ?beschaeftigte }
  OPTIONAL {?w wdt:P1454 ?rechtsform}
  OPTIONAL {?w wdt:P968 ?email}
  OPTIONAL {?w wdt:P11647*/wdt:P1037 ?leitung . ?leitung rdfs:label ?leitungname .}
  OPTIONAL {
      ?w wdt:P131+ ?bundesland .
      ?bundesland  wdt:P31 wd:Q1221156 .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
} GROUP BY ?w ?wLabel ?wAltLabel ?wDescription ?bundeslandLabel ?rechtsformLabel ?telefon ?rorid ?lobbyregister ?email
ORDER BY ASC(?wLabel)

Try it!

Consortia

SELECT DISTINCT ?w ?wLabel ?wAltLabel ?wDescription ?speakerLabel ?applicantLabel (SAMPLE(?website) AS ?website)  ?email ?phone (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?facebook) AS ?facebook) ?zenodoid (SAMPLE(?inception) AS ?inception)
WHERE 
{
  ?w wdt:P31 wd:Q98270496 .
  OPTIONAL {
    ?w p:P1416 ?statement .
    ?statement ps:P1416 ?applicant .
    ?statement pq:P3831 wd:Q54875338 .
  } 
  OPTIONAL {?w wdt:P10301 ?lobbyregister }
  OPTIONAL {?w wdt:P856 ?website .}
  OPTIONAL {?w wdt:P2002 ?twitter .}
  OPTIONAL {?w wdt:P2769 ?budget .}
  OPTIONAL {?w wdt:P6782 ?rorid .}
  OPTIONAL {?w wdt:P9934 ?zenodoid }
  OPTIONAL {?w wdt:P2013 ?facebook }
  OPTIONAL {?w wdt:P1329 ?phone }
  OPTIONAL {?w wdt:P968 ?email}
  OPTIONAL {?w wdt:P571 ?inception }
  OPTIONAL {?w wdt:P1128 ?beschaeftigte }
  OPTIONAL {?w wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
} GROUP BY ?w ?wLabel ?wAltLabel ?wDescription ?phone ?zenodoid ?email ?speakerLabel ?applicantLabel
ORDER BY ASC(?wLabel)

Try it!

Sections

SELECT DISTINCT ?w ?wLabel ?wAltLabel ?wDescription ?speakerLabel  (SAMPLE(?website) AS ?website)  ?email ?telefon (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?facebook) AS ?facebook) ?zenodoid (SAMPLE(?inception) AS ?inception)
WHERE 
{
  ?w wdt:P31 wd:Q111582288 .
  OPTIONAL {?w wdt:P10301 ?lobbyregister }
  OPTIONAL {?w wdt:P856 ?website .}
  OPTIONAL {?w wdt:P2002 ?twitter .}
  OPTIONAL {?w wdt:P2769 ?budget .}
  OPTIONAL {?w wdt:P6782 ?rorid .}
  OPTIONAL {?w wdt:P9934 ?zenodoid }
  OPTIONAL {?w wdt:P2013 ?facebook }
  OPTIONAL {?w wdt:P1329 ?telefon }
  OPTIONAL {?w wdt:P968 ?email}
  OPTIONAL {?w wdt:P571 ?inception }
  OPTIONAL {?w wdt:P1128 ?beschaeftigte }
  OPTIONAL {?w wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
} GROUP BY ?w ?wLabel ?wAltLabel ?wDescription ?telefon ?zenodoid ?email ?speakerLabel
ORDER BY ASC(?wLabel)

Try it!

Lobbyregister

Vereinsmitglieder und Konsortialbeteiligte mit Eintrag im Lobbyregister

SELECT DISTINCT ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel ?lobby
WHERE 
{
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  ?w wdt:P10301 ?lobby .
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

OpenStreetmap / UMap

Members of the Association

SELECT DISTINCT ?wLabel (SAMPLE(?geo) AS ?geo)
WHERE 
{
   ?w wdt:P463 wd:Q105757481 .
   {?w wdt:P625 ?geo} UNION {?w wdt:P276 ?ort . ?ort wdt:P625 ?geo .} UNION 
   {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION 
   {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?wLabel
ORDER BY ASC(?wLabel)

Try it!

All NFDI associated organisations

sace as csv for direct import in umap. Before that: change header column "placeLabel" to "name" and "placeDescription" to "description"

SELECT DISTINCT ?placeLabel ?placeDescription ?lat ?long {
    {
     ?place wdt:P463 wd:Q105757481 .
   } UNION {
     ?p wdt:P31 wd:Q98270496 .
     ?p wdt:P1416 ?place .
   } 
   ?place p:P625 ?coords_sample .
  {
    SELECT (SAMPLE(?coords_stmt) AS ?coords_sample) {
      {
        ?place wdt:P463 wd:Q105757481 .
      } UNION {
        ?p wdt:P31 wd:Q98270496 .
        ?p wdt:P1416 ?place .
      }
      ?place p:P625 ?coords_stmt .
    } GROUP BY ?place
  }
  ?coords_sample ps:P625 ?coords;
                 psv:P625 [
                   wikibase:geoLatitude ?lat;
                   wikibase:geoLongitude ?long
                 ] .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
ORDER BY ?placeLabel

Try it!

Show Members and Applcants as Map

#defaultView:Map
SELECT DISTINCT ?wLabel (SAMPLE(?geo) AS ?geo) ?rgb ?layer
WHERE 
{
   {
   ?w wdt:P463 wd:Q105757481 .
   {?w wdt:P625 ?geo} UNION {?w wdt:P276 ?ort . ?ort wdt:P625 ?geo .} UNION 
   {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION 
   {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}
   } UNION {
     ?p wdt:P31 wd:Q98270496 . 
     ?p wdt:P1416 ?w .
     ?w wdt:P625 ?geo .
   }
   BIND(
    IF(bound(?p), "Member",
    IF(!bound(?p), "Applicant",
    "other"))
    AS ?layer).
    BIND(
    IF(bound(?p), "000000",
    IF(!bound(?p), "DE1A3B",
    "other"))
    AS ?rgb).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?wLabel ?layer ?rgb
ORDER BY ASC(?wLabel)

Try it!

[Housecleaning] Members Geolocation

SELECT DISTINCT ?w ?wLabel (SAMPLE(?geo) AS ?geo)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  OPTIONAL {
     {?w wdt:P625 ?geo} UNION {?w wdt:P276 ?ort . ?ort wdt:P625 ?geo .} UNION 
     {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION 
     {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel
ORDER BY ASC(?wLabel)

Try it!

[Housecleaning] (Co-)Applicants Geolocation

SELECT DISTINCT ?w ?wLabel (SAMPLE(?geo) AS ?geo)
WHERE 
{
     ?p wdt:P31 wd:Q98270496 . 
     ?p wdt:P1416 ?w .
       OPTIONAL {
     {?w wdt:P625 ?geo} UNION {?w wdt:P276 ?ort . ?ort wdt:P625 ?geo .} UNION 
     {?w wdt:P159 ?hauptverwaltung . ?hauptverwaltung wdt:P625 ?geo .} UNION 
     {?w wdt:P131 ?verwaltungseinheit . ?verwaltungseinheit wdt:P625 ?geo .}
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel
ORDER BY ASC(?wLabel)

Try it!

Bundesinstitute (=Ressortforschungseinrichtungen)

Give me all members of the Arbeitsgemeinschaft Ressortforschungseinrichtungen!

SELECT DISTINCT ?w ?wLabel
WHERE 
{
  ?w wdt:P463 wd:Q627618 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

... only those which are active in NFDI!

SELECT DISTINCT ?w ?wLabel ?p ?pLabel ?affiliationTypeLabel
WHERE 
{
  ?w wdt:P463 wd:Q627618 . 
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

Alle Bundesinstitute, die an NFDI beteiligt sind!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
  {
    ?w wdt:P31/wdt:P279* wd:Q314024
  } UNION {
    ?w wdt:P463 wd:Q627618
   } UNION {
    ?w wdt:P749*/wdt:P31 wd:Q896375 .
  } UNION {
    ?w wdt:P31 wd:Q3726309 .
  }
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .} 
  }
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel) ASC(?affiliationTypeLabel) ASC(?pLabel)

Try it!

By Citys (and with Bundesländer)

tends to run into a timeout. Try several times! NEW: See tim-optimzed query, next query.

SELECT DISTINCT ?bundesland ?bundeslandLabel ?stadt ?stadtLabel ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  {
   ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  OPTIONAL {
    ?w wdt:P131+ ?stadt .
    ?stadt  wdt:P31/wdt:P279* wd:Q515 .
    OPTIONAL {
      ?w wdt:P131+ ?bundesland .
      ?bundesland  wdt:P31 wd:Q1221156 .
     }
   }
  OPTIONAL {
    ?w wdt:P159/wdt:P131* ?stadt . 
    ?stadt  wdt:P31/wdt:P279* wd:Q515 .
    OPTIONAL {
      ?stadt wdt:P131* ?bundesland .
      ?bundesland  wdt:P31 wd:Q1221156 .
     }    
   }
  FILTER NOT EXISTS {?w  wdt:P31 wd:Q98270496 }  # To not display Konsortia associations to Base4NFDI
  BIND(IF(! Bound(?affiliationType), "NFDI-Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?bundeslandLabel) ASC(?stadtLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

...the same but query optimized to prevent a timeout

SELECT DISTINCT ?bundesland ?bundeslandLabel ?stadt ?stadtLabel ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel WHERE {
{
SELECT DISTINCT ?bundesland ?stadt ?w ?affiliationType ?p WHERE {
  {
   ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  OPTIONAL {
    ?w wdt:P131+ ?stadt .
    {?stadt  wdt:P31/wdt:P279* wd:Q515} UNION {?stadt  wdt:P31/wdt:P279* wd:Q116457956 } 
    OPTIONAL {
      ?stadt wdt:P131* ?bundesland .
      ?bundesland  wdt:P31 wd:Q1221156 .
     }
   }
  OPTIONAL {
    ?w wdt:P159/wdt:P131* ?stadt . 
    ?stadt  wdt:P31/wdt:P279* wd:Q515 . 
    OPTIONAL {
      ?stadt wdt:P131* ?bundesland .
      ?bundesland  wdt:P31 wd:Q1221156 .
     }    
   }
  #FILTER (?bundesland = wd:Q985)
  #FILTER (?stadt = wd:Q3150) 
  FILTER NOT EXISTS {?w  wdt:P31 wd:Q98270496 }  # do nit display consortia associations to Base4NFDI
}
  }
  BIND(IF(! Bound(?affiliationType), "NFDI-Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?bundeslandLabel) ASC(?stadtLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

Städte nach Anzahl Konsortialbeteiligungen

number = Anzahl von Konsortialbeteiligungen einer Stadt = Hier wird jede Beteiligung gezählt, d.h. wenn aus einer Stadt mehrere Beteiligungen an demselben Konsortium kommen, werden diese auch mehrfach gezählt.

number-distinct: Anzahl von Konsortien, an denen eine Stadt beteiligt ist = Hier werden diese nur einfach gezählt, d.h. wenn aus einer Stadt mehrere Beteiligungen an demselben Konsortium kommen.

SELECT DISTINCT ?stadtLabel (COUNT(DISTINCT(?p)) AS ?numberDistinct) (COUNT(?p) AS ?number) WHERE {
{
SELECT DISTINCT ?bundesland ?stadt ?w ?affiliationType ?p WHERE {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    ?statement pq:P3831 ?affiliationType .  
  OPTIONAL {
    ?w wdt:P131+ ?stadt .
    ?stadt  wdt:P31/wdt:P279* wd:Q515 .
   }
  OPTIONAL {
    ?w wdt:P159/wdt:P131* ?stadt . 
    ?stadt  wdt:P31/wdt:P279* wd:Q515 .
   }
  FILTER NOT EXISTS {?w  wdt:P31 wd:Q98270496 }  # To not display Konsortia associations to Base4NFDI
}
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?stadt ?stadtLabel
ORDER BY DESC(?numberDistinct) ASC(?stadtLabel)

Try it!

...count (Co-)Applicants only, i.e. no Participants

SELECT DISTINCT ?stadtLabel (COUNT(DISTINCT(?p)) AS ?numberDistinct) (COUNT(?p) AS ?number) WHERE {
{
SELECT DISTINCT ?bundesland ?stadt ?w ?affiliationType ?p WHERE {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    {?statement pq:P3831 wd:Q54875338} UNION {?statement pq:P3831 wd:Q105906738}   # this line modified to exclude participants  
  OPTIONAL {
    ?w wdt:P131+ ?stadt .
    ?stadt  wdt:P31/wdt:P279* wd:Q515 .
   }
  OPTIONAL {
    ?w wdt:P159/wdt:P131* ?stadt . 
    ?stadt  wdt:P31/wdt:P279* wd:Q515 .
   }
  FILTER NOT EXISTS {?w  wdt:P31 wd:Q98270496 }  # To not display Konsortia associations to Base4NFDI
}
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?stadt ?stadtLabel
ORDER BY DESC(?numberDistinct) ASC(?stadtLabel)

Try it!

DFG-Fachsystematik

• DFG Science Classification (2020-2024) (Q110439023)
• DFG Science Classification (2016-2019) (Q113294657)
• Property: DFG Science Classification (P10287)

Give me all Einzelwissenschaften!

SELECT ?instance ?instanceLabel ?instanceDescription
WHERE {
  ?instance wdt:P31 wd:Q11862829 .
    SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en"}
  } ORDER BY ASC(?instanceLabel)

Try it!

Show me all disciplies and their number of the DFG Fachsystematik!

SELECT ?dfgdisciplineID ?dfgdisciplineName ?discipline ?disciplineLabel 
WHERE {
  ?discipline p:P10287 ?statement .
  ?statement ps:P10287 ?dfgdisciplineID .
  OPTIONAL {?statement pq:P1810 ?dfgdisciplineName}
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de, en"}
} ORDER BY ASC(?dfgdisciplineID)

Try it!

...as a tree (UNDER DEVELOPMENT)

#defaultView:Tree
SELECT ?discipline1 (CONCAT(?dfgdiscipline1ID," ",?dfgdiscipline1Name) AS ?text1) ?discipline2 (CONCAT(?dfgdiscipline2ID," ",?dfgdiscipline2Name) AS ?text2) ?discipline3 (CONCAT(?dfgdiscipline3ID," ",?dfgdiscipline3Name) AS ?text3) ?discipline4 (CONCAT(?dfgdiscipline4ID," ",?dfgdiscipline4Name) AS ?text4)       
WHERE
{
  {
    SELECT * WHERE {
        ?discipline1 p:P10287 ?statement1 .
        ?statement1 ps:P10287 ?dfgdiscipline1ID .
        OPTIONAL {?statement1 pq:P1810 ?dfgdiscipline1Name}.
        ?discipline2 p:P10287 ?statement2 .
        ?statement2 ps:P10287 ?dfgdiscipline2ID .
        OPTIONAL {?statement2 pq:P1810 ?dfgdiscipline2Name}.
        ?discipline3 p:P10287 ?statement3 .
        ?statement3 ps:P10287 ?dfgdiscipline3ID .
        OPTIONAL {?statement3 pq:P1810 ?dfgdiscipline3Name}.
        ?discipline4 p:P10287 ?statement4 .
        ?statement4 ps:P10287 ?dfgdiscipline4ID .
        OPTIONAL {?statement4 pq:P1810 ?dfgdiscipline4Name}.
        ?discipline2 wdt:P279 ?discipline1 .
        ?discipline3 wdt:P279 ?discipline2 .
        #?discipline4 wdt:P279 ?discipline3 .
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
} ORDER by ASC(?dfgdiscipline1ID) ASC(?dfgdiscipline2ID) ASC(?dfgdiscipline3ID) ASC(?dfgdiscipline4ID)

Try it!

Show me all consortia and their disciplines of the DFG Fachsystematik!

SELECT  ?p ?pLabel ?discipline ?dfgdisciplineID ?dfgdisciplineName
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p wdt:P101 ?discipline .
  ?discipline p:P10287 ?statement .
  ?statement ps:P10287 ?dfgdisciplineID .
  OPTIONAL {?statement pq:P1810 ?dfgdisciplineName}
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de, en"}
} ORDER BY ASC(?pLabel) ASC(?dfgdisciplineName)

Try it!

...as a graph with all disciplines

#defaultView:Graph
SELECT  ?p ?pLabel ("EC0000" AS ?rgb) ?topic (CONCAT(?dfgTopic,?topicLabel) AS ?topicLabelFull) ?dfgTopic ?topicLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  OPTIONAL { ?p wdt:P101 ?topic }
  OPTIONAL { ?topic wdt:P10287 ?dfgTopic .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?topicLabel) ASC(?pLAbel)

Try it!

...as a graph with DFG disciplines only

#defaultView:Graph
#SELECT  ?p ?pLabel ("EC0000" AS ?rgb) ?topic (CONCAT(?dfgTopic,?topicLabel) AS ?topicLabelFull) ?dfgTopic ?topicLabel
SELECT  ?p ?pLabel  ("EC0000" AS ?rgb) ?discipline (?dfgdisciplineName AS ?disciplineLabel)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p wdt:P101 ?discipline .
  ?discipline p:P10287 ?statement .
  ?statement ps:P10287 ?dfgdisciplineID .
  OPTIONAL {?statement pq:P1810 ?dfgdisciplineName}
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de, en"}
} ORDER BY ASC(?pLabel) ASC(?dfgdisciplineName)

Try it!

Under Development

Give me the Bundesländer, ordered by the number of their affiliations to NFDI, detailed by afiliationtype!

SELECT ?aLabel (COUNT(*) AS ?number)
WHERE { 
  {
    SELECT DISTINCT ?a ?w ?p
    WHERE {  
    {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}
    FILTER (?affiliationType = wd:Q54875338)
  }
      OPTIONAL {
      ?w wdt:P131+ ?a .
      ?a  wdt:P31 wd:Q1221156 .
      }
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} GROUP BY ?aLabel
ORDER BY DESC(?number)

Try it!

Wiss. Akademien

Gib mir alle Mitglieder der !

SELECT ?instance ?instanceLabel ?instanceDescription
WHERE {
  ?instance wdt:P463 wd:Q1662834 .
    SERVICE wikibase:label {bd:serviceParam wikibase:language "de,en"}
} ORDER BY ASC(?instanceLabel)

Try it!

Vernetzung

Gib mir alle FDM-Servicestellen! (als Karte)

#defaultView:Map
SELECT ?organizational_unit ?geo ?located_in_the_administrative_territorial_entityLabel ?organizational_unitLabel ?email_address ?official_website ?part_ofLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?organizational_unit wdt:P31 wd:Q679206;
    wdt:P101 wd:Q30089794.
  OPTIONAL { ?organizational_unit wdt:P131 ?located_in_the_administrative_territorial_entity. }
  OPTIONAL { ?organizational_unit wdt:P968 ?email_address. }
  OPTIONAL { ?organizational_unit wdt:P856 ?official_website. }
  OPTIONAL { ?organizational_unit wdt:P361 ?part_of. }
  OPTIONAL { ?part_of wdt:P625 ?geo. }
}

Try it!

...also sortierte Liste

SELECT ?organizational_unit ?organizational_unitLabel  ?part_ofLabel ?located_in_the_administrative_territorial_entityLabel?email_address ?official_website 
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,[AUTO_LANGUAGE],en". }
  ?organizational_unit wdt:P31 wd:Q679206;
    wdt:P101 wd:Q30089794.
  OPTIONAL { ?organizational_unit wdt:P131 ?located_in_the_administrative_territorial_entity. }
  OPTIONAL { ?organizational_unit wdt:P968 ?email_address. }
  OPTIONAL { ?organizational_unit wdt:P856 ?official_website. }
  OPTIONAL { ?organizational_unit wdt:P361 ?part_of. }
  OPTIONAL { ?part_of wdt:P625 ?geo. }
}
ORDER BY ASC(?located_in_the_administrative_territorial_entityLabel) ASC(?part_ofLabel) ASC(?organizational_unitLabel)

Try it!

Deutsche Hochschulen als Bubble Charts nach Größe (= Anzahl Studierender)

NFDI-Beteiligung markiert

#defaultView:BubbleChart
SELECT DISTINCT ?w ?wLabel ?students ?rgb {  
  ?w wdt:P31/wdt:P279* wd:Q38723 .      # nur Hochschulen
  # ?w wdt:P31/wdt:P279* wd:Q1365560 .      # HAWs only
  # ?w wdt:P31/wdt:P279* wd:Q3918 .      # Unis only
  ?w wdt:P17 wd:Q183 .
  OPTIONAL {?w wdt:P2196 ?students .} # Lernende
  # OPTIONAL {?w wdt:P1128 ?students .}  # Mitarbeiter
  OPTIONAL { ?w wdt:P463 wd:Q105757481 .
   BIND("Vereinsmitglied" AS ?affiliationTypeLabel)
   BIND(TRUE AS ?NFDIassociated)
  }
  OPTIONAL {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}   
    BIND(TRUE AS ?NFDIassociated)
  } 
  BIND(IF(Bound(?NFDIassociated), "0abaf0", "666666") AS ?rgb)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" }
} ORDER BY DESC(?students) ASC(?wLabel)

Try it!

... FDM-Servicestellen markiert

#defaultView:BubbleChart
SELECT DISTINCT ?w ?wLabel ?students ?rgb {  
  ?w wdt:P31/wdt:P279* wd:Q38723 .      # nur Hochschulen
  #?w wdt:P31/wdt:P279* wd:Q1365560 .      # HAWs only
  # ?w wdt:P31/wdt:P279* wd:Q3918 .      # Unis only
  ?w wdt:P17 wd:Q183 .
  OPTIONAL {
    ?p wdt:P101 wd:Q30089794 .
    ?p wdt:P31 wd:Q679206 .
    ?p wdt:P361 ?w . 
    BIND(TRUE AS ?kontaktstelle)
  }
  ?w wdt:P2196 ?students .
  BIND(IF(Bound(?kontaktstelle), "a3c717", "666666") AS ?rgb)  # Kontaktstelle: grün
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" }
} ORDER BY DESC(?students) ASC(?wLabel)

Try it!

... both combined in one Bubblechart (doesn't work yet)

#defaultView:BubbleChart
SELECT DISTINCT ?w ?wLabel ?students ?rgb {  
  ?w wdt:P31/wdt:P279* wd:Q38723 .      # nur Hochschulen
  # ?w wdt:P31/wdt:P279* wd:Q1365560 .      # HAWs only
  # ?w wdt:P31/wdt:P279* wd:Q3918 .      # Unis only
  ?w wdt:P17 wd:Q183 .
  OPTIONAL {
    ?p wdt:P101 wd:Q30089794 .
    ?p wdt:P31 wd:Q679206 .
    ?p wdt:P361 ?w . 
    BIND(TRUE AS ?kontaktstelle)
  }
  OPTIONAL {?w wdt:P2196 ?students .} # Lernende
  # OPTIONAL {?w wdt:P1128 ?students .}  # Mitarbeiter
  OPTIONAL { ?w wdt:P463 wd:Q105757481 .
   BIND("Vereinsmitglied" AS ?affiliationTypeLabel)
   BIND(TRUE AS ?NFDIassociated)
  }
  OPTIONAL {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}   
    BIND(TRUE AS ?NFDIassociated)
  } 
  #BIND(IF(Bound(?NFDIassociated), "0abaf0", "666666") AS ?rgb)  # NFDI: blau
  #BIND(IF(Bound(?kontaktstelle), "a3c717", "666666") AS ?rgb)  # Kontaktstelle: grün
  BIND(IF(Bound(?NFDIassociated), IF(Bound(?kontaktstelle), "a3c717", "0abaf0"), IF(Bound(?kontaktstelle), "a3c717", "666666")) AS ?rgb)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" }
} ORDER BY DESC(?students) ASC(?wLabel)

Try it!

Konsortialbeteiligte und Vereinsmitglieder

Gib mir die Schnittmenge aus Konsortialbeteiligten (Applicants. Coaplicants, Participants) und Vereinsmitgliedern!

SELECT DISTINCT ?p ?pLabel ?w ?wLabel ?affiliationType ?affiliationTypeLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?wx .
  ?wx wdt:P361* ?w . 
#   {{ ?wx wdt:P361* ?w } UNION { ?wx wdt:P749* ?w }} 
  #?wx (wdt:P361|wdt:P749)* ?w .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel) ASC(?wLabel)

Try it!

Gib mir alle Vereinsmitglieder, die nicht an einem Konsortium beteiligt sind!

SELECT DISTINCT ?p ?pLabel ?w ?wLabel ?affiliationType ?affiliationTypeLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?wx .
  ?wx wdt:P361* ?w . 
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?pLabel) ASC(?wLabel)

Try it!

Gib mir alle Konsortialbeteiligten, die (noch) nicht Vereinsmitglied sind!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 . 
    ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416+ ?statement .
  ?statement ps:P1416+ ?w .
  ?statement pq:P3831 ?affiliationType .
  FILTER NOT EXISTS {?w wdt:P463+|wdt:P361/wdt:P463|wdt:P749/wdt:P463 wd:Q105757481 .} 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY DESC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

Konsortialbeteiligungen (für Zwischenberichte der Konsortien)

Liste für ein gegebenes Konsortiums, an welchem andern Konsortien dessen Participants beteiligt sind! (Von Daniel Mietchen)

SELECT ?Consortium1 ?Consortium1Label ?institution ?institutionLabel ?Consortium2 ?Consortium2Label 
WHERE 
{
  ?Consortium1 wdt:P31 wd:Q98270496 . 
  ?Consortium2 wdt:P31 wd:Q98270496 . 
  FILTER (?Consortium1 != ?Consortium2)
  ?Consortium1 wdt:P1416 ?institution.
  ?Consortium2 wdt:P1416 ?institution.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
}
ORDER BY ASC(?Consortium1Label) ASC(?institution) ASC(?Consortium2Label)

Try it!

Gibt mir alle an KonsortSWD beteiligten Organisationen!

SELECT DISTINCT ?p ?pLabel ?affiliationTypeLabel ?w ?wLabel
WHERE 
{
  wd:Q98380340 p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)

Try it!

Liste für ein gegebenes Konsortium (KonsortSWD), an welchem andern Konsortien dessen Beteiligte ebenfalls beteiligt sind! (2023-04-17)

SELECT DISTINCT  ?wsingular ?wsingularLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  wd:Q98380340 wdt:P1416 ?wsingular .    # Für anderes Konsortium: wd:Q98380340 ersetzen
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?wsingular .
  #FILTER (?p != wd:Q98380340 )     # um KonsortSWD auszublenden
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
} ORDER BY ASC(?wsingularLabel) ASC(?pLabel)

Try it!

...als Graph

#defaultView:Graph
#SELECT  ?p ?pLabel ("EC0000" AS ?rgb) ?topic (CONCAT(?dfgTopic,?topicLabel) AS ?topicLabelFull) ?dfgTopic ?topicLabel
SELECT  ?p ?pLabel  ("EC0000" AS ?rgb) ?discipline (?dfgdisciplineName AS ?disciplineLabel)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p wdt:P101 ?discipline .
  ?discipline p:P10287 ?statement .
  ?statement ps:P10287 ?dfgdisciplineID .
  OPTIONAL {?statement pq:P1810 ?dfgdisciplineName}
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de, en"}
} ORDER BY ASC(?pLabel) ASC(?dfgdisciplineName)

Try it!

TEST: Dasselbe, aber mit Berücksichtigung, dass Applicants auch Teilorganisationen sein können.

SELECT DISTINCT  ?wsingular ?wsingularLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  wd:Q98380340 wdt:P361*/wdt:P1416+/wdt:P361* ?wsingular .
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P361*/p:P1416+/p:P361*  ?statement .
  ?statement ps:P361*/ps:P1416+/ps:P361*  ?wsingular .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
} ORDER BY ASC(?wsingularLabel) ASC(?pLabel)

Try it!

Alle Konsortien, unqualifizierte Verbindung

vgl. Lösung von Daniel Mietchen (s.o.)

SELECT DISTINCT ?consortium1Label ?organisationLabel ?consortium2Label
WHERE 
{
  ?consortium1 wdt:P1416 ?organisation .   
  ?consortium1 wdt:P31 wd:Q98270496 .
  ?consortium2 wdt:P31 wd:Q98270496 .
  FILTER (?consortium1 != ?consortium2)
  ?consortium2 p:P1416 ?statement .
  ?statement ps:P1416 ?organisation .
  #FILTER (?p != wd:Q98380340 )     # um KonsortSWD auszublenden
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
} ORDER BY ASC(?consortium1Label) ASC(?organisationLabel) ASC(?consortium2Label)

Try it!

...(Co-)applicants only

SELECT DISTINCT ?consortium1Label ?organisationLabel ?consortium2Label
WHERE 
{ 
  ?consortium1 wdt:P31 wd:Q98270496 .
  ?consortium2 wdt:P31 wd:Q98270496 .
  ?consortium1 p:P1416 ?statement1 .
  ?statement1 ps:P1416 ?organisation .
  {?statement1 pq:P3831 wd:Q54875338} UNION {?statement1 pq:P3831 wd:Q105906738}
  ?statement1 pq:P3831 ?affiliationType . 
  ?consortium2 p:P1416 ?statement2 .
  ?statement2 ps:P1416 ?organisation .
  {?statement2 pq:P3831 wd:Q54875338} UNION {?statement2 pq:P3831 wd:Q105906738}
  ?statement2 pq:P3831 ?affiliationType . 
  FILTER (?consortium1 != ?consortium2)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
} ORDER BY ASC(?consortium1Label) ASC(?organisationLabel) ASC(?consortium2Label)

Try it!

Fachgesellschaften

Gib mir alle an NFDI beteiligten Fachgsellschaten!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p p:P1416 ?statement .
  ?statement ps:P1416 ?w .
  {{?w wdt:P31 wd:Q1391145} UNION {?w wdt:P31 wd:Q1391517} UNION {?w wdt:P31 wd:Q955824}}
  ?w wdt:P17 wd:Q183 .
  OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  OPTIONAL { ?p wdt:P571 ?inception }
  OPTIONAL { ?p wdt:P488 ?speaker }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel) ASC(?affiliationTypeLabel) ASC(?pLabel)

Try it!

Gib mir alle Fachgsellschaften!

SELECT DISTINCT ?w ?wLabel
WHERE 
{
  #?w wdt:P31 wd:Q1391145 .  # Fachgesellschat
  #?w wdt:P31 wd:Q748019 .   # Wissenschaftliche Gesellschaft
  #?w wdt:P31 wd:Q1391517 .  # Fachverband
  ?w wdt:P31 wd:Q955824 .   # Gelehrtengesellschaft
  ?w wdt:P17 wd:Q183 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

HAW

Gib mir alle Fachhochschulen in Deutschland!

SELECT ?instance ?instanceLabel
WHERE {
  ?instance wdt:P31/wdt:P279* wd:Q1365560 .
  ?instance wdt:P131+ wd:Q183 .
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de"}
} ORDER BY ASC(?instanceLabel)

Try it!

Gib mir alle Fachhochschulen in Deutschland, die Mitglied von NFDI sind, gruppiert nach Bundesländern!

SELECT DISTINCT ?w ?wLabel ?bundesland ?bundeslandLabel
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31 wd:Q1365560 .
  OPTIONAL {
    ?w wdt:P131+ ?bundesland .
    ?bundesland  wdt:P31 wd:Q1221156 .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?bundeslandLabel) ASC(?wLabel)

Try it!

Gib mir alle Universitäten in Deutschland!

SELECT ?instance ?instanceLabel
WHERE {
  ?instance wdt:P31 wd:Q3918 .
  ?instance wdt:P17 wd:Q183
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de"}
} ORDER BY ASC(?instanceLabel)

Try it!

Strukturbericht 2024

Give me the classes of NFDI associated organisations and their number!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(DISTINCT ?w) as ?number)
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p wdt:P1416 ?w . 
  }
  ?w wdt:P31 ?aggregate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

...raw data fpr the previous query + including parent classes!

SELECT DISTINCT ?w ?wLabel ?class ?classLabel
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p wdt:P1416 ?w . 
  }
  ?w wdt:P31/wdt:P279* ?class .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
}
ORDER BY DESC(?number)

Try it!

Gib mir alle Klassen der Mitgliedsorganisationen des Vereins!

SELECT DISTINCT ?aggregate ?aggregateLabel (count(DISTINCT ?w) as ?number)
WHERE 
{
  ?w wdt:P463 wd:Q105757481 .
  ?w wdt:P31 ?aggregate .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?aggregate ?aggregateLabel
ORDER BY DESC(?number)

Try it!

Gib mir alle an NFDI beteiligten Fachgesellschaften!

SELECT DISTINCT ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL {?statement pq:P3831 ?affiliationType .  }
  }
    {{?w wdt:P31 wd:Q1391145} UNION {?w wdt:P31 wd:Q1391517} UNION {?w wdt:P31 wd:Q955824}}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel) ASC(?affiliationTypeLabel) ASC(?pLabel)

Try it!

Gib mir alle Institutionen aus dem öffentlichem Sektor ("Bundesinstitute"), die an NFDI beteiligt sind!

SELECT DISTINCT ?wGeprisID  ?wRORID ?w ?wLabel ?affiliationType ?affiliationTypeLabel ?p ?pLabel 
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p p:P1416 ?statement .
    ?statement ps:P1416 ?w .
    OPTIONAL { ?statement pq:P3831 ?affiliationType .}  
  }
  {
    ?w wdt:P31/wdt:P279* wd:Q314024
  } UNION {
    ?w wdt:P463 wd:Q627618
   } UNION {
    ?w wdt:P749*/wdt:P31 wd:Q896375 .
  } UNION {
    ?w wdt:P31 wd:Q3726309 .
  }
  OPTIONAL {?w wdt:P4871 ?wGeprisID} 
  OPTIONAL {?w wdt:P6782 ?wRORID} 
  BIND(IF(! Bound(?affiliationType), "Vereinsmitglied", ?affiliationTypeLabel) AS ?affiliationTypeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)

Try it!

An NFDI Beteiligte mit Eintrag im Lobbyregister

SELECT DISTINCT ?w ?wLabel ?lobbyregister
WHERE 
{
  {
    ?w wdt:P463 wd:Q105757481 .
  } UNION {
    ?p wdt:P31 wd:Q98270496 .
    ?p wdt:P1416 ?w . 
  }
  ?w wdt:P10301 ?lobbyregister .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
}
ORDER BY ASC(?wLabel)

Try it!

How any organizations are involved in multiple consortia?

SELECT DISTINCT ?w ?wLabel (count(DISTINCT ?p) as ?number)
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  ?p wdt:P1416 ?w . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel
ORDER BY DESC(?number)

Try it!

...aggregated

SELECT DISTINCT ?number1 (count(?number1) as ?number2) WHERE {
{
SELECT DISTINCT ?w (count(DISTINCT ?p) as ?number1) WHERE {
  ?p wdt:P31 wd:Q98270496 .
  ?p wdt:P1416 ?w . 
} GROUP BY ?w ?wLabel
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?number1
ORDER BY DESC(?number1)

Try it!

Forschungsdaten.org

Liste der Konsortien auf FDM-Kontakte

SELECT  ?pLabel ?pDescription ?website ?email
WHERE 
{
  ?p wdt:P31 wd:Q98270496 .
  OPTIONAL { ?p wdt:P968 ?email. }
  OPTIONAL { ?p wdt:P856 ?website. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
} ORDER BY ASC(?pLabel)

Try it!