Talk:Q38074555
Jump to navigation
Jump to search
Autodescription — QID milestone (Q38074555)
description: milestone related to the numbering of items in Wikidata
- Useful links:
- View it! – Images depicting the item on Commons
- Report on constraint conformation of “QID milestone” claims and statements. Constraints report for items data
- See also
- This documentation is generated using
{{Item documentation}}
.
Source[edit]
Dates are from Wikidata:News or edit history of item.
Queries[edit]
Query for milestone chart over time[edit]
- Items used: QID milestone (Q38074555)
- Properties used: quantity (P1114) , point in time (P585)
#defaultView:LineChart
# by Jura1, 2017-08-28
SELECT ?date ?qid (URI(CONCAT("https://www.wikidata.org/w/index.php?title=Q",str(?qid),"&action=history")) as ?check)
{
wd:Q38074555 p:P1114 [ ps:P1114 ?qid ; pq:P585 ?date ]
}
ORDER BY ?qid
Query for approximate creation dates of a series of items[edit]
- Items used: Australia (Q408) , QID milestone (Q38074555)
- Properties used: country (P17) , quantity (P1114) , point in time (P585)
# by Jura1, 2019-06-08
# Number of items about Australia created at a given milestone
#defaultView:AreaChart
SELECT ?date ?cumulativecount
{
hint:Query hint:optimizer "None".
{ SELECT ?milestonep (COUNT(?item) as ?cumulativecount)
WHERE
{
{ SELECT ?item { ?item wdt:P17 wd:Q408 } LIMIT 190000 }
BIND( xsd:integer( substr(str(?item), 33)) as ?qid)
wd:Q38074555 p:P1114 ?milestonep .
?milestonep ps:P1114 ?milestone .
FILTER( ?milestone > ?qid )
}
GROUP BY ?milestonep
}
?milestonep pq:P585 ?date
}
- Neat idea! --Daniel Mietchen (talk) 03:55, 13 June 2019 (UTC)
Query for approximate creation dates of a series of items (> 200,000 items)[edit]
- Items used: France (Q142) , QID milestone (Q38074555)
- Properties used: quantity (P1114) , point in time (P585)
#adapted by 99of9, 11 June 2019
#[[Wikidata:Request_a_query/Archive/2019/06#dateCreated_instead_of_dateModified?]]
# Number of items about France created at a given milestone
#defaultView:LineChart
SELECT (SAMPLE(?date) AS ?date) (SUM(?count) AS ?cumulative_count) ?milestone
{
{ SELECT ?qid_rounded (count(?item) AS ?count) (SAMPLE(?item) AS ?exampleitem) WHERE {
?item ?property wd:Q142 .
BIND( xsd:integer( substr(str(?item), 33)) as ?qid)
BIND(xsd:integer(?qid/50000) as ?qid_cut)
BIND(?qid_cut*50000 as ?qid_rounded)
#SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } .
}
GROUP BY ?qid_rounded
}
wd:Q38074555 p:P1114 ?milestonep .
?milestonep ps:P1114 ?milestone .
FILTER(?milestone > ?qid_rounded) .
?milestonep pq:P585 ?date .
}
GROUP BY ?milestone
Items with approximate age (in years)[edit]
- Items used: Mersenne prime (Q186875) , QID milestone (Q38074555)
- Properties used: instance of (P31) , quantity (P1114) , point in time (P585)
# by Jura1, 2019-09-13
SELECT
?item ?itemLabel ?itemDescription
?st ?ids ?sl
(MIN(?age) as ?age_years)
WHERE
{
?item wdt:P31 wd:Q186875 .
?item wikibase:statements ?st ; wikibase:identifiers ?ids ; wikibase:sitelinks ?sl .
wd:Q38074555 p:P1114 [ ps:P1114 ?milestone ; pq:P585 ?d ]
FILTER( ?milestone < xsd:integer(STRAFTER(str(?item),"Q")))
BIND(ROUND((NOW()-?d)/36.5)/10 as ?age)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
GROUP BY ?item ?itemLabel ?itemDescription ?st ?ids ?sl
ORDER BY ?age_years
See also[edit]
- PID milestone (Q73616850): Talk:Q73616850
- LID milestone (Q55003547): Talk:Q55003547
- edit number milestone (Q66002030): Talk:Q66002030