User:Richard Nevell

Babel user information
en-N This user has a native understanding of English. en-GB-N This user has a native understanding of British English. it-0 Questo utente non è in grado di comunicare in italiano (o lo capisce solo con notevole difficoltà). cs-0 Tento uživatel nerozumí česky (nebo rozumí se značnými problémy). de-0 Dieser Benutzer beherrscht Deutsch nicht (oder versteht es nur mit beträchtlichen Schwierigkeiten). es-0 Esta persona no tiene ningún conocimiento del español (o lo entiende con mucha dificultad). fr-0 Cet utilisateur n’a aucune connaissance en français (ou le comprend avec de grandes difficultés). sv-0 Den här användaren har inga kunskaper i svenska (eller förstår det bara med en stor svårighet). la-0 Hic usor aut parum aut nihil Latine scit. cy-0 Nid yw'r defnyddiwr hwn yn medru'r Gymraeg (neu mae'n cael trafferth ei deall). kw-0 Ny wor an devnydhyer ma konvedhes Kernewek (po y gonvedhes gans kaletter dres eghen). ru-0 Этот участник не владеет русским языком (или понимает его с трудом). pl-0 Ten użytkownik nie rozumie języka polskiego (albo ma z nim olbrzymie trudności). ar-0 هذا المستخدم ليس لديه معرفة بالعربية (أو يفهمها بصعوبة بالغة).
Users by language

Worked on:

• Wressle Castle (Q8037764)   
• Gleaston Castle (Q5567411)   
• Tibbers Castle (Q7800318)   
• Castle Studies Trust (Q26224002)   

Will add more to:

• Ballintober Castle (Q26696936)   
• Holt Castle (Q5884534)   
• Pleshey Castle and town enclosure (Q17646397)   
• Caus Castle (Q5054556)   
• Castell Dinas Brân (Q1226281)   
• Pembroke Castle (Q1422235)   
• Clifford Castle and Barbican (Q5132895)   
• Castle Pulverbatch (Q17678771)   
• Lathom House (Q6495928)   

Example queries

UK heritage sites

Map of scheduled monuments

The following query uses these:

• Items: scheduled monument (Q219538)   

• Properties: heritage designation (P1435)   , coordinate location (P625)   

Features: map (Q24515275)   

#Locations of scheduled monuments (29,115 in total as of September 2019 - vastly under-represented in Wales)
#defaultView:Map
SELECT ?label ?coord ?subj
WHERE {
   ?subj wdt:P1435 wd:Q219538 ; # scheduled monument
         wdt:P625 ?coord .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
                         ?subj rdfs:label ?label}
}

Try it!

Map of scheduled monuments without a category on Commons

The following query uses these:

• Items: scheduled monument (Q219538)   

• Properties: heritage designation (P1435)   , coordinate location (P625)   , Commons category (P373)   

Features: map (Q24515275)   

#Locations of scheduled monuments (27,557 in total as of 26 September 2019 - vastly under-represented in Wales)
#defaultView:Map
SELECT ?label ?coord ?subj
WHERE {
   ?subj wdt:P1435 wd:Q219538 ; # scheduled monument
         wdt:P625 ?coord .
  MINUS { ?subj wdt:P373 [] } . # Commons category
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
                         ?subj rdfs:label ?label}
}

Try it!

Map of scheduled monuments with a category on Commons but no image

The following query uses these:

• Items: scheduled monument (Q219538)   

• Properties: heritage designation (P1435)   , coordinate location (P625)   , Commons category (P373)   , image (P18)   

Features: map (Q24515275)   

#Locations of scheduled monuments (150 in total as of 27 September 2019 - vastly under-represented in Wales)
#defaultView:Map
SELECT ?label ?coord ?subj
WHERE {
   ?subj wdt:P1435 wd:Q219538 ; # scheduled monument
         wdt:P625 ?coord ;
         wdt:P373 [] . # Commons category
  MINUS { ?subj wdt:P18 [] } . # image
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
                         ?subj rdfs:label ?label}
}

Try it!

Map of listed buildings with a category on Commons but no image

The following query uses these:

• Items: listed building in the United Kingdom (Q570600)   

• Properties: heritage designation (P1435)   , subclass of (P279)   , coordinate location (P625)   , Commons category (P373)   , image (P18)   

Features: map (Q24515275)   

#Locations of scheduled monuments (4558 in total as of 27 September 2019)
#defaultView:Map
SELECT ?label ?coord ?subj
WHERE {
   ?subj wdt:P1435/wdt:P279* wd:Q570600 ; # listed building
         wdt:P625 ?coord ;
         wdt:P373 [] . # Commons category
  MINUS { ?subj wdt:P18 [] } . # image
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".  
                         ?subj rdfs:label ?label}
}

Try it!

Castles and archaeology

Map of archaeological sites in the United Kingdom

The following query uses these:

• Items: archaeological site (Q839954)   , United Kingdom (Q145)   

• Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , coordinate location (P625)   

Features: map (Q24515275)   

# UK archaeological site on a map (must have coordinates!)
#defaultView:Map
SELECT ?library ?libraryLabel ?coords WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
  ?library (wdt:P31/wdt:P279*) wd:Q839954.
  ?library wdt:P17 wd:Q145.
  ?library wdt:P625 ?coords.
}

Try it!

Map of castles in the United Kingdom

The following query uses these:

• Items: castle (Q23413)   , United Kingdom (Q145)   

• Properties: instance of (P31)   , image (P18)   , subclass of (P279)   , country (P17)   , coordinate location (P625)   

Features: map (Q24515275)   

# Castles on a map (must have coordinates!)
#defaultView:Map{"hide": ["?coords", "?layer"]}
SELECT DISTINCT ?library ?libraryLabel ?coords ?layer WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". 
                          ?type rdfs:label ?layer.
                          ?library rdfs:label ?libraryLabel }
  ?library wdt:P31 ?type .
OPTIONAL { ?library wdt:P18 ?image }.
  ?type wdt:P279* wd:Q23413.
  ?library wdt:P17 wd:Q145.
  ?library wdt:P625 ?coords.
}

Try it!

Castles per year per country

The following query uses these:

• Items: castle (Q23413)   

• Properties: instance of (P31)   , subclass of (P279)   , inception (P571)   , country (P17)   

  #defaultView:BarChart
  SELECT (SAMPLE(?year) AS ?year) (COUNT(?_country) AS ?count) (SAMPLE(?_countryLabel) AS ?_countryLabel) WHERE {
    ?object wdt:P31/wdt:P279* wd:Q23413. # Castles or subtypes
    BIND(STR(YEAR(?_inception)) AS ?year)
    ?object wdt:P571 ?_inception;
            wdt:P17 ?_country.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
                          ?_country rdfs:label ?_countryLabel. }
  }
  GROUP BY ?year ?_country
  ORDER BY ?_countryLabel
  

Try it!

Map of slighted places

The following query uses these:

• Items: slighting (Q2238935)   , archaeological site (Q839954)   

• Properties: significant event (P793)   , coordinate location (P625)   , instance of (P31)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?item ?itemLabel ?layer ?geo WHERE { 
  ?item wdt:P793 wd:Q2238935;
        wdt:P625 ?geo ;
        wdt:P31 ?type .
    FILTER (  ?type !=wd:Q839954 ). #filter archaeological sites from appearing in the layer
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
                            ?type rdfs:label ?layer . 
                            ?item rdfs:label ?itemLabel
}
}

Try it!

Map of slighted places with filters for type

The following query uses these:

• Items: slighting (Q2238935)   , archaeological site (Q839954)   , castle ruin (Q17715832)   

• Properties: coordinate location (P625)   , instance of (P31)   , image (P18)   , significant event (P793)   , point in time (P585)   

Features: map (Q24515275)   

#defaultView:Map{"hide": ["?geo", "?layer"]}
SELECT ?item ?itemLabel ?layer ?geo (year (?date) as ?year) ?image WHERE { 
  ?item p:P793 ?s .
  ?s ps:P793 wd:Q2238935. 
OPTIONAL { ?s pq:P585 ?date }.
  ?item wdt:P625 ?geo ;
        wdt:P31 ?type .
OPTIONAL { ?item wdt:P18 ?image }.
  FILTER (  ?type !=wd:Q839954 ). #filter archaeological sites from appearing in the layer
  FILTER (  ?type !=wd:Q17715832 ). #filter castle ruins from appearing in the layer
    #FILTER ( year (?date) < 1200).  #filter sites slighted after 1200; deactivated by default
    #FILTER ( year (?date) > 1000).  #filter sites slighted before 1000; deactivated by default
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
                            ?type rdfs:label ?layer . 
                            ?item rdfs:label ?itemLabel
}
}

Try it!

Map of sites where an individual has led archaeological fieldwork

The following query uses these:

• Items: Leslie Alcock (Q1032387)   , archaeological site (Q839954)   

• Properties: director of archaeological fieldwork (P4345)   , coordinate location (P625)   , instance of (P31)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?item ?itemLabel ?layer ?geo WHERE { 
  ?item wdt:P4345 wd:Q1032387; #The archaeologist in question
        wdt:P625 ?geo ;
        wdt:P31 ?type .
    FILTER (  ?type !=wd:Q839954 ). #filter archaeological sites from appearing in the layer
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". 
                            ?type rdfs:label ?layer . 
                            ?item rdfs:label ?itemLabel
}
}

Try it!

Map of sites with fieldwork directed by someone employed by/affiliated with/a member of a particular organisation

The following query uses these:

• Properties: director of archaeological fieldwork (P4345)   , employer (P108)   

Features: map (Q24515275)   

#defaultView:Map
SELECT ?item ?itemLabel ?layer ?geo WHERE { 
  ?item wdt:P4345 ?organisation .
         ?organisation ( wdt:P108

Try it!

Authors in a given field without an ADS identifier

The following query uses these:

• Items: prehistoric archaeology (Q2415966)   

• Properties: main subject (P921)   , instance of (P31)   , subclass of (P279)   , part of (P361)   , facet of (P1269)   , author (P50)   , Archaeology Data Service person ID (P6734)   , ORCID iD (P496)   

  #defaultView:Table
  SELECT ?count ?author ?authorLabel (COALESCE(?orcid_, CONCAT("orcid-search/quick-search/?searchQuery=", ?authorLabel)) AS ?orcid) 
  WITH {
    SELECT (count(?work) as ?count) ?author WHERE {
      { ?work wdt:P921/wdt:P31*/wdt:P279* wd:Q2415966 . }
      union { ?work wdt:P921/wdt:P361+ wd:Q2415966 . }
      union { ?work wdt:P921/wdt:P1269+ wd:Q2415966 . }
      ?work wdt:P50 ?author .
      MINUS { ?author wdt:P6734 [] } .
  }
    GROUP BY ?author
  } AS %result
  WHERE {
    INCLUDE %result
            
    # Include optional ORCID iD
    OPTIONAL { ?author wdt:P496 ?orcid_ . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  

Try it!

Archaeological journals

The following query uses these:

• Items: archaeology journal (Q21834496)   

• Properties: instance of (P31)   , published in (P1433)   , cites work (P2860)   

  #defaultView:ScatterChart
  SELECT ?work_count ?citation_count ?journal ?journalLabel 
  WITH {
    SELECT ?work_count ?citation_count ?journal {
      {
        SELECT ?journal (COUNT(?work) AS ?work_count) {
    	    ?journal wdt:P31 wd:Q21834496 .
          ?work wdt:P1433 ?journal .
        }
        GROUP BY ?journal 
      }
      {
        SELECT ?journal (COUNT(?citing_work) AS ?citation_count) {
    	    ?journal wdt:P31 wd:Q21834496 .
          ?work wdt:P1433 ?journal .
          ?citing_work wdt:P2860 ?work . 
        }
        GROUP BY ?journal 
      } 
    }
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  

Try it!

Welsh journals

The following query uses these:

• Items: Welsh Journals (Q2603503)   

• Properties: part of (P361)   , published in (P1433)   , cites work (P2860)   

  #defaultView:ScatterChart
  SELECT ?work_count ?citation_count ?journal ?journalLabel 
  WITH {
    SELECT ?work_count ?citation_count ?journal {
      {
        SELECT ?journal (COUNT(?work) AS ?work_count) {
    	    ?journal wdt:P361 wd:Q2603503 .
          ?work wdt:P1433 ?journal .
        }
        GROUP BY ?journal 
      }
      {
        SELECT ?journal (COUNT(?citing_work) AS ?citation_count) {
    	    ?journal wdt:P361 wd:Q2603503 .
          ?work wdt:P1433 ?journal .
          ?citing_work wdt:P2860 ?work . 
        }
        GROUP BY ?journal 
      } 
    }
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  

Try it!

Castle studies publications

Papers in Chateau Gaillard without the subject of castellology

The following query uses these:

• Items: Château Gaillard. Etudes de castellologie médiévale (Q27443263)   , castellology (Q2941393)   

• Properties: published in (P1433)   , main subject (P921)   

  SELECT ?paper ?paperLabel
  WHERE
  {
      ?paper wdt:P1433 wd:Q27443263 .
      MINUS { ?paper wdt:P921 wd:Q2941393 } .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" }
  }
  

Try it!

People most cited by a particular author

The following query uses these:

• Items: Rachel Swallow (Q42712203)   

• Properties: author (P50)   , cites work (P2860)   , ORCID iD (P496)   

  #defaultView:Table
  SELECT
    ?count
    ?citing_author ?citing_authorLabel
  
    # Either show the ORCID iD or construct part of a URL to search on the ORCID homepage
    (COALESCE(?orcid_, CONCAT("orcid-search/quick-search/?searchQuery=", ENCODE_FOR_URI(?citing_authorLabel))) AS ?orcid)
  WITH {
    SELECT (COUNT(?citing_work) AS ?count) ?citing_author WHERE {
      ?work wdt:P50 wd:Q42712203 .
      ?citing_work ^wdt:P2860 ?work . 
      MINUS { ?citing_work wdt:P50 wd:Q42712203 }
      ?citing_work wdt:P50 ?citing_author .
    }
    GROUP BY ?citing_author 
    ORDER BY DESC(?count)
    LIMIT 500
  } AS %counts
  WITH {
    # An author might have multiple ORCID iDs
    SELECT
      ?count
      ?citing_author
      (SAMPLE(?orcids) AS ?orcid_)
    WHERE {
      INCLUDE %counts
      OPTIONAL { ?citing_author wdt:P496 ?orcids }
    }
    GROUP BY ?count ?citing_author
  } AS %result
  WHERE {
    INCLUDE %result
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh". }
  } 
  ORDER BY DESC(?count)
  

Try it!

Missing authors most cited often by a particular author

http://w.wiki/3i2

Most-cited author name strings for a given subject

https://w.wiki/5wU

Journal articles with lots of outgoing citations but few or no topics

https://w.wiki/6rb

Prolific authors in a journal with VIAF and LCCN IDs

The following query uses these:

• Items: Castellologica Bohemica (Q69499259)   

• Properties: author (P50)   , published in (P1433)   , VIAF ID (P214)   , Library of Congress authority ID (P244)   

  # Prolific authors for a specific journal
  SELECT ?count ?author ?authorLabel ?viaf ?lccn ?example_work ?example_workLabel
  WITH {
    # Count the number of works author by the author publishing in the journal
    SELECT
      ?author
      (COUNT(?work) AS ?count)
      (SAMPLE(?work) AS ?example_work)
    WHERE {
      ?work wdt:P50 ?author ;
            wdt:P1433 wd:Q69499259 .
    }
    GROUP BY ?author
  } AS %result
  WHERE {
    INCLUDE %result 
            
    # Include optional ORCID iD
    OPTIONAL { ?author wdt:P214 ?viaf . }
    OPTIONAL { ?author wdt:P244 ?lccn . }
    
    # Label the results
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  LIMIT 500
  

Try it!

Most cited authors from a field by publications after 2015

The following query uses these:

• Properties: main subject (P921)   , part of (P361)   

  SELECT ?number_of_citations ?author ?authorLabel ?publicationdate ?cited_work_example ?cited_work_exampleLabel
  WITH {
    # Find works about the topic
    SELECT DISTINCT ?work WHERE {
  	  ?work wdt:P921 / (wdt:P361+
  

Try it!

Most works in a field published after a certain date (eg: 2009)

The following query uses these:

• Items: castellology (Q2941393)   

• Properties: publication date (P577)   , main subject (P921)   , instance of (P31)   , subclass of (P279)   , part of (P361)   , facet of (P1269)   , cites work (P2860)   

  # tool: scholia
  #defaultView:Table
  SELECT ?count ?cited_work ?cited_workLabel
  WITH {
    SELECT (count(?work) as ?count) ?cited_work WHERE {
        ?cited_work wdt:P577 ?publicationdate .
      FILTER (?publicationdate > "2009-01-01T00:00:00"^^xsd:dateTime) . #works published on the subject after a certain date
      { ?work wdt:P921/wdt:P31*/wdt:P279* wd:Q2941393 . }
      union { ?work wdt:P921/wdt:P361+ wd:Q2941393 . }
      union { ?work wdt:P921/wdt:P1269+ wd:Q2941393 . }
      ?work wdt:P2860 ?cited_work .
    }
    GROUP BY ?cited_work
  } AS %result
  WHERE {
    INCLUDE %result
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
  }
  ORDER BY DESC(?count)
  LIMIT 200
  

Try it!

Collections

Image gallery of paintings from Kenwood House

The following query uses these:

• Items: painting (Q3305213)   , Kenwood House (Q764804)   , oil paint (Q296955)   

• Properties: instance of (P31)   , subclass of (P279)   , collection (P195)   , creator (P170)   , made from material (P186)   , image (P18)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT DISTINCT ?painting ?paintingLabel ?painterLabel ?image where {
      ?painting wdt:P31/wdt:P279* wd:Q3305213 ;  # any painting (or type of painting)
       wdt:P195 wd:Q764804 ;  # in collection Kenwood House
       wdt:P170 ?painter ; # get painter
       wdt:P186 wd:Q296955 ; # Made with oil paint
       wdt:P18 ?image . # Image from Commons of the artwork
  SERVICE wikibase:label {
       bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,es"
    }
} LIMIT 160

Try it!

Birthplaces of painters in the Kenwood House collection (based on query by Jane Darnell)

The following query uses these:

• Items: painting (Q3305213)   , Kenwood House (Q764804)   

• Properties: instance of (P31)   , subclass of (P279)   , collection (P195)   , creator (P170)   , place of birth (P19)   , coordinate location (P625)   

Features: map (Q24515275)   

#defaultView:Map
SELECT DISTINCT ?painter ?painterLabel ?birthplaceLabel ?geoloc where {
      ?painting wdt:P31/wdt:P279* wd:Q3305213 ;  # any painting (or type of painting)
       wdt:P195 wd:Q764804 ;  # in collection Kenwood House
       wdt:P170 ?painter . # get painter
      ?painter wdt:P19 ?birthplace . # get painter's birthplace
      ?birthplace wdt:P625 ?geoloc . #latitude and longitude
  SERVICE wikibase:label {
       bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,es"
    }
}

Try it!