User : MartinPoulter/queries/ee

SELECT ?person ?personLabel ?birthdate WHERE {
  ?person wdt:P3429 ?ee.
  ?person wdt:P21 wd:Q6581072.
  ?person wdt:P106 wd:Q201788.
  ?person wdt:P569 ?birthdate.
  FILTER ((YEAR(?birthdate) > 1729) && (YEAR(?birthdate) < 1740))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Editions of works by Catharine Macaulay, and their online text[edit]

Note: doesn't capture Wikisource transcriptions or Google Books links via Google Books ID (P675)

The following query uses these:

Items: Catharine Macaulay (Q538767)

Properties: author (P50)  

, edition or translation of (P629)  

, title (P1476)  

, English Short Title Catalogue ID (P3939)  

, publication date (P577)  

, edition number (P393)  

, full work available at URL (P953)  

, number of pages (P1104)  

SELECT ?edition ?title ?year ?no ?pages (URI(CONCAT("http://estc.bl.uk/",?estc)) AS ?estc_cit) ?text WHERE {
?work wdt:P50 wd:Q538767. # work by Macaulay
?edition wdt:P629 ?work; # edition of work
 wdt:P1476 ?title; # title of edition
 wdt:P3939 ?estc; # ESTC Citation number
 wdt:P577 ?pubdate.
BIND(YEAR(?pubdate) as ?year) # publication year
OPTIONAL{ ?edition wdt:P393 ?no } # edition number
OPTIONAL{ ?edition wdt:P953 ?text } # work available at
OPTIONAL { ?edition wdt:P1104 ?pages } # no of pages
} ORDER BY ?year ?no

Digital versions of a work that the Oxford Text Archive has, but a different edition from the Oxford Text Archive[edit]

The following query uses these:

Properties: edition or translation of (P629)  

, full work available at URL (P953)  

, publication date (P577)  

, title (P1476)  

, edition number (P393)  

SELECT ?edition2 ?title ?year2 ?text2 ?this_is_no ?ota_has_no WHERE {
?edition1 wdt:P629 ?work; 
    wdt:P953 ?text1;
    wdt:P577 ?pubdate1.
FILTER CONTAINS(STR(?text1),"ota.ox.ac.uk") # OTA scan of work
BIND(YEAR(?pubdate1) as ?year) # publication year  
?edition2 wdt:P629 ?work; # edition of work
    wdt:P953 ?text2;
    wdt:P1476 ?title;
    wdt:P577 ?pubdate2.
FILTER( ?edition1 != ?edition2 ) # non-OTA scan of work
BIND(YEAR(?pubdate2) as ?year2) # publication year
#FILTER{ ?year1 > ?year2 }
OPTIONAL{ ?edition1 wdt:P393 ?ota_has_no } # edition number
OPTIONAL{ ?edition2 wdt:P393 ?this_is_no }
}

Biographies in the Plomer Dictionary of Booksellers and Printers[edit]

The following query uses these:

Items: A Dictionary of the Booksellers and Printers who Were at Work in England, Scotland and Ireland from 1641 to 1667 (Q40901539)

Properties: published in (P1433)  

SELECT ?entry ?wslink WHERE {
  ?entry wdt:P1433 wd:Q40901539. # published in Plomer DBP
OPTIONAL{ ?wslink schema:about ?entry; schema:isPartOf <https://en.wikisource.org/> }
}

Types of edition[edit]

Maps[edit]

Map of birthplaces[edit]

Lots of overlaps due to common birthplaces..

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)   , place of birth (P19)   , coordinate location (P625)   , date of birth (P569)   , image (P18)

Features: map (Q24515275)  

#defaultView:Map
SELECT ?name ?birthyear ?image (SAMPLE(?coord) AS ?coord) (URI(CONCAT("https://doi.org/10.13051/ee:bio/", ?ee)) AS ?eelink)
WHERE {
   ?person wdt:P3429 ?ee;
     wdt:P19 ?place;
     rdfs:label ?name filter (lang(?name) = "en").
   ?place wdt:P625 ?coord
   OPTIONAL { ?person wdt:P569 ?dob }
   BIND(CONCAT("Born ", STR(YEAR(?dob))) as ?birthyear)
   OPTIONAL {?person wdt:P18 ?image }
} GROUP BY ?name ?image ?ee ?birthyear

Wikipedia articles[edit]

EE items that have English Wikipedia articles[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

SELECT ?name (URI(CONCAT("https://doi.org/10.13051/ee:bio/", ?ee)) AS ?eelink) ?englishwp
WHERE {
?person wdt:P3429 ?ee;
        rdfs:label ?name filter (lang(?name) = "en")
?englishwp schema:about ?person; schema:isPartOf <https://en.wikipedia.org/>
} ORDER BY ?ee

Note: as of 13 April 2017, 420 imported EE items lack English Wikipedia articles.

EE items that lack English Wikipedia articles, but have articles in another version of Wikipedia[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

SELECT ?person ?personLabel ?personDescription (URI(CONCAT("https://doi.org/10.13051/ee:bio/", ?ee)) AS ?eelink)
(GROUP_CONCAT(?otherwp) AS ?links)
WHERE {
?person wdt:P3429 ?ee.
MINUS {?englishwp schema:about ?person; schema:isPartOf <https://en.wikipedia.org/> }
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de"}
?otherwp schema:about ?person
FILTER CONTAINS(STR(?otherwp),"wikipedia") 
} GROUP BY ?personLabel ?personDescription ?ee ?person ORDER BY ?ee

EE items with no article in any language version of Wikipedia, with optional links to texts that describe them[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, described by source (P1343)  

SELECT ?person ?personLabel ?personDescription (URI(CONCAT("https://doi.org/10.13051/ee:bio/", ?ee)) AS ?eelink) ?sourcename ?ws
WHERE {
?person wdt:P3429 ?ee.
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de"}
MINUS {?wp schema:about ?person; FILTER CONTAINS(STR(?wp),"wikipedia")  }
OPTIONAL { ?person p:P1343/ps:P1343 ?source. ?source rdfs:label ?sourcename filter (lang(?sourcename) = "en")
OPTIONAL { ?ws schema:about ?source; schema:isPartOf <https://en.wikisource.org/> } }
} ORDER BY ?ee

Depictions[edit]

Image gallery[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)   , image (P18)

Features: ImageGrid (Q24515278)  

#defaultView:ImageGrid
SELECT ?personLabel ?personDescription ?image (URI(CONCAT("https://doi.org/10.13051/ee:bio/", ?ee)) AS ?eelink)
WHERE {
?person wdt:P3429 ?ee;
   wdt:P18 ?image
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,es,it,sv"}
} ORDER BY ?personLabel

EE people without images, including links to searches on the National Portrait Gallery[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, image (P18)  

, National Portrait Gallery (London) person ID (P1816)  

SELECT ?person ?name ?ee (URI(CONCAT("http://www.npg.org.uk/collections/search/person/", ?npg)) AS ?npglink)
WHERE {
?person wdt:P3429 ?ee.
MINUS{?person wdt:P18 []} # no image
OPTIONAL{?person wdt:P1816 ?npg}
?person rdfs:label ?name filter (lang(?name) = "en")
} ORDER BY ?name

Art depicting EE people[edit]

Only shows art for which there is a freely available scan in Wikimedia Commons

The following query uses these:

Items: human (Q5)

Properties: Electronic Enlightenment ID (P3429)  

, depicts (P180)  

, image (P18)  

SELECT ?person ?personLabel ?ee ?art ?artLabel ?image
WHERE {
?person wdt:P3429 ?ee;
   wdt:P31 wd:Q5
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,es,it,sv,ru,pl,nl"}
?art wdt:P180 ?person;
   wdt:P18 ?image
MINUS { ?person wdt:P18 ?image }
} ORDER BY ?personLabel

Organisations[edit]

Organisation membership[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)   , member of (P463)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?orgname (COUNT(?person) AS ?members)
WHERE {
   ?person wdt:P3429 [];
     wdt:P463 ?org.
    ?org rdfs:label ?orgname filter (lang(?orgname) = "en")
} GROUP BY ?orgname
ORDER BY DESC (?members)

Organisations and the individuals who are members[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, member of (P463)  

SELECT DISTINCT ?orgLabel ?person ?personLabel ?ee
WHERE {
?person wdt:P3429 ?ee;
     wdt:P463 ?org
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"}
} ORDER BY ?orgLabel ?ee

Biographical facts[edit]

Bubble chart of occupations[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)   , occupation (P106)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?jobname (COUNT(?person) AS ?members)
WHERE {
   ?person wdt:P3429 ?ee;
      wdt:P106 ?job.
    ?job rdfs:label ?jobname filter (lang(?jobname) = "en")
} GROUP BY ?jobname
ORDER BY DESC (?members)

EE people not tagged with an occupation in Wikidata[edit]

The following query uses these:

Items: human (Q5)

Properties: Electronic Enlightenment ID (P3429)  

, occupation (P106)  

SELECT ?person ?personLabel ?personDescription ?ee
WHERE {
   ?person wdt:P3429 ?ee;
           wdt:P31 wd:Q5
MINUS{?person wdt:P106 [] }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,es" }
} ORDER BY ?ee

Causes of death[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, cause of death (P509)  

SELECT ?person ?personLabel ?ee ?causeLabel  WHERE {
?person wdt:P3429 ?ee;
  wdt:P509 ?cause
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?causeLabel

Other identifiers[edit]

UK National Archive IDs[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, UK National Archives ID (P3029)  

SELECT ?person ?personLabel ?ee (URI(CONCAT("https://discovery.nationalarchives.gov.uk/details/c/",?natarch)) AS ?natarchlink)  WHERE {
?person wdt:P3429 ?ee;
  wdt:P3029 ?natarch
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?personLabel

Project Gutenberg author IDs[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, Project Gutenberg author ID (P1938)  

SELECT ?person ?personLabel ?ee (URI(CONCAT("https://www.gutenberg.org/ebooks/author/", ?gutenberg)) AS ?gutenberglink)  WHERE {
?person wdt:P3429 ?ee;
  wdt:P1938 ?gutenberg
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?personLabel

Genealogics.org person IDs[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, genealogics.org person ID (P1819)  

SELECT ?person ?personLabel ?ee (URI(CONCAT("http://www.genealogics.org/getperson.php?tree=LEO&personID=", ?gorg)) AS ?gorglink)  WHERE {
?person wdt:P3429 ?ee;
  wdt:P1819 ?gorg
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?personLabel

History of Parliament ID[edit]

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

, History of Parliament ID (P1614)  

SELECT ?person ?personLabel ?ee (URI(CONCAT("http://www.historyofparliamentonline.org/volume/", ?parl)) AS ?parllink)  WHERE {
?person wdt:P3429 ?ee;
  wdt:P1614 ?parl
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?personLabel

Letters[edit]

Letters sent by EE entities[edit]

The following query uses these:

Items: letter (Q133492)

Properties: author (P50)  

, Electronic Enlightenment ID (P3429)  

SELECT ?author ?authorLabel ?letter ?letterLabel ?ws
WHERE {
  ?letter wdt:P50 ?author;
   wdt:P31 wd:Q133492.
  ?author wdt:P3429 []
OPTIONAL {?ws schema:about ?letter; schema:isPartOf <https://en.wikisource.org/> }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
} ORDER BY ?authorLabel

Things addressed to EE entities[edit]

The following query uses these:

Properties: addressee (P1817)  

, Electronic Enlightenment ID (P3429)  

SELECT ?recipient ?recipientLabel ?letter ?letterLabel ?ws
WHERE {
  ?letter wdt:P1817 ?recipient.
    ?recipient wdt:P3429 []
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
  OPTIONAL {?ws schema:about ?letter; schema:isPartOf <https://en.wikisource.org/> }
} ORDER BY ?recipientLabel

Maintenance queries[edit]

Wikidata entities with EE IDs[edit]

This highlights entities that have more than one EE ID, and also gives a total count.

The following query uses these:

Properties: Electronic Enlightenment ID (P3429)  

SELECT ?person ?personLabel ?personDescription (COUNT(?ee) AS ?eelinks)
WHERE {
   ?person wdt:P3429 ?ee
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,es" }
} GROUP BY ?person ?personLabel ?personDescription
ORDER BY DESC(?eelinks) ?ee

Early Modern Letters Online[edit]

Years and places of birth and death[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)  

, date of death (P570)  

, place of birth (P19)  

, place of death (P20)  

SELECT DISTINCT ?person ?personLabel (URI(CONCAT("http://emlo.bodleian.ox.ac.uk/profile/person/",?emlo)) AS ?emlolink) ?birthyear (IF(isBLANK(?pob),"unknown",?pobLabel) AS ?birthplace) ?deathyear (IF(isBLANK(?pod),"unknown",?podLabel) AS ?deathplace)
WHERE {
   ?person wdt:P1802 ?emlo;
 OPTIONAL { ?person wdt:P569 ?dob }
 OPTIONAL { ?person wdt:P570 ?dod }
 OPTIONAL { ?person wdt:P19 ?pob }
 OPTIONAL { ?person wdt:P20 ?pod }
BIND(YEAR(?dob) as ?birthyear)
BIND(YEAR(?dod) as ?deathyear)
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,nl,es,pl".
  ?pob rdfs:label ?pobLabel.
  ?pod rdfs:label ?podLabel.
  ?person rdfs:label ?personLabel
  }
} ORDER BY DESC(?birthyear)

Map of birthplaces[edit]

Lots of overlaps due to common birthplaces. Some duplicates because of individuals having multiple EMLO IDs.

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)   , place of birth (P19)   , coordinate location (P625)   , date of birth (P569)   , image (P18)

Features: map (Q24515275)  

#defaultView:Map
SELECT ?name ?birthyear ?image (SAMPLE(?coord) AS ?coord) (URI(CONCAT("http://emlo.bodleian.ox.ac.uk/profile/person/", ?emlo)) AS ?emlolink)
WHERE {
   ?person wdt:P1802 ?emlo;
     wdt:P19 ?place;
     rdfs:label ?name filter (lang(?name) = "en").
   ?place wdt:P625 ?coord
   OPTIONAL { ?person wdt:P569 ?dob }
   BIND(CONCAT("Born ", STR(YEAR(?dob))) as ?birthyear)
   OPTIONAL {?person wdt:P18 ?image }
} GROUP BY ?name ?image ?emlo ?birthyear

Organisation membership[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)   , member of (P463)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?orgname (COUNT(?person) AS ?members)
WHERE {
   ?person wdt:P1802 [];
     wdt:P463 ?org.
    ?org rdfs:label ?orgname filter (lang(?orgname) = "en")
} GROUP BY ?orgname
ORDER BY DESC (?members)

Occupations[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)   , occupation (P106)

Features: BubbleChart (Q24515280)  

#defaultView:BubbleChart
SELECT ?jobname (COUNT(?person) AS ?members)
WHERE {
   ?person wdt:P1802 ?emlo;
      wdt:P106 ?job.
    ?job rdfs:label ?jobname filter (lang(?jobname) = "en")
} GROUP BY ?jobname
ORDER BY DESC (?members)

Timeline of members of the French Academy of Sciences[edit]

The following query uses these:

Items: French Academy of Sciences (Q188771)

Properties: Early Modern Letters Online person ID (P1802)  

, member of (P463)  

, sex or gender (P21)  

, image (P18)  

, occupation (P106)  

, date of death (P570)  

SELECT ?item ?itemLabel ?birthDate ?birthPrecision ?deathDate ?deathPrecision ?pic ?occupation (URI(CONCAT("http://emlo.bodleian.ox.ac.uk/profile/person/", SAMPLE(?emlo))) AS ?emlolink) ?gender
WHERE
{ ?item wdt:P1802 ?emlo;
    wdt:P463 wd:Q188771;
 wdt:P21 ?genderItem .
OPTIONAL { ?item wdt:P18 ?pic }
OPTIONAL {?item wdt:P106 ?occupationItem }
?item p:P569/psv:P569 ?birthDateNode .
?birthDateNode wikibase:timeValue ?birthDate .
?birthDateNode wikibase:timePrecision ?birthPrecision .
OPTIONAL {?item p:P570/psv:P570 ?deathDateNode .
?deathDateNode wikibase:timeValue ?deathDate .
?deathDateNode wikibase:timePrecision ?deathPrecision }

SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
    ?item rdfs:label ?itemLabel .
?occupationItem rdfs:label ?occupation .
    ?genderItem rdfs:label ?gender 
  }
}  GROUP BY ?item ?itemLabel ?birthDate ?birthPrecision ?deathDate ?deathPrecision ?pic ?occupation ?gender

This as a HistropediaJS timeline, colour-coded by occupation

Publications with Wikipedia articles or on-line text[edit]

The following query uses these:

Items: version, edition or translation (Q3331189)

Properties: Early Modern Letters Online person ID (P1802)  

, author (P50)  

, publication date (P577)  

, full work available at URL (P953)  

SELECT ?personLabel ?work ?workLabel ?pubyear ?englishwp ?englishws (SAMPLE(?fulltext) AS ?fulltext)
WHERE {
  ?person wdt:P1802 ?emlo.
  ?work wdt:P50 ?person.  
  MINUS {?work wdt:P31 wd:Q3331189}
OPTIONAL{?work wdt:P577 ?pubdate}
BIND(YEAR(?pubdate) as ?pubyear)
OPTIONAL{ ?englishwp schema:about ?work. ?englishwp schema:isPartOf <https://en.wikipedia.org/> }
OPTIONAL{ ?englishws schema:about ?work. ?englishws schema:isPartOf <https://en.wikisource.org/> }
OPTIONAL{ ?work wdt:P953 ?fulltext }
FILTER (BOUND(?fulltext) || BOUND(?englishwp) || BOUND(?englishws))
SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,es,it,cz"}
} GROUP BY ?personLabel ?work ?workLabel ?pubyear ?englishwp ?englishws
ORDER BY ?personLabel ?pubyear

Timeline with membership of learned and scientific societies[edit]

The following query uses these:

Items: learned society (Q955824)   , scientific society (Q748019)

Properties: Early Modern Letters Online person ID (P1802)  

, member of (P463)  

, subclass of (P279)  

, image (P18)  

, date of death (P570)  

SELECT DISTINCT ?item ?itemLabel ?birthDate ?birthPrecision ?deathDate ?deathPrecision ?pic ?groupLabel (URI(CONCAT("http://emlo.bodleian.ox.ac.uk/profile/person/", SAMPLE(?emlo))) AS ?emlolink)
WHERE
{ ?item wdt:P1802 ?emlo;
         wdt:P463 ?group.
 { ?group wdt:P31/wdt:P279? wd:Q955824 } UNION { ?group wdt:P31/wdt:P279? wd:Q748019 }
OPTIONAL { ?item wdt:P18 ?pic }

?item p:P569/psv:P569 ?birthDateNode .
?birthDateNode wikibase:timeValue ?birthDate .
?birthDateNode wikibase:timePrecision ?birthPrecision .
OPTIONAL {?item p:P570/psv:P570 ?deathDateNode .
?deathDateNode wikibase:timeValue ?deathDate .
?deathDateNode wikibase:timePrecision ?deathPrecision }

SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"
  }
}  GROUP BY ?item ?itemLabel ?birthDate ?birthPrecision ?deathDate ?deathPrecision ?pic ?groupLabel

This timeline in HistropediaJS

Causes of death[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)  

, cause of death (P509)  

SELECT ?person ?personLabel ?emlo ?causeLabel  WHERE {
?person wdt:P1802 ?emlo;
  wdt:P509 ?cause
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?causeLabel

Wikidata entries with more than one EMLO identifier (not counting deprecated identifiers)[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)  

SELECT ?person ?personLabel (URI(CONCAT("http://emlo.bodleian.ox.ac.uk/profile/person/",?emlo1)) AS ?emlolink1) (URI(CONCAT("http://emlo.bodleian.ox.ac.uk/profile/person/",?emlo2)) AS ?emlolink2)
WHERE {
?person wdt:P1802 ?emlo2;
wdt:P1802 ?emlo1.
  FILTER (?emlo1 > ?emlo2)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?personLabel

EMLO identifiers to Wikipedia pages[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)  

SELECT ?emlolink ?wp
WHERE {
  ?entity wdt:P1802 ?emlolink.
OPTIONAL{?enwp schema:about ?entity; schema:isPartOf <https://en.wikipedia.org/>}
OPTIONAL{?dewp schema:about ?entity; schema:isPartOf <https://de.wikipedia.org/>}
OPTIONAL{?frwp schema:about ?entity; schema:isPartOf <https://fr.wikipedia.org/>}
OPTIONAL{?itwp schema:about ?entity; schema:isPartOf <https://it.wikipedia.org/>}
OPTIONAL{?ruwp schema:about ?entity; schema:isPartOf <https://ru.wikipedia.org/>}
OPTIONAL{?svwp schema:about ?entity; schema:isPartOf <https://sv.wikipedia.org/>}
BIND (IF(BOUND(?enwp),?enwp,IF(BOUND(?dewp),?dewp,IF(BOUND(?frwp),?frwp,IF(BOUND(?itwp),?itwp,IF(BOUND(?ruwp),?ruwp,IF(BOUND(?svwp),?svwp,"") ) ) ) ) ) AS ?wp)
FILTER (?wp != "")
}

Which Wikimedia sites have pages about EMLO people?[edit]

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)  

SELECT (COUNT(?emlolink) AS ?count) ?site
WHERE {
  ?entity wdt:P1802 ?emlolink.
  ?page schema:about ?entity; schema:isPartOf ?site
        } GROUP BY ?site
ORDER BY DESC(?count)

Reasonator links for EMLO people[edit]

Delete the ?personLabel and ?personDescription columns if you just want a mapping.

The following query uses these:

Properties: Early Modern Letters Online person ID (P1802)  

SELECT ?personLabel ?personDescription ?emlo (URI(CONCAT("https://tools.wmflabs.org/reasonator/?q=", SUBSTR(STR(?person),32) )) as ?reasonator)
WHERE {
?person wdt:P1802 ?emlo.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,es,po,nl" }
}
ORDER BY ?personLabel

Non-EMLO identifiers for things with an EMLO Person ID[edit]

The following query uses these:

Items: Wikidata property for authority control for people (Q19595382)

Properties: Early Modern Letters Online person ID (P1802)  

, subclass of (P279)  

SELECT ?emlo ?idlabel ?value WITH {
  SELECT DISTINCT ?item ?emlo WHERE {
    ?item wdt:P1802 ?emlo
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  ?id wikibase:propertyType wikibase:ExternalId; wikibase:claim ?p; wikibase:statementProperty ?ps; wdt:P31/wdt:P279* wd:Q19595382 FILTER( ?id != wd:P1802 ).
  ?item ?p [ ?ps ?value ] .
  ?id rdfs:label ?idlabel FILTER (lang(?idlabel) = "en").
} ORDER BY ?idlabel

Mapping between EMLO Location and Wikidata[edit]

SELECT ?q ?qLabel ?qDescription ?emlo_loc WHERE {
?q wdt:P4672 ?emlo_loc.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}