User:Looniverse/Bundestagswahl

Einiges zur Bundestagswahl 2017

• Overpass-Abfrage für OpenStreetMap-Grenz-Relationen der Wahlkreise als csv:

[out:csv(::id,::type,"ref","name","wikidata","wikipedia","election:part","election:year";header;"|")]; area[name="Deutschland"]->.a;( rel(area.a)[political=election]['election:parliament'~'Bundestag'];);out;

Probier es!

• als Karte

• OSM-Wiki-Seite
• Relation #2959029 enthält alle Wahlkreise von 2013

• Abfrage der Mitglieder der Wahlkreisrelation (Mitgliedsrelation)

<osm-script output="csv" output-config="(::id,::type,'name','admin_level','type';true;'|')">
 <query type="relation">
   <has-kv k="type" v="election" />
   <has-kv k="election:parliament"
      v="Deutscher Bundestag" />
   <has-kv k="election:part"
   v="Wahlkreis" />
   <has-kv k="election:year" v="2013" />     
   <has-kv k="ref" v="255"/>  
 </query>
 <union>
   <item/>
   <recurse type="relation-relation"/>
 </union>
 <print/>
</osm-script>

Probier es!

• SPARQL-Abfrage aller Bundestagswahlkreise:

The following query uses these:

• Items: federal electoral district of Germany (Q11703715)   

• Properties: instance of (P31)   , OpenStreetMap relation ID (P402)   , locator map image (P242)   , start time (P580)   , end time (P582)   

  SELECT ?item ?itemLabel ?start ?ende ?osm_rel ?karte
  WHERE
  {
    ?item wdt:P31 wd:Q11703715 .
    ?item p:P31 ?statement .
    OPTIONAL {?statement pq:P580 ?start.}.
    OPTIONAL {?statement pq:P582 ?ende.}.
    OPTIONAL {?item wdt:P402 ?osm_rel.}.
    OPTIONAL {?item wdt:P242 ?karte.}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  }
  ORDER BY ?itemLabel
  

Try it!

• SPARQL-Abfrage der Bundestagswahlkreise 2017:

The following query uses these:

• Items: list of constituencies for the election to the German Bundestag 2017 (Q26971257)   , federal electoral district of Germany (Q11703715)   

• Properties: instance of (P31)   , OpenStreetMap relation ID (P402)   , catalog code (P528)   , start time (P580)   , end time (P582)   , catalog (P972)   

  # Liste der Bundestagswahlkreise 2017
  SELECT ?item ?itemLabel ?start ?ende ?katalogid ?katalog ?katalogLabel ?article #?osm_rel 
  WHERE
  {
   BIND(wd:Q26971257 AS ?katalog)
   ?item wdt:P31 wd:Q11703715 .
   ?item p:P31 ?statement .
   OPTIONAL {?statement pq:P580 ?start.}.
   OPTIONAL {?statement pq:P582 ?ende.}.
   #OPTIONAL {?item wdt:P402 ?osm_rel.}.
   ?item p:P528 ?katalogStatement.
   ?katalogStatement ps:P528 ?katalogid.
   ?katalogStatement pq:P972 ?katalog.
   OPTIONAL {
        ?article schema:about ?item .
        ?article schema:inLanguage "de" .
        ?article schema:isPartOf <https://de.wikipedia.org/> .
      }
   SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  }
  ORDER BY xsd:integer(?katalogid)
  

Try it!

• SPARQL-Abfrage Abgeordnete des 19. Bundestages mit Wahlkreisen:

The following query uses these:

• Items: 19th German Bundestag (Q30579723)   , member of the German Bundestag (Q1939555)   

• Properties: position held (P39)   , parliamentary term (P2937)   , parliamentary group (P4100)   , electoral district (P768)   

  # Mitglieder des Bundestags mit Wahlkreisen
  select ?mdb ?mdbLabel ?periodeLabel ?fraktionLabel ?wahlbezirk ?wahlbezirkLabel
  WHERE {
     BIND(wd:Q30579723 AS ?periode)
      ?mdb p:P39 ?statement.
      ?statement ps:P39 wd:Q1939555;
                 pq:P2937 ?periode.
      OPTIONAL {?statement pq:P4100 ?fraktion.}.
      OPTIONAL {?statement pq:P768 ?wahlbezirk.}.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
  }
  

Try it!