fr-N	Cet utilisateur a pour langue maternelle le français.

en-1	This user has basic knowledge of English.

Je contribue principalement sur Commons

Outils

Mix'n'match Liste de sources pour WD
Items créés
My edit groups
OpenRefine a free data wrangling tool that can be used to clean tabular data and connect it with knowledge bases, including Wikidata.
QueryGraph : Outil de création de requête à partir d’un graphe
osm-wikidata Ajout tag wikidata dans OSM

Wikishootme

Wikishootme Visu d'éléments WD géolocalisés + ajout d'image
Wikishootme filtré sur MH (items avec id Mérimée)

Wikishootme filtré sur communes (pour trouver communes à photographier)

Wikishootme : voies de Grenoble

Projets

Monuments historiques

Projet Monuments historiques (WD)

Art

La somme de toutes les peintures
- Wassily Kandinski
- Paul Klee
mémo de Shonagon (présentation à la Wiki convention 2018
Wikidata et œuvres d'art (vidéo, 2015)
Créer et renseigner un élément œuvre d'art sur Wikidata (vidéo, 2015)
exemple de statut des droits d'auteur ne pouvant plus être enfreints

Projets

Vocabulaires Joconde

Ressources

Musée de Grenoble

Ressources

Wikidata

Musée de Grenoble (Q1952944)
Liste des liens pointant vers l'élément WD

Requêtes

Docs, Tutos...

Formation Wikidata en 3 heures
SPARQL, le SQL du Web, et Linked Data Fragment : le point sur le requêtage du Web
Atelier Wikidata à Pas Sage en Seine 2016
Apprendre Wikidata Un cours pour les professionnels de l'information
Introduction à Observable pour les utilisateurs de Wikidata
PU PAC2
Help:Dates
Exemples d’œuvres d'art
- Partie de cartes dans une hôtellerie Dépôt du musée du Louvre
- Saint Jérôme pénitent "Dépeint" avec positions dans l'image (ajoutées avec cet outil )

Requêtes

Communes

Voies de Lyon

Rues du 3eme arrondissement de Lyon avec lat+lon pour export et conversion en gpx

#defaultView:Map
SELECT DISTINCT ?voie ?image ?coord ?lat ?long  ?loc ?locLabel ?layer ?voieLabel WHERE {
  { ?voie (wdt:P31/(wdt:P279*)) wd:Q79007. }
  UNION
  { ?voie (wdt:P31/(wdt:P279*)) wd:Q174782. }
  UNION
  { ?voie (wdt:P31/(wdt:P279*)) wd:Q16544740. }
  UNION
  { ?voie (wdt:P31/(wdt:P279*)) wd:Q3840711. }
  UNION
  { ?voie (wdt:P31/(wdt:P279*)) wd:Q13634881. }
  MINUS { ?voie wdt:P582 ?dateDeFin. }
  ?voie wdt:P131 wd:Q3348.
  OPTIONAL { ?voie wdt:P18 ?image. }
  BIND(IF(?image = "", "yes", "no") AS ?layer)
  OPTIONAL { ?voie wdt:P625 ?coord. }
  OPTIONAL { ?voie p:P625 ?statement. }
  OPTIONAL { ?statement psv:P625 ?coordinate . }
  OPTIONAL { ?coordinate wikibase:geoLatitude ?lat . }
  OPTIONAL { ?coordinate wikibase:geoLongitude ?long .}
  OPTIONAL { ?voie wdt:P131 ?loc. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY DESC (?voieLabel)

Try it!

Items Wikidata à Claix

#Items WD à Claix
SELECT ?item ?itemLabel ?natureLabel ?coord ?image  WHERE {
  ?item  wdt:P131  wd:Q818965; wdt:P31 ?nature.
  
  OPTIONAL{ ?item wdt:P625 ?coord .}
  OPTIONAL {?item wdt:P18 ?image. }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} ORDER BY ?itemLabel

Try it!

Monuments historiques

Préparation WLM 2020 : éléments Wikidata sans image alors qu'il existe une catégorie Commons : https://w.wiki/NwV (N.Vigneron 24/04/20)

SELECT DISTINCT ?mh ?mhLabel (URI(CONCAT("https://commons.wikimedia.org/wiki/Category:", ?com)) AS ?url) ?communeLabel ?deptLabel ?daLabel ?coord 
WHERE {
  ?mh wdt:P380 ?id ; wdt:P373 ?com ; wdt:P625 ?coord; wdt:P131 ?commune .
  OPTIONAL{?mh wdt:P6216 ?da}
  ?commune wdt:P131 ?dept .
  ?dept wdt:P31 wd:Q6465 . #département français
  MINUS { ?mh wdt:P18 [] } # avec image
  MINUS { ?mh wdt:P6216 wd:Q50423863 } # sous copyright
  MINUS { ?mh wdt:P5816 wd:Q56556915 } # détruit
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} ORDER by ?deptLabel ?communeLabel

Try it!

#MH dont les coordonnées sont à plus de 10 kilomètres des coordonnées de la localisation en P131
SELECT ?MH ?MHLabel ?communeLabel ?deptLabel  ?dist ?coordMH ?coordLoc WHERE {
  ?MH wdt:P380 []; wdt:P131 ?commune ; wdt:P625 ?coordMH .
  ?commune wdt:P31 wd:Q484170 . #commune de France
  ?commune wdt:P131 wd:Q3336. #dept 
  ?commune wdt:P131 ?dept.
  ?dept wdt:P31 wd:Q6465 .
  
  ?commune wdt:P625  ?coordLoc.  

  BIND(geof:distance(?coordLoc, ?coordMH) AS ?dist)
  FILTER(?dist > 10 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} ORDER BY DESC (?dist)

Try it!

#MH sans coordonnées
SELECT ?MH ?MHLabel ?communeLabel ?deptLabel ?idLabel  WHERE {
  ?MH wdt:P380 ?id; wdt:P131 ?commune  .
  ?commune wdt:P31 wd:Q484170 . #commune de France
  ?commune wdt:P131 wd:Q12559. #dept 
  ?commune wdt:P131 ?dept.
  ?dept wdt:P31 wd:Q6465 .
  
  ?commune wdt:P625  ?coordLoc. 
  OPTIONAL { ?MH  wdt:P625 ?coordMH. }
  FILTER (!bound(?coordMH))
  MINUS { ?MH wdt:P5816 wd:Q56556915 } # détruit
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} ORDER BY ?communeLabel ?MHLabel

Try it!

MH à partir id Mérimée

SELECT ?item ?itemLabel ?communeLabel ?image ?commons WHERE {
  ?item wdt:P380 "PA00117241".
  OPTIONAL {?item wdt:P18 ?image. }
  OPTIONAL {?item wdt:P131 ?commune. }
  OPTIONAL {?item wdt:P373 ?commons. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

MH dans commune

SELECT ?item ?itemLabel ?statutLabel ?merimeeLabel ?communeLabel ?image ?commons WHERE {
  ?item wdt:P131 wd:Q1155319.
  ?item wdt:P1435 ?statut . 
  ?item wdt:P380 ?merimee . 
  OPTIONAL {?item wdt:P18 ?image. }
  OPTIONAL {?item wdt:P373 ?commons. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

#MH copyvio pour vérif WLM 2017 (d'après Nicolas Vigneron)
SELECT ?item ?itemLabel ?merimee ?locLabel ?insee ?deces ?archiLabel
WHERE 
{
  ?item wdt:P380 ?id ; wdt:P84 ?archi; wdt:P380 ?merimee; wdt:P131 ?loc .
  ?loc  wdt:P374 ?insee .
  ?archi wdt:P570 ?deces .

  FILTER ( year(?deces) > 1946 ).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} GROUP BY ?item ?itemLabel ?merimee ?locLabel ?insee ?deces ?archiLabel

Try it!

Patrimoine religieux

Croix

#croix dans le Gard Q12515
SELECT ?item ?itemLabel ?communeLabel ?image ?commons WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q392371.
  ?item wdt:P131 ?commune. 
  ?commune wdt:P131 wd:Q12515.

  OPTIONAL {?item wdt:P18 ?image. }
  OPTIONAL {?item wdt:P373 ?commons. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Églises (par Olyon )

#title:église du Puy de Dôme
SELECT distinct ?item ?wikidata ?itemLabel ?name ?lat ?lon ?locLabel WHERE {
  SERVICE wikibase:label
    {
      bd:serviceParam wikibase:language "fr,en" .
      ?item rdfs:label ?itemLabel .
      ?loc rdfs:label ?locLabel .
    }
  ?item wdt:P31/wdt:P279* wd:Q16970.
  ?item wdt:P17 wd:Q142.
  ?item wdt:P131 ?loc.
  ?loc wdt:P131 wd:Q12694. #département
  ?item p:P625 ?p625.
  ?p625 psv:P625 [
             wikibase:geoLatitude ?lat ;
             wikibase:geoLongitude ?lon ;
           ].
  BIND(REPLACE(str(?item), "http://www.wikidata.org/entity/", "") AS ?wikidata)
  BIND(REPLACE(CONCAT(UCASE(SUBSTR(?itemLabel,1,1)),SUBSTR(?itemLabel,2)), "( de| des | du | d')(?!.*( de | des | du | d')).*$", "") AS ?name)
}

église du Puy de Dôme

#objets Palissy à  Bussy-le-Grand filtrés sur id Palissy des objets de l'église paroissiale Saint-Antonin
SELECT ?item ?itemLabel ?natureLabel ?statutLabel ?palissyLabel ?lieuLabel WHERE {
  ?item wdt:P31 ?nature. # nature de l'élément (P31)
  ?item wdt:P131 wd:Q844637. #  localisation administrative (P131)  = Bussy-le-Grand (Q844637) 
  OPTIONAL{?item wdt:P276 ?lieu}. #lieu (P276) affiché s'il est renseigné  
  ?item wdt:P1435 ?statut . # statut patrimonial (P1435) 
  ?item wdt:P481 ?palissy . # identifiant Palissy (P481) 
  FILTER ( ?palissy IN ('PM21000462', 'PM21000466', 'PM21000469', 'PM21000467', 'PM21000468', 'PM21000465', 'PM21003402', 'PM21000463', 'PM21000464', 'PM21003401') )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Try it!

Art

#musée par dept
SELECT ?item ?itemLabel ?communeLabel ?deptLabel ?image ?commons ?museoId WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q33506 .
  ?item wdt:P131 ?commune. 
  ?commune wdt:P131 ?dept . 
  ?dept wdt:P31 wd:Q6465 . 
  ?commune wdt:P131 wd:Q12703 . 
  OPTIONAL {?item wdt:P539 ?museoId. }
  OPTIONAL {?item wdt:P18 ?image. }
  OPTIONAL {?item wdt:P373 ?commons. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY  ?communeLabel

Try it!

#Liste matériau marbre
SELECT ?item ?itemLabel ?natureLabel WHERE {
  ?item wdt:P279  wd:Q40861.
  OPTIONAL { ?item wdt:P31 ?nature. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

#liste tableaux d'un peintre
SELECT ?item ?itemLabel ?placeLabel ?collectionLabel ?statutDALabel ?image 
WHERE {
  ?item wdt:P31 wd:Q3305213.
  ?item wdt:P170 wd:Q203371. #peintre
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL { ?item wdt:P6216 ?statutDA .}
  OPTIONAL { ?item wdt:P276 ?place. }
  OPTIONAL { ?item wdt:P195 ?collection. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de". }
}
order by ?placeLabel

Try it!

#Paintings by Kandinsky without image
SELECT ?item ?itemLabel ?placeLabel ?image 
WHERE {
  ?item wdt:P31 wd:Q3305213.
  ?item wdt:P170 wd:Q61064.
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL { ?item wdt:P276 ?place. }
  FILTER (!bound(?image))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

#Paintings by Kandinsky without image at the Solomon R. Guggenheim Museum 
SELECT ?item ?itemLabel ?image 
WHERE {
  ?item wdt:P31 wd:Q3305213.
  ?item wdt:P170 wd:Q61064.
  ?item wdt:P276 wd:Q201469.
  OPTIONAL { ?item wdt:P18 ?image. }
  FILTER (!bound(?image))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Musée de Grenoble

#tableaux du musée de  Grenoble dont le peintre est décédé depuis plus de 70ans, sans image
SELECT ?item ?itemLabel ?inv ?creator ?creatorLabel ?date_deces  ?inception ?image   WHERE {
  ?item wdt:P195 wd:Q1952944.
  ?item wdt:P31 wd:Q3305213.
  ?item wdt:P170 ?creator.
  OPTIONAL { ?item wdt:P217 ?inv. }
  OPTIONAL { ?item wdt:P571 ?inception. }
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL { ?creator wdt:P570 ?date_deces. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  FILTER(!BOUND(?image))
  FILTER (year(?date_deces) < 1950).
}
ORDER BY ?creator

Try it!

Divers

#oeuvres inspirées par "Vingt Mille Lieues sous les mers" de Jules Verne
SELECT ?oeuvre ?oeuvreLabel ?oeuvreDescription ?natureLabel
WHERE {
  ?oeuvre wdt:P144 wd:Q183565. #basé sur 
  ?oeuvre wdt:P31 ?nature.       
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ASC(?natureLabel)

Try it!

#oeuvres inspirées par des romans Jules Verne
SELECT ?oeuvre ?oeuvreLabel ?oeuvreDescription ?natureLabel ?romanLabel
WHERE
{
  #?film wdt:P31 wd:Q11424. #film 
  ?oeuvre wdt:P144 ?roman. #basé sur 
  ?oeuvre wdt:P31 ?nature.    
  ?roman wdt:P50 wd:Q33977. #auteur Jules Verne 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ASC(?romanLabel)

Try it!

#oeuvres inspirées par des romans d'un auteur ayant reçu le prix Nobel de littérature 
SELECT ?oeuvre ?oeuvreLabel ?oeuvreDescription ?natureLabel ?romanLabel ?auteurLabel
WHERE
{
  #?film wdt:P31 wd:Q11424. #film 
  ?oeuvre wdt:P144 ?roman. #basé sur 
  ?oeuvre wdt:P31 ?nature.    
  ?roman wdt:P50 ?auteur. #auteur 
  ?auteur wdt:P166  wd:Q37922 #distinction : prix Nobel de littérature 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY  ?auteurLabel ?romanLabel

Try it!

#Journaux français avec site web
SELECT DISTINCT ?item ?itemLabel ?natureLabel ?siteLabel
WHERE {
  ?item wdt:P31/wdt:P279* wd:Q11032 . 
  ?item wdt:P31 ?nature .
  ?item wdt:P17 wd:Q142 .
  ?item wdt:P856 ?site .
  MINUS { ?item wdt:P576 ?dateFin}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
}
order by ?nature

Try it!

#Stolpersteine in France
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q26703203.
  ?item wdt:P17 wd:Q142.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

#fontaines sans coordonnées
SELECT ?q ?qLabel  ?communeLabel WHERE {
  ?q wdt:P31 wd:Q483453 ; wdt:P17 wd:Q142; wdt:P131 ?commune .
  MINUS { ?q wdt:P625 [] }
   SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} ORDER BY ?communeLabel

Try it!

# arbres remarquables de France
SELECT ?communeLabel ?itemLabel   ?item  WHERE {
  ?item wdt:P31 wd:Q811534. # nature de l'élément (P31)
  ?item wdt:P131 ?commune. #  localisation administrative (P131)   
  ?commune wdt:P17 wd:Q142. # pays : France
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?communeLabel ?itemLabel

Try it!

User:Jvillafruela

Contents

Outils

Wikishootme

Projets

Monuments historiques

Art

Projets

Ressources

Musée de Grenoble

Ressources

Wikidata

Requêtes

Docs, Tutos...

Requêtes

Communes

Voies de Lyon

Items Wikidata à Claix

Monuments historiques

Patrimoine religieux

Art

Musée de Grenoble

Divers

Navigation menu

User:Jvillafruela

Outils

Wikishootme

Projets

Monuments historiques

Art

Projets

Ressources

Musée de Grenoble

Ressources

Wikidata

Requêtes

Docs, Tutos...

Requêtes

Communes

Voies de Lyon

Items Wikidata à Claix

Monuments historiques

Patrimoine religieux

Art

Musée de Grenoble

Divers

Navigation menu

Search