User:Aluxosm/Scratchpad

Lighthouses

• Rock lighthouses in Great Britain and Ireland (mentioned in Seashaken Houses)

Works authored by Merlin Sheldrake

#defaultView:Table

SELECT ?item ?itemLabel ?subjectLabel ?publisherLabel ?date ?doi ?pubmed ?pmcid
WHERE 
{
  ?item wdt:P50 wd:Q89428526.
  OPTIONAL {?item wdt:P921 ?subject.}
  OPTIONAL {?item wdt:P1433 ?publisher.}
  OPTIONAL {?item wdt:P577 ?date.}
  OPTIONAL {?item wdt:P356 ?doi.}
  OPTIONAL {?item wdt:P698 ?pubmed.}
  OPTIONAL {?item wdt:P932 ?pmcid.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?date

Try it!

Breweries that are abbreviated to ABC

#defaultView:Table

SELECT ?item ?itemLabel ?countryLabel ?localityLabel
WHERE
{
  {?item wdt:P31 wd:Q131734}           # Is a brewery
  UNION
  {?item wdt:P31 wd:Q5487333}          # or a microbrewery
  
  ?item skos:altLabel ?alias.          # Get the alias (also known as)
  OPTIONAL {?item wdt:P17 ?country}.   # Get the country
  OPTIONAL {?item wdt:P131 ?locality}. # Get the locality

  FILTER(CONTAINS(?alias, "ABC"@en))   # Check that the alias is 'ABC'
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE]"
    }
}

ORDER BY ?countryLabel

Try it!

People who have held a position in the Air Training Corps

#defaultView:Table

SELECT ?person ?personLabel ?positionLabel ?start_time ?end_time
WHERE
{
  ?person wdt:P31 wd:Q5 .                                           # human
  ?person p:P39 [ ps:P39 ?position; pq:P642 wd:Q4698217] .          # position held - ? - of - Air Training Corps
  OPTIONAL{?person p:P39 [ ps:P39 ?position; pq:P580 ?start_time]}  # start time
  OPTIONAL{?person p:P39 [ ps:P39 ?position; pq:P582 ?end_time]}    # end time
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}

ORDER BY (?start_time)

Try it!

Classification of sound recording devices

Classification of the class sound recording device (Q66087652)   

For help about classification, see Wikidata:Classification.

Parent classes (classes of items which contain this one item)

• sound recording device (Q758891)
  • recorder (Q1312336)
    • audio equipment (Q15190726) ^(@)→
  • ^→(@) audio equipment (Q15190726)
    • appliance (Q1183543)
      • physical tool (Q39546)
        • equipment (Q10273457)
          • physical object (Q223557) ^(#)→
          • product (Q2424752)
            • object (Q488383) ^(+)→
        • artificial physical object (Q8205328)
          • ^→(#) physical object (Q223557)
            • material entity (Q53617407)
              • independent continuant (Q53617489)
                • continuant (Q103940464)
                  • entity (Q35120) ⊸
            • concrete object (Q4406616)
              • object (Q488383) ^(+)→
          • artificial object (Q16686448)
            • object (Q488383) ^(+)→
        • tool (Q123691918)
          • ^→(+) object (Q488383)
            • entity (Q35120) ⊸

Subclasses (classes which contain special kinds of items of this class)

⟨sound recording device⟩ on wikidata tree visualisation (external tool)(depth=1)

Generic queries for classes

• Number of subclasses (query)
• List of subclasses
• List of direct subclasses
• Number of instances (query)
• Count of instances by class (query)
• List of instances (query)
• List of most frequent properties for items of this class (query)
• Properties suggested for this class (query)

Younger Dryas impact hypothesis

See also: Wikidata:WikiProject Younger Dryas impact hypothesis

# Articles where the main subject is "Younger Dryas impact hypothesis" and the reference for that statement is a link to "The Bib"

SELECT DISTINCT ?item ?date ?itemLabel ?publisherLabel ?doi ?statements ?ids (COUNT(?cite) AS ?cites) # ?ref ?sitelinks
WHERE
{ 
  ?item wdt:P921 wd:Q1092095.
  
  ?item p:P921 ?statement.
  ?statement prov:wasDerivedFrom ?refnode.
  ?refnode   pr:P854 ?ref.
  
  FILTER(CONTAINS(STR(?ref), "younger-dryas-impact-hypothesis-bibliography-and-paper-archive")).
  
  OPTIONAL { ?item wdt:P577 ?date }
  OPTIONAL { ?item wdt:P1433 ?publisher }
  OPTIONAL { ?item wdt:P356 ?doi }
  OPTIONAL { ?item wdt:P2860 ?cite }
  OPTIONAL { ?item wikibase:statements ?statements ; wikibase:identifiers ?ids ; wikibase:sitelinks ?sitelinks }
  
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
GROUP BY ?item ?date ?itemLabel ?publisherLabel ?doi ?statements ?ids
ORDER BY ?date ?itemLabel

Try it!