User:Florentyna

From Wikidata
Jump to navigation Jump to search

Links[edit]

Badminton players without citizenship[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER NOT EXISTS { ?item wdt:P27 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Badminton players from a specific country without birth date[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P27 wd:Q668 .
   FILTER NOT EXISTS { ?item wdt:P569 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Badminton players without gender[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER NOT EXISTS { ?item wdt:P21 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Chinese badminton players[edit]

SELECT ?item ?itemLabel WHERE {
 ?item wdt:P106 wd:Q13141064 .
 { ?item wdt:P27 wd:Q148. }
 UNION
 { ?item wdt:P27 wd:Q865. }
 UNION
 { ?item wdt:P27 wd:Q14773. }
 UNION
 { ?item wdt:P27 wd:Q8646. }
 SERVICE wikibase:label {
 bd:serviceParam wikibase:language "zh" .
 }
 }
Try it!

Missing gender by tournament type[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Women's") AS ?is_woman) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      MINUS { ?item wdt:P21 [] } .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_woman = true ) .
  #FILTER( ?is_woman = false ) . 
  #false is not the correct solution, because Mixed doubles will listed there, too
}
Try it!

Missing labels[edit]

SELECT ?item ?itemLabel ?itemDescription ?emptyOtherLanguageLabel WHERE {
  ?item wdt:P106 wd:Q13141064 .
  OPTIONAL {
    ?item rdfs:label ?emptyOtherLanguageLabel .
  	FILTER( LANG(?emptyOtherLanguageLabel) = "fr" ) . 
  }
  FILTER(!BOUND(?emptyOtherLanguageLabel))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
Try it!

Replace rdfs:label by schema:description for missing descriptions. Replace "fr" by another language code for another missing language.

Number of Chinese labels[edit]

SELECT ?item ?itemLabel ?numberOfDifferentChineseLabels WHERE {
  {
    SELECT ?item (COUNT(DISTINCT ?plainlabel) AS ?numberOfDifferentChineseLabels) WHERE {
      {
        SELECT ?item WHERE {
          ?item wdt:P106 wd:Q13141064 .
        }
      }
      OPTIONAL {
        ?item rdfs:label ?label .
        BIND(STR(?label) AS ?plainlabel) .
      }
      FILTER( SUBSTR(LANG(?label), 0, 2) = "zh" ) . 
      FILTER( BOUND(?label) ) .
    } GROUP BY ?item
  }
  FILTER(?numberOfDifferentChineseLabels > 0) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} ORDER BY DESC(?numberOfDifferentChineseLabels)
Try it!

Chinese labels per all Chinese languages incl. yue and wuu[edit]

SELECT ?item ?itemLabel ?plainlabel (GROUP_CONCAT(?lang; separator=", ") as ?langs) WHERE {
  {
    SELECT ?item WHERE {
      ?item wdt:P106 wd:Q13141064 .
    }
  }
  OPTIONAL {
    ?item rdfs:label ?label .
    BIND(STR(?label) AS ?plainlabel) .
    BIND(LANG(?label) AS ?lang) .
  }
  FILTER( REGEX(LANG(?label), '^(zh.*|yue|wuu)$') ) . 
  FILTER( BOUND(?label) ) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} GROUP BY ?item ?itemLabel ?plainlabel ORDER BY ASC(?item)
Try it!

Chinese labels per ZH-Chinese languages (without yue and wuu)[edit]

SELECT ?item ?itemLabel ?plainlabel (GROUP_CONCAT(?lang; separator=", ") as ?langs) WHERE {
  {
    SELECT ?item WHERE {
      ?item wdt:P106 wd:Q13141064 .
    }
  }
  OPTIONAL {
    ?item rdfs:label ?label .
    BIND(STR(?label) AS ?plainlabel) .
    BIND(LANG(?label) AS ?lang) .
  }
  FILTER( SUBSTR(LANG(?label), 0, 2) = "zh" ) . 
  FILTER( BOUND(?label) ) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} GROUP BY ?item ?itemLabel ?plainlabel ORDER BY ASC(?item)
Try it!

Comparison of zh-hans and zh-hant[edit]

SELECT ?item ?itemLabel ?plainlabel (GROUP_CONCAT(?lang; separator=", ") as ?langs) WHERE {
  {
    SELECT ?item WHERE {
      ?item wdt:P106 wd:Q13141064 .
    }
  }
  OPTIONAL {
    ?item rdfs:label ?label .
    BIND(STR(?label) AS ?plainlabel) .
    BIND(LANG(?label) AS ?lang) .
  }
  FILTER( LANG(?label) = "zh-hant" ) .
  FILTER( BOUND(?label) ) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "zh-hans" }
} GROUP BY ?item ?itemLabel ?plainlabel ORDER BY ASC(?item)
Try it!

Sports-Reference without BWF-ID[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P106 wd:Q13141064 .
   FILTER EXISTS { ?item wdt:P1447 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2729 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Article in a specific Wiki with a property on Wikidata[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
		FILTER EXISTS { ?wen schema:about ?item . ?wen schema:inLanguage "de" }
		SERVICE wikibase:label {
		bd:serviceParam wikibase:language "de,en" .
	}
}
GROUP BY ?item ?itemLabel
Try it!

Participants of tournaments[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Bangladesh Badminton") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
}
Try it!

Missing name in native language[edit]

SELECT ?item ?itemLabel ?countryLabel WHERE {
   ?item wdt:P106 wd:Q13141064; wdt:P27 ?country .
   FILTER EXISTS { ?item wdt:P27 ?dummy0 }
   FILTER EXISTS { ?item wdt:P106 wd:Q13141064 }
   FILTER NOT EXISTS { ?item wdt:P1559 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
ORDER BY ?countryLabel
Try it!

No backlinks[edit]

SELECT DISTINCT ?item 
WHERE
{
  ?item wikibase:sitelinks 0 .
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P21 ?dummy1 .
   ?item wdt:P106 wd:Q13141064 .
  OPTIONAL{
    ?backlink ?p1 ?item .
  }
  FILTER(!bound(?backlink))  
  OPTIONAL{
    ?item ?claim ?dummy0 .
    ?property wikibase:propertyType wikibase:ExternalId .
    ?property wikibase:directClaim ?claim
  }
  FILTER(!bound(?dummy0))
  OPTIONAL{
    ?item ?p2 [prov:wasDerivedFrom ?ref] .
    ?ref ?pr [] .
  }  
  FILTER(!bound(?ref))
}
Limit 100
Try it!

Article in zh not in de[edit]

SELECT DISTINCT ?item ?itemLabel WHERE {
   ?item wdt:P5008 wd:Q66098665 
  FILTER EXISTS { ?wzh schema:about ?item . ?wzh schema:inLanguage "zh" }
  FILTER NOT EXISTS { ?wde schema:about ?item . ?wde schema:inLanguage "de" }
		SERVICE wikibase:label {
		bd:serviceParam wikibase:language "de,zh" .
	}
}
GROUP BY ?item ?itemLabel
Try it!

Athletes without CGF-ID[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Commonwealth") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
  FILTER NOT EXISTS { ?item wdt:P4548 ?dummy0 }
}
Try it!

Tournaments in 2017[edit]

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P5008 wd:Q66098665 .
  ?item wdt:P585 ?_publication_date .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
FILTER (?_publication_date = "2017-00-00T00:00:00Z"^^xsd:dateTime)
}
Try it!

Wrong gender[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Women") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P21 wd:Q6581097; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
}
Try it!

Participants of tournaments in the 1990s without BWF-ID[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "199") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
  FILTER NOT EXISTS { ?item wdt:P2729 ?dummy0 }
}
Try it!

Participants of Asian Games[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P1344 wd:Q495611
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Search for point in time[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "T00:00:00Z") AS ?is_Bangla) WHERE {
      ?item wdt:P5008 wd:Q66098665; wdt:P585 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
  FILTER EXISTS { ?item wdt:P585 ?dummy0 }
        }
Try it!

Start and end time[edit]

SELECT ?item ?itemLabel ?_start ?_end ?_instanceLabel
WHERE {
   ?item wdt:P5008 wd:Q66098665 .
   FILTER EXISTS  { ?item wdt:P580 ?dummy0 }
   ?item wdt:P580 ?_start.
   ?item wdt:P582 ?_end.
   ?item wdt:P31 ?_instance.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Try it!

Korean badminton players without McCune-Reischauer romanization[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P27 wd:Q884 .
   FILTER NOT EXISTS { ?item wdt:P1942 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Badminton players without IDs, participations, awards, works[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER NOT EXISTS { ?item wdt:P1344 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2729 ?dummy0 }  
   FILTER NOT EXISTS { ?item wdt:P4548 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2868 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P166 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P800 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2581 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P213 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P214 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3620 ?dummy0 }
   FILTER NOT EXISTS {?article schema:about ?item } 
   FILTER NOT EXISTS { ?item wdt:P4042 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1741 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P646 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4588 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3973 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P166 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3171 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1447 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3417 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P244 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3222 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4392 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2671 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1280 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3670 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4787 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2029 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4638 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3988 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P8350 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4613 ?dummy0 }
   SERVICE wikibase:label {
   bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Badminton people without a specific language label[edit]

SELECT ?item ?itemLabel ?itemDescription WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P641 wd:Q7291 .

 SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
 FILTER(NOT EXISTS {
   ?item rdfs:label ?lang_label.
   FILTER(LANG(?lang_label) = "eml") #with missing eml label
 })
}
ORDER BY ?itemLabel
Try it!

Locations of events with parts[edit]

SELECT ?item ?itemLabel ?location ?haspart WHERE {
   ?item wdt:P5008 wd:Q66098665; wdt:P276 ?location; wdt:P527 ?haspart.
   FILTER EXISTS { ?item wdt:P527 ?dummy0 }
   FILTER EXISTS { ?item wdt:P276 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Norwegian badminton players[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P27 wd:Q20 . 
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
ORDER BY ?itemLabel
Try it!

Location of main tournament page to parts of tournament[edit]

SELECT ?item ?itemLabel ?participant ?participantLabel ?location WHERE {
   ?item wdt:P17 wd:Q35; wdt:P5008 wd:Q66098665; wdt:P527 ?participant; wdt:P276 ?location .
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Japanese name without kana[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P27 wd:Q17 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER EXISTS { ?item wdt:P1559 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1814 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Japanese translations[edit]

SELECT ?item ?itemLabel ?participantLabel WHERE {
   ?item wdt:P27 wd:Q17; wdt:P106 wd:Q13141064; wdt:P1559 ?participant .
   FILTER EXISTS { ?item wdt:P1559 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Category check for correct location[edit]

SELECT ?cat ?catLabel ?location ?locationLabel {
  ?cat p:P4224[ps:P4224 wd:Q13357858; pq:P276 ?location]
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
Try it!

Category of locations to location for tournaments[edit]

PREFIX mw: <http://tools.wmflabs.org/mw2sparql/ontology#>
SELECT DISTINCT ?tournament ?tournamentLabel ?location ?locationLabel {
  hint:Query hint:optimizer "None" .
  ?cat p:P4224[ps:P4224 wd:Q13357858; pq:P276 ?location] .
  ?catArticle schema:about ?cat
  SERVICE <http://tools.wmflabs.org/mw2sparql/sparql> {
    ?page mw:inCategory ?catArticle
  }
  ?page schema:about ?tournament . ?tournament wdt:P5008 wd:Q66098665
  FILTER NOT EXISTS { ?tournament wdt:P276 [] } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de" }
}
Try it!

Locations for Part-of-tournaments[edit]

SELECT ?parts ?partsLabel ?location ?locationLabel {
  ?tournament wdt:P5008 wd:Q66098665; wdt:P276 ?location; wdt:P527 ?parts .
  ?parts wdt:P5008 wd:Q66098665
  FILTER NOT EXISTS { ?parts wdt:P276 [] }
  FILTER NOT EXISTS { ?parts wdt:P2094 wd:Q63874701 }
  FILTER NOT EXISTS { ?parts wdt:P3085 [] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de" }
}
Try it!

Missing locations for for a specific country[edit]

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P5008 wd:Q66098665 .
  ?item wdt:P17 wd:Q145 .
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q18608583 }
  FILTER NOT EXISTS { ?item wdt:P276 ?dummy0 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Try it!

Missing description in en[edit]

SELECT ?item ?itemLabel ?genderLabel ?itemDescription WHERE {
  ?item wdt:P5008 wd:Q66098665.  # focus badminton tournament
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,it,es,pt,no". }
  FILTER(NOT EXISTS {
    ?item schema:description ?itemdesc.
    FILTER(LANG(?itemdesc) = "en") # with missing language description
  })
}
order by ?itemLabel
Try it!

From participant to birth date[edit]

SELECT ?item ?itemLabel ?haspart ?haspartLabel WHERE {
   ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?haspart.
   FILTER NOT EXISTS { ?item wdt:P569 ?dummy0 }
   FILTER EXISTS { ?item wdt:P1344 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Irish badminton players without an article in en-wiki[edit]

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P106 wd:Q13141064 .
   FILTER EXISTS { ?item wdt:P1532 wd:Q27 }
   FILTER NOT EXISTS { ?wen schema:about ?item . ?wen schema:inLanguage "en"  }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
Try it!

Badminton players born in a specific year[edit]

SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P569 ?statement_0.
      ?statement_0 psv:P569 ?statementValue_0.
      ?statementValue_0 wikibase:timePrecision ?precision_0.
      hint:Prior hint:rangeSafe "true"^^xsd:boolean.
      FILTER(?precision_0 = 11 )
      ?statementValue_0 wikibase:timeValue ?P569_0.
      hint:Prior hint:rangeSafe "true"^^xsd:boolean.
      FILTER(("+1899-00-00T00:00:00Z"^^xsd:dateTime <= ?P569_0) && (?P569_0 < "+1900-00-00T00:00:00Z"^^xsd:dateTime))
      ?item p:P641 ?statement1.
      ?statement1 (ps:P641/(wdt:P279*)) wd:Q7291.
      ?item p:P31 ?statement2.
      ?statement2 (ps:P31/(wdt:P279*)) wd:Q5.
    }
 }
 }
Try it!

Badminton championships in a specific year with start and end[edit]

SELECT ?item ?itemLabel ?_start ?_end ?_instanceLabel
WHERE {
   ?item wdt:P5008 wd:Q66098665 .
   FILTER EXISTS  { ?item wdt:P580 ?dummy0 }
   ?item wdt:P580 ?_start.
   ?item wdt:P582 ?_end.
   ?item wdt:P31 ?_instance.
   ?item wdt:P585 ?_publication_date .
   FILTER NOT EXISTS { ?item wdt:P31 wd:Q57733494 }
   FILTER (?_publication_date = "2016-00-00T00:00:00Z"^^xsd:dateTime)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
Try it!

Badminton championships in 2020 without an article in de[edit]

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P5008 wd:Q66098665 .
  ?item wdt:P585 ?_publication_date .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
FILTER (?_publication_date = "2020-00-00T00:00:00Z"^^xsd:dateTime)
FILTER NOT EXISTS { ?item wdt:P31 wd:Q57733494 }
FILTER NOT EXISTS { ?wde schema:about ?item . ?wde schema:inLanguage "de" }
}
Try it!

Missing Babel for badminton items in all languages[edit]

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P641 wd:Q7291 . hint:Prior hint:runFirst true .
  ?wen schema:about ?item .  
  ?wen schema:isPartOf ?partOf .
  ?partOf wikibase:wikiGroup "wikipedia" .
  FILTER NOT EXISTS { ?item wdt:P31/wdt:P279* wd:Q4167836 . hint:Prior hint:gearing "forward". }
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q11266439 .}
  FILTER NOT EXISTS { ?item wdt:P2581 [] .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q15184295 .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q11753321 .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q17633526 .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q19887878 .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'en' .}
}
Try it!

Mandantory language option for name in native language[edit]

Q4115189<TAB>P1559<TAB>en:"Name" should work (adding the English monolingual text "Name" to P1559 of Q4115189 in this case).

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Florentyna&oldid=2050593578"