Wikidata:Synia:actor

Synia: actor

PREFIX target: <http://www.wikidata.org/entity/Q294647>

SELECT
  ?description ?descriptionLabel

  ?value ?valueLabel ?valueUrl ?valueDescription
 
  ?wikidata ?wikidataUrl
WHERE {
  {
    BIND(1 AS ?order)
    BIND(wd:Q82799 AS ?description)
    BIND(target: AS ?value)
    BIND("Wikidata ↗" AS ?wikidata)
    BIND(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(?value), 32)) AS ?wikidataUrl)
  }
  UNION
  {
    BIND(2 AS ?order)
    BIND(wd:Q47223 AS ?description)
    target: wdt:P569 ?birthday_time .
    BIND(xsd:date(?birthday_time) AS ?value)
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} 
ORDER BY ?order

Try it!

Films

PREFIX target: <http://www.wikidata.org/entity/Q294647>

SELECT
  (xsd:date(?release_datetime) AS ?release_date)

  ?film ?filmLabel
  (CONCAT("#film/", SUBSTR(STR(?film), 32)) AS ?filmUrl)
  ?filmDescription
WITH {
  SELECT
    (MIN(?release_datetimes) AS ?release_datetime)
    ?film
  WHERE {
    ?film wdt:P161 target: .
    OPTIONAL {
      ?film wdt:P577 ?release_datetimes .
    }
  }
  GROUP BY ?film
} AS %films
WHERE {
  INCLUDE %films
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?release_date)

Try it!

Films by year

#defaultView:BarChart
PREFIX target: <http://www.wikidata.org/entity/Q294647>

SELECT
  (STR(?year_) AS ?year)
  (COUNT(?film) AS ?films)
WITH {
  SELECT
    (YEAR(MIN(?release_datetimes)) AS ?year_)
    ?film
  WHERE {
    ?film wdt:P161 target: ;
          wdt:P577 ?release_datetimes .
  }
  GROUP BY ?film
} AS %films
WHERE {
  INCLUDE %films
}
GROUP BY ?year_

Try it!

Co-appearances

PREFIX target: <http://www.wikidata.org/entity/Q294647>

SELECT
  ?coappearances

  ?actor ?actorLabel
  (CONCAT("#actor/", SUBSTR(STR(?actor), 32)) AS ?actorUrl)
  ?actorDescription

  ?example_film ?example_filmLabel
  (CONCAT("#film/", SUBSTR(STR(?example_film), 32)) AS ?example_filmUrl)
WITH {
  SELECT
    (COUNT(?film) AS ?coappearances)
    ?actor
    (SAMPLE(?film) AS ?example_film)
  WHERE {
    ?film wdt:P161 ?actor, target: .
    FILTER (target: != ?actor)
  }
  GROUP BY ?actor
  ORDER BY DESC(?coappearances)
  LIMIT 500
} AS %actors
WHERE {
  INCLUDE %actors
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?coappearances)

Try it!

Co-appearance graph

#defaultView:Graph
PREFIX target: <http://www.wikidata.org/entity/Q294647>

SELECT DISTINCT
  ?actor1 ?actor1Label
  ?actor2 ?actor2Label
WITH {
  SELECT 
    (COUNT(?film) AS ?films)
    ?actor1
    ?actor2
  WHERE {
    ?film wdt:P161 target:, ?actor1, ?actor2 .
    FILTER (target: != ?actor1)
    FILTER (target: != ?actor2)
    FILTER (?actor1 != ?actor2)
  }
  GROUP BY ?actor1 ?actor2
  HAVING (?films > 1)
} AS %actors
WHERE {
  INCLUDE %actors
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!