User:YULdigitalpreservation/ScienceStories

Dora Hoffleit

Science Stories: Using linked open data to explore the scientific research of women

Centering women affiliated with Yale University in the years before undergraduate coeducation.

Grace Hopper

Maxine Singer

Project Description

In honor of the 50th anniversary of undergraduate co-education at Yale, we are building a web application “Science Stories”. This project is focused on transforming metadata related to the publications, scientific specimens, and archival photographs, related to women who earned doctorates at Yale. We will transform metadata from heterogeneous sources into linked open data. We will use the linked open data to power the interactions within the web application. The application itself will allow users to explore the scientific lives of these women through images and descriptions, and will provide pathways back to Yale collections. We aim to increase visibility of scientific research performed by women scientists affiliated with Yale.

The scope of this project includes material related to women, and will involve metadata drawn from Yale University Library, Manuscripts and Archives, and Yale Peabody Museum. We will adopt the International Image Interoperability Framework (Q22682088) (IIIF) and publish the metadata in conformance with the IIIF specification. We will create additional linked open data via the Wikidata platform.

One source of inspiration for this project is the book The Door in the Dream: Conversations With Eminent Women in Science (Q42680943) by Elga Wasserman. This book, written in response to Wasserman’s experiences providing leadership during the transition to co-education at Yale, emphasizes how few women have been elected to the National Academy of Science. We hope to contextualize the work of Yale alumnae within larger conversations about women in science. We will write queries in the SPARQL query language to extract data from Wikidata that will be reused in the web application.

Puzzle Game related to women in science at Yale

• Women in Astronomy at Yale
• Women at Yale

Subpages

• Yale PhDs before 1969 in the sciences
• Bibliography on the Topic of Women in Science
• Women employed by Yale in the sciences before 1969
• Women who got MD from Yale School of Medicine before 1969
• Women research fellows at Yale before 1969
• Material related to Katharine Jeanette Bush
• Material related to Maxine Singer
• Material related to Dorothy M. Horstmann
• Material related to Dorrit Hoffleit
• Material related to Grace Hopper
• Image sources
• The National Academy of Sciences
• Science Awards Honoring Women
• Coeducation
• Data Reports
• Recent Passings

Items named after our Scientists

The following query uses these:

• Items: Grace Hopper (Q11641)   , Maxine Singer (Q7309)   , Dorothy M. Horstmann (Q5298518)   , Dorrit Hoffleit (Q451538)   , Katharine Jeannette Bush (Q6376201)   

• Properties: named after (P138)   

  SELECT ?item ?itemLabel ?scientist ?scientistLabel
  WHERE 
  {
    VALUES ?scientist {wd:Q11641 wd:Q7309 wd:Q5298518 wd:Q451538 wd:Q6376201} .
    ?item wdt:P138 ?scientist .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

People who have won a science award that is named after a woman

The following query uses these:

• Items: science award (Q11448906)   , female (Q6581072)   

• Properties: award received (P166)   , instance of (P31)   , subclass of (P279)   , named after (P138)   , sex or gender (P21)   

  SELECT ?item ?itemLabel ?awardLabel
  WHERE 
  {
    ?item wdt:P166 ?award. 
    ?award wdt:P31/wdt:P279* wd:Q11448906. 
    ?award wdt:P138 ?person. 
    ?person wdt:P21 wd:Q6581072.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women who have served on the National Science Board along with educational institutions

The following query uses these:

• Items: female (Q6581072)   , National Science Board (Q6978271)   

• Properties: sex or gender (P21)   , member of (P463)   , image (P18)   , educated at (P69)   

  SELECT DISTINCT ?item ?image ?itemLabel ?school ?schoolLabel ("00FFFF" AS ?rgb) WHERE {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P463 wd:Q6978271.
    OPTIONAL { ?item wdt:P18 ?image. }
    ?item wdt:P69 ?school.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Scientific Articles that have a woman as the main subject

The following query uses these:

• Items: scholarly article (Q13442814)   , human (Q5)   , female (Q6581072)   

• Properties: instance of (P31)   , main subject (P921)   , sex or gender (P21)   

  SELECT ?article ?articleLabel ?person ?personLabel
  WHERE 
  {
    ?article wdt:P31 wd:Q13442814.
    ?article wdt:P921 ?person.
    ?person wdt:P31 wd:Q5.
    ?person wdt:P21 wd:Q6581072.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Variation that filters occupations to those that are subclasses of scientist

The following query uses these:

• Items: scholarly article (Q13442814)   , female (Q6581072)   , scientist (Q901)   

• Properties: instance of (P31)   , main subject (P921)   , sex or gender (P21)   , occupation (P106)   , subclass of (P279)   

  SELECT ?article ?articleLabel ?person ?personLabel
  WHERE 
  {
    ?article wdt:P31 wd:Q13442814.
    ?article wdt:P921 ?person.
    ?person wdt:P21 wd:Q6581072.
    ?person wdt:P106 ?occupation.
    ?occupation wdt:P279 wd:Q901.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women who have won National Medial of Technology and Innovation

The following query uses these:

• Items: National Medal of Technology and Innovation (Q937629)   , female (Q6581072)   

• Properties: award received (P166)   , sex or gender (P21)   , occupation (P106)   , image (P18)   

  SELECT ?item ?itemLabel ?occLabel ?image  WHERE {
    ?item wdt:P166 wd:Q937629.
    ?item wdt:P21 wd:Q6581072.
    OPTIONAL {?item wdt:P106 ?occ.}
    OPTIONAL {?item wdt:P18 ?image.}
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
    }
  
  }
  

Try it!

Google Doodles honoring women scientists

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , occupation (P106)   , subclass of (P279)   , Google Doodle (P4431)   

  SELECT ?person ?personLabel ?occLabel ?doodle
  WHERE 
  {
    ?person wdt:P21 wd:Q6581072.
    ?person wdt:P106 ?occ.
    ?occ wdt:P279* wd:Q901.
    ?person wdt:P4431 ?doodle.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women members of the Royal Society

The following query uses these:

• Items: Royal Society (Q123885)   , female (Q6581072)   

• Properties: member of (P463)   , sex or gender (P21)   , image (P18)   

  SELECT ?item ?itemLabel ?image
  WHERE 
  {
    ?item wdt:P463 wd:Q123885.
    ?item wdt:P21 wd:Q6581072.
    OPTIONAL {?item wdt:P18 ?image.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women who have an ACM author ID

The following query uses these:

• Items: female (Q6581072)   

• Properties: sex or gender (P21)   , ACM Digital Library author ID (P864)   

  SELECT ?item ?itemLabel ?acmID
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P864 ?acmID
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women who have a DBLP author id

The following query uses these:

• Items: female (Q6581072)   

• Properties: sex or gender (P21)   , DBLP author ID (P2456)   

  SELECT ?item ?itemLabel ?acmID WHERE {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P2456 ?acmID.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women who have archival material at NARA

The following query uses these:

• Items: female (Q6581072)   

• Properties: U.S. National Archives Identifier (P1225)   , sex or gender (P21)   , occupation (P106)   

  SELECT ?person ?personLabel ?occupationLabel ?value 
  {
  	?person wdt:P1225 ?value .
      ?person wdt:P21 wd:Q6581072.
    ?person wdt:P106 ?occupation.
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
  }
  

Try it!

Women scientists optional image material NARA

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: U.S. National Archives Identifier (P1225)   , sex or gender (P21)   , occupation (P106)   , subclass of (P279)   , image (P18)   

  SELECT ?person ?personLabel ?occupationLabel ?value ?image
  {
  	?person wdt:P1225 ?value .
      ?person wdt:P21 wd:Q6581072.
    ?person wdt:P106 ?occupation.
    ?occupation wdt:P279 wd:Q901.
    OPTIONAL {?person wdt:P18 ?image}.
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
  }
  

Try it!

Women who have a Biodiversity Heritage Library creator ID

The following query uses these:

• Items: female (Q6581072)   

• Properties: sex or gender (P21)   , BHL creator ID (P4081)   

  SELECT ?item ?itemLabel ?bhlID
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P4081 ?bhlID
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Scientific Illustrators and Institutional collections

The following query uses these:

{{{query}}}

Try it!

IIIF resources

• IIIF Image API spec
• IIIF Presentation API spec
• Awesome IIIF

IIIF related queries

• The following query uses these:
• Items: human (Q5)   , female (Q6581072)   

• Properties: IIIF manifest URL (P6108)   , depicts (P180)   , instance of (P31)   , sex or gender (P21)   , occupation (P106)   

  SELECT ?item ?itemLabel ?subjectLabel ?occupationLabel ?manifest WHERE {
    ?item wdt:P6108 ?manifest.
    ?item wdt:P180 ?subject.
    ?subject wdt:P31 wd:Q5.
    ?subject wdt:P21 wd:Q6581072.
    ?subject wdt:P106 ?occupation.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

occupations subclass of scientist

The following query uses these:

• Items: human (Q5)   , female (Q6581072)   , scientist (Q901)   

• Properties: IIIF manifest URL (P6108)   , depicts (P180)   , instance of (P31)   , sex or gender (P21)   , occupation (P106)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?subjectLabel ?occupationLabel ?manifest WHERE {
    ?item wdt:P6108 ?manifest.
    ?item wdt:P180 ?subject.
    ?subject wdt:P31 wd:Q5.
    ?subject wdt:P21 wd:Q6581072.
    ?subject wdt:P106 ?occupation.
    ?occupation wdt:P279* wd:Q901.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

IIIF manifests we may want to reuse

• Mary Buckland (Q3296150) Fossil hyaena jaw
• Fossil hyaena jaw different angle
• Hertha Ayrton (Q17522)
• Kathleen Lonsdale (Q7513)
• Getty image Maria Sibylla Merian (Q62530)
• In commons: Plant study with peppers (Q24090664)
• In commons: Plant study with butterflies (Q24090665)
• Full text of Merian's work: https://archive.org/details/MariaSybillaMer00Meri

Women who have a NAS Biographical Memoir

• Linda S. Cordell (Q22808451) NAS Biographical Memoir
• Gertrude Mary Cox (Q450290) NAS Biographical Memoir
• Mary Edmonds NAS Biographical Memoir
• Gertrude B. Elion (Q35703) NAS Biographical Memoir
• Katherine Esau (Q568623) NAS Biographical Memoir
• Frederica de Laguna (Q3615745) NAS Biographical Memoir
• Victoria Fromkin (Q7926717) NAS Biographical Memoir
• Maria Goeppert Mayer (Q57100) NAS Biographical Memoir
• Gertrude Scharff Goldhaber (Q89046) NAS Biographical Memoir
• Mary Ellen Jones (Q6779447) NAS Biographical Memoir
• Marian E. Koshland (Q6761921) NAS Biographical Memoir
• Rebecca Lancefield (Q1545648) NAS Biographical Memoir
• Martha L. Ludwig (Q15989717) NAS Biographical Memoir
• Margaret Mead (Q180099) NAS Biographical Memoir
• Lois K. Miller (Q21664761) NAS Biographical Memoir
• Ruth Patrick (Q513586) NAS Biographical Memoir
• Helen Ranney (Q5703017) NAS Biographical Memoir
• Sarah Ratner (Q7422726) NAS Biographical Memoir
• Julia Hall Bowman Robinson (Q452116) NAS Biographical Memoir
• Margaret Floy Washburn (Q6759414) NAS Biographical Memoir
• Chien-Shiung Wu (Q450317) NAS Biographical Memoir

Women whose occupations are subclasses of scientist who have a NYT person ID

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , New York Times topic ID (P3221)   , occupation (P106)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?value ?occLabel
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P3221 ?value.
    ?item wdt:P106 ?occ.
    ?occ wdt:P279 wd:Q901.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women whose occupations are subclasses of scientist who have a ted tALK sPEAKER id

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , TED speaker ID (P2611)   , occupation (P106)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?value ?occLabel
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P2611 ?value.
    ?item wdt:P106 ?occ.
    ?occ wdt:P279 wd:Q901.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women whose occupations are instance of scientist or subclasses of scientist who have a Ted Talk speaker ID

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , TED speaker ID (P2611)   , occupation (P106)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?value ?occLabel
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P2611 ?value.
    ?item wdt:P106 ?occ.
    {?occ wdt:P31 wd:Q901}
     UNION {?occ wdt:P279* wd:Q901}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women whose occupations are instance of scientist or subclasses of scientist who have a Ted Talk speaker ID with images

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , TED speaker ID (P2611)   , occupation (P106)   , instance of (P31)   , subclass of (P279)   , image (P18)   

  SELECT DISTINCT ?item ?itemLabel ?value ?occLabel ?image
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P2611 ?value.
    ?item wdt:P106 ?occ.
    {?occ wdt:P31 wd:Q901}
     UNION {?occ wdt:P279* wd:Q901}.
    OPTIONAL {?item wdt:P18 ?image}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women occ scientist

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , occupation (P106)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P106 ?occ.
  
    {?occ wdt:P31 wd:Q901}
  
     UNION {?occ wdt:P279* wd:Q901}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women scientists with SNAC id

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , SNAC ARK ID (P3430)   , occupation (P106)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?snacID
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P3430 ?snacID.
    ?item wdt:P106 ?occ.
  
    {?occ wdt:P31 wd:Q901}
  
     UNION {?occ wdt:P279* wd:Q901}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women w bio in Am Nat Bio

The following query uses these:

• Items: female (Q6581072)   

• Properties: American National Biography ID (P4823)   , sex or gender (P21)   , occupation (P106)   

  SELECT ?item ?itemLabel ?value ?occ ?occLabel
  {
  	?item wdt:P4823 ?value .
      ?item wdt:P21 wd:Q6581072.
    ?item wdt:P106 ?occ.
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
  }
  

Try it!

Women in Harvard Index of Botanists

The following query uses these:

• Items: female (Q6581072)   

• Properties: Harvard Index of Botanists ID (P6264)   , sex or gender (P21)   

  SELECT ?item ?itemLabel ?value 
  {
  	?item wdt:P6264 ?value .
      ?item wdt:P21 wd:Q6581072.
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
  }
  

Try it!

Works that are avail on the web by women scientists

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , occupation (P106)   , subclass of (P279)   , author (P50)   , full work available at URL (P953)   

  SELECT DISTINCT ?item ?itemLabel ?occLabel ?work ?workLabel ?link
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P106 ?occ.
    ?occ wdt:P279* wd:Q901.
    ?work wdt:P50 ?item.
    ?work wdt:P953 ?link
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Filtered to people who have passed

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   

• Properties: sex or gender (P21)   , occupation (P106)   , date of death (P570)   , instance of (P31)   , subclass of (P279)   , author (P50)   , full work available at URL (P953)   

  SELECT DISTINCT ?item ?itemLabel ?date ?occLabel ?work ?workLabel ?link
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P106 ?occ.
    ?item wdt:P570 ?date.
    {?occ wdt:P31 wd:Q901}
     UNION {?occ wdt:P279* wd:Q901}.
    ?work wdt:P50 ?item.
    ?work wdt:P953 ?link
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Specific occupations

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   , physicist (Q169470)   , social psychologist (Q16611554)   , biologist (Q864503)   , botanist (Q2374149)   , zoologist (Q350979)   , chemist (Q593644)   , carcinologist (Q16868721)   , marine biologist (Q3640160)   , computer scientist (Q82594)   , mathematician (Q170790)   , information scientist (Q1265807)   , engineer (Q81096)   

• Properties: sex or gender (P21)   , SNAC ARK ID (P3430)   , occupation (P106)   

  SELECT ?item ?itemLabel ?snacID 
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P3430 ?snacID.
    {?item wdt:P106 wd:Q901}
  
     UNION {?item wdt:P106 wd:Q169470} #physicist
    UNION {?item wdt:P106 wd:Q16611554} #social_psychologist
    UNION {?item wdt:P106 wd:Q864503} #biologist
    UNION {?item wdt:P106 wd:Q2374149} #botanist
    UNION {?item wdt:P106 wd:Q350979} #zoologist
    UNION {?item wdt:P106 wd:Q593644} #chemist
    UNION {?item wdt:P106 wd:Q16868721} #carcinologist
    UNION {?item wdt:P106 wd:Q3640160} #marine_biologist
    UNION {?item wdt:P106 wd:Q82594} #computer_scientist
    UNION {?item wdt:P106 wd:Q170790} #mathematician
    UNION {?item wdt:P106 wd:Q1265807} #information_scientist
    UNION {?item wdt:P106 wd:Q81096} #engineer
    UNION {?item wdt:P106 wd:entomologist} #entomologist
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

specific occupations passed

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   , physicist (Q169470)   , social psychologist (Q16611554)   , biologist (Q864503)   , botanist (Q2374149)   , zoologist (Q350979)   , chemist (Q593644)   , carcinologist (Q16868721)   , marine biologist (Q3640160)   , computer scientist (Q82594)   , mathematician (Q170790)   , information scientist (Q1265807)   , engineer (Q81096)   

• Properties: sex or gender (P21)   , date of death (P570)   , occupation (P106)   

  SELECT ?item ?itemLabel ?date
  
  WHERE 
  
  {
  
    ?item wdt:P21 wd:Q6581072.
  
    ?item wdt:P570 ?date.
  
    {?item wdt:P106 wd:Q901}
  
  
     UNION {?item wdt:P106 wd:Q169470} #physicist
  
    UNION {?item wdt:P106 wd:Q16611554} #social_psychologist
  
    UNION {?item wdt:P106 wd:Q864503} #biologist
  
    UNION {?item wdt:P106 wd:Q2374149} #botanist
  
    UNION {?item wdt:P106 wd:Q350979} #zoologist
  
    UNION {?item wdt:P106 wd:Q593644} #chemist
  
    UNION {?item wdt:P106 wd:Q16868721} #carcinologist
  
    UNION {?item wdt:P106 wd:Q3640160} #marine_biologist
  
    UNION {?item wdt:P106 wd:Q82594} #computer_scientist
  
    UNION {?item wdt:P106 wd:Q170790} #mathematician
  
    UNION {?item wdt:P106 wd:Q1265807} #information_scientist
  
    UNION {?item wdt:P106 wd:Q81096} #engineer
  
    UNION {?item wdt:P106 wd:entomologist} #entomologist
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  
  }
  

Try it!

Women who passed in 1947- works should now be in public domain

The following query uses these:

• Items: human (Q5)   , female (Q6581072)   

• Properties: instance of (P31)   , sex or gender (P21)   , occupation (P106)   , date of death (P570)   

  SELECT DISTINCT ?item ?itemLabel ?occ ?occLabel WHERE
  {
    ?item wdt:P31 wd:Q5 .
    ?item wdt:P21 wd:Q6581072.
    OPTIONAL {?item wdt:P106 ?occ}.
    ?item wdt:P570 ?time0 .
    FILTER((?time0 >= "1947-01-01T00:00:00Z"^^xsd:dateTime) && (?time0 <= "1948-01-01T00:00:00Z"^^xsd:dateTime))
  
     SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Women who have passed educated at stanford

The following query uses these:

• Items: female (Q6581072)   , scientist (Q901)   , Stanford University (Q41506)   

• Properties: sex or gender (P21)   , date of death (P570)   , occupation (P106)   , subclass of (P279)   , educated at (P69)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P21 wd:Q6581072.
    ?item wdt:P570 ?date. 
    ?item wdt:P106 ?occ. 
    ?occ wdt:P279* wd:Q901.
    ?item wdt:P69 wd:Q41506.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software named after women

The following query uses these:

• Items: software (Q7397)   , female (Q6581072)   

• Properties: instance of (P31)   , subclass of (P279)   , named after (P138)   , sex or gender (P21)   , image (P18)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT DISTINCT ?item ?itemLabel ?after ?afterLabel ?image WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q7397.
  ?item wdt:P138 ?after.
  ?after wdt:P21 wd:Q6581072.
   OPTIONAL { ?after wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Women who have passed with Dictionary Grierson ID

The following query uses these:

• Items: female (Q6581072)   

• Properties: Dictionary Grierson ID (P3946)   , sex or gender (P21)   , date of death (P570)   , image (P18)   

  SELECT ?item ?itemLabel ?value ?image
  WHERE 
  {
    ?item wdt:P3946 ?value .
      ?item wdt:P21 wd:Q6581072.
    ?item wdt:P570 ?date.
    OPTIONAL {?item wdt:P18 ?image}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Items with IMDB id that have a woman listed as a main subject

The following query uses these:

• Items: human (Q5)   , female (Q6581072)   

• Properties: IMDb ID (P345)   , main subject (P921)   , instance of (P31)   , sex or gender (P21)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P345 ?imdb.
    ?item wdt:P921 ?subject. 
    ?subject wdt:P31 wd:Q5. 
    ?subject wdt:P21 wd:Q6581072.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

listing occupation

The following query uses these:

• Items: human (Q5)   , female (Q6581072)   

• Properties: IMDb ID (P345)   , main subject (P921)   , instance of (P31)   , sex or gender (P21)   , occupation (P106)   

  SELECT ?item ?itemLabel ?subjectLabel ?occupation
  WHERE 
  {
    ?item wdt:P345 ?imdb.
    ?item wdt:P921 ?subject. 
    ?subject wdt:P31 wd:Q5. 
    ?subject wdt:P21 wd:Q6581072.
    ?subject wdt:P106 ?occupation.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Related Work

• Darwin-SW: Darwin Core-based terms for expressing biodiversity data as RDF (Q44943965)
• Towards a biodiversity knowledge graph (Q44944149)
• The BiSciCol Triplifier: bringing biodiversity data to the Semantic Web (Q30586018)
• Semantics in support of biodiversity knowledge discovery: an introduction to the biological collections ontology and related ontologies (Q28658282)
• Darwin Core: an evolving community-developed biodiversity data standard (Q21560880)