User:FabC/Italy

Italy and Wikidata

This page is about Italy and how it is model and represented in Wikidata.

Administrative divisions

Regions

Italy is divided in 20 administrative regions. Some regions have a special statute and they are considered as a subclass of the most generic region [1]. The query for the list of the italian regions must includes the region of Italy (Q16110) and subclasses (only one indeed, autonomous region with special statute (Q1710033)).

#Italian regions
SELECT ?item ?itemLabel
WHERE 
{
  ?item wdt:P131 wd:Q38.                   # Administrative divisions of Italy
  ?item p:P31/ps:P31/wdt:P279* wd:Q16110 . # Regions (including subclasses for special statute regions)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Provinces

Each region is administratively divided in 102 provinces. Since 2016 some province of Italy (Q15089) have been replaced by metropolitan city of Italy (Q15110) and free municipal consortium (Q21190155), the next query consider all of them.

#Italia: regions, provinces
#defaultView:Tree
SELECT ?italiaLabel ?regione ?regioneLabel ?provincia ?provinciaLabel ?comune ?comuneLabel
WHERE 
{
  ?regione p:P31/ps:P31/wdt:P279* wd:Q16110 .    # Regions of Italia
  ?provincia wdt:P131 ?regione .                 # Administrative divisions in the region
  
  { ?provincia wdt:P31 wd:Q15089 . }             # List of provinces

  UNION
  { ?provincia wdt:P31 wd:Q15110 . }             # metropolitan cities of Italy
  
  UNION
  { ?provincia wdt:P31 wd:Q21190155 . }          # Liberi consorzi comunali of Sicily
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Unioni Territoriali Intercomunali

The intermunicipal territorial union (Q27961023) can be considered similar to provinces but are not administrative entities and they are used only for statistical purposes. They are a total of 18 and replaced 4 provinces from Friuli Venezia-Giulia since 2016:

#Italia: Unioni territoriali intercomunali
#defaultView:Tree
SELECT ?regione ?regioneLabel ?provincia ?provinciaLabel
WHERE 
{
  ?regione p:P31/ps:P31/wdt:P279* wd:Q16110 .    # Regions of Italia
  ?provincia wdt:P131 ?regione .                 # Administrative divisions in the region
  
  { ?provincia wdt:P31 wd:Q27961023 . }          # Unioni terriotriali
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Moreover, the region of Val d'Aosta is sometimes referenced as province because of the its level of functionality.

Comuni

Each region is divided in provinces and then in comuni. Both {Q|15089} and {Q|15110} have to be considered in order to have a complete set of administrative entities of second level. Since 1-Jan-2018 many comuni have been joined in a new entity, so wikidata items have been (or must be) updated. This comuni have been defined as instance of (P31) of abolished municipality in Italy (Q3685476).

#Italia: regions, provinces and comuni
#defaultView:Tree
SELECT ?italiaLabel ?regione ?regioneLabel ?provincia ?provinciaLabel ?comune ?comuneLabel
WHERE 
{
  ?regione p:P31/ps:P31/wdt:P279* wd:Q16110 .    # Regions of Italia
  ?provincia wdt:P131 ?regione .                 # Administrative divisions in the region
  
  { ?provincia wdt:P31 wd:Q15089 . }             # List of provinces
  UNION
  { ?provincia wdt:P31 wd:Q15110 . }             # metropolitan cities of Italy
  UNION
  { ?provincia wdt:P31 wd:Q21190155 . }          # Liberi consorzi comunali of Sicily
   
  ?comune wdt:P131 ?provincia .                  # Administrative divisions in the province
  {
    ?comune wdt:P31 wd:Q747074 .                 # Italian municipality
  }
  UNION
  {
    ?comune wdt:P31 wd:Q954172 .                 # Italian sparse municipality
  } 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!