User:Awinkler3/BiB2WD

BiB2WD-Workshop (April 2024)

Präliminiarien

Über den Workshop

Der eintägige Workshop (netto ca. 4,5 Std.) bietet eine praxisorientierte Einführung in die Nutzung von Wikidata im GLAM-Kontext.

Als Grundlage für den Workshop dienen die Daten aus dem Projekt Bildhauerei in Berlin.

Der Workshop unterteilt sich inhaltlich in 3 Blöcke und sieht verschiedene praktische Übungen vor, in denen die Teilnehmenden an und mit BiB-bezogenen Daten auf Wikidata arbeiten.

Im Workshop sollen Potenziale aufgezeigt und Workflows demonstriert und eingeübt werden. Er versteht sich jedoch keine vollumfängliche Einführung in die einzelnen Teilgebiete, von denen jedes bequem Gegenstand eines eigenen Workshops werden könnte.

In diesem Dokument werden regelmäßig Ressourcen verlinkt, die eine Wiederholung und Vertiefung der Workshopinhalte ermöglichen.

Voraussetzungen

Es werden keine besonderen Kenntnisse vorausgesetzt.

Teilnehmende sollten für die Veranstaltung jedoch über einen Wikimedia-Account verfügen. Dieser ist kostenlos und datensparsam einzurichten: Special:CreateAccount.

Für die Übungen wird mit dem quelloffenen Tool Open Refine gearbeitet, das diesem hier heruntergeladen werden kann. Alternativ kann OpenRefine auch über das JupyterHub von Wikimedia verwendet werden [1]. Hierzu wird lediglich ein Wikimedia-Account vorausgesetzt.

Programm

Block	Thema	Inhalte	Hands on
1	Einführung	Allgemein zu Wikidata, Datenmodell	Statements, Quellen, Referenzen über Web-Interface ergänzen
2	Batch modifications	Mehrere Edits mit Quickstatements, Reconciliation mit OpenRefine
3	Workflows, Fragen, Überhang	...	...

Block 1: Was ist Wikidata?

Wikidata in Kürze

Wikidata gibt es seit 2012. Sie ist ein Schwesterprojekt zu Wikipedia. Während Wikipedia Information insbesondere in Textform und v.a. zur Verarbeitung durch Menschen bereithält, speichert Wikidata sowohl menschen- als auch maschinenlesbare strukturierte Information.

Daten in Wikidata sind CC0-lizenziert. Sie können frei editiert und verwendet werden.

Es gibt für Wikidata relativ niedrige Relevanzanforderungen, sodass nahezu beliebige Entitäten aufgenommen werden können. Es reicht, wenn eine der folgenden drei Bedingungen erfüllt ist:

• Eintrag enthält einen Verweis auf ein Wikimedia-Projekt (z.B. Wikipedia-Seite)
• Eintrag enthält einen Quellenbeleg (Publikation, Internetlink, Katalogisat etc.)
• Eintrag wird in einem anderen Wikidata-Eintrag referenziert

Erfahrungsgemäß werden Einträge zu nachvollziehbar relevanten Entitäten nicht gelöscht, auch wenn die Kriterien zunächst nicht erfüllt sind. Es gibt aber aucht Ausnahmen, vgl. z.B. aus dem digiS-Kontext Heinz-Günter Kupers Beitrag zu den Malweibern [2]. Gerade bei größereren Uploads bietet es sich an, einen Weg zu finden, die Kriterien von Beginn an systematisch zu erfüllen.

Wikidata ist eine (sehr große) Wikibase-Instanz [3].

Wikidata versteht sich zudem als tertiäre Datenbank, die gesicherte Information aus Sekundärquellen zusammenträgt. Sie ist nicht im eigentlichen Sinn eine Datenbank für primäre, mitunter noch unsichere oder hypothetische Forschungsdaten. Für derlei Daten (inbes. aus den Geschichtswissenschaften) steht z.B. FactGrid [4] zur Verfügung.

Die offene Wikibase-Software lässt sich jedoch auch lokal installieren oder neuerdings auch über eine Cloud benutzen [5]. So reizvoll der Aufbau einer eigenen Instanz (mit der entsprechenden Kontrolle) aus ist, sollte der Aufwand nicht unterschätzt werden, der z.B. mit dem Aufbau einer schlüssigen Ontologie verbunden ist.

Für GLAM-Einrichtungen ist Wikidata in aller Regel die Plattform der Wahl.

Wikidata im GLAM-Sektor

• Wikidata fungiert als Normdaten-Hub, der Identifikatoren aus verschiedenen Quellen zusammenträgt
• mit Wikidata lassen sich "Normdaten" (stabil referenzierbare Datensätze) generieren. Wo es also z.B. noch keinen GND-Eintrag gibt (und vielleicht nie geben wird), kann ein Wikidata-Item erstellt werden, das die Entität eindeutig identifiziert.
• in Wikidata lassen sich beliebige Informationen verzeichnen, es können also auch Informationen festgehalten werden, die über die Objektbeschreibung hinausgehen und damit im Erschließungssystem keinen Platz finden
• Wikidata-Daten können von der Community angereichert und nachgenutzt werden (Stichwort "data roundtripping"[6])
• Wikidata bietet eine offene Schnittstelle an, mit der programmatisch auf Daten zugegriffen werden kann

Nützliche Ressourcen

- Wikidata-Hilfe

Daten in Wikidata

Datenmodell

Datenobjekt

Zentrale Entität von Wikidata ist das Datenobjekt (Item). Jedes Datenobjekt verfügt über eine eindeutige ID (bestehend aus Q und einer Ziffernfolge, daher auch der Name Q-ID). Jedes Datenobjekt ist über eine URL (z.B. https://www.wikidata.org/wiki/Q42) erreichbar und vefügt über einen Konzept-URI (z.B. http://www.wikidata.org/entity/Q42). Mit diesem Konzept-URI ist die Entität dauerhaft eindeutig referenzierbar.

Datenobjekte können für jede beliebige Entität (Statuen, Personen, Themen, Orte ...) definiert werden.

In der Praxis dürften Items v.a. für Personen (Paul Brandenburg (Q2058972), Firmen (Aktien-Gesellschaft Gladenbeck (Q25245329)), Vereine (Verein für die Geschichte Berlins (Q1299943)), Objekte (Hand mit Uhr (Q15112130)) und Publikationen (Q121951907) erstellt werden.

Aussagen

Zu einem Datenobjekt können verschiedene Aussagen (statements) gespeichert werden. Eine Aussage besteht aus einer Eigenschaft (property) und einem Objekt. Das Objekt kann seinerseits ein Datenobjekt oder aber ein Zeichenkette, ein Datum o.ä. sein.

Eine Aussage entspricht einem einfachen Satz bestehend aus Subjekt (Item), Prädikat (Property) und Objekt.

Vgl. z.B. folgende Aussage:

Der "Satzbau" eines Wikidata-Statements

Subjekt	Prädikat	Objekt
Prussian National Monument for the Liberation Wars (Q819820)	location (P276)	Viktoriapark (Q566495)
Das Nationaldenkmal für die Befreiungskriege	hat als Standort	den Viktoriapark

Das Subjekt muss immer eine Wikidata-Objekt (mit Q-ID) sein und das Prädikat eine Property (mit P-ID). Als Objekt sind mitunter unterschiedliche Datentypen (neben Items mit Q-ID z.B. Zahlen, Zeichenfolgen, URLs, Datumsangaben, externe Identifikatoren, Geokoordinaten) möglich.

Eigenschaften

Eigenschaften (properties) sind definierte Relationen zwischen Objekten.

Wikidata enthält zahlreiche Properties und Information lässt sich mitunter unterschiedlich modellieren.

Bei größeren Projekten sollte man sich vorher ein Datenmodell (im Wesentlichen eine Liste verpflichtender bzw. optionaler Eigenschaften) überlegen. Es bietet sich an, bestehende vergleichbare Datensätze zu betrachten oder sich an eingschlägigen Projekten zu orientieren. Für GLAM-Objekte lohnt z.B. ein Blick auf das Projekt WikiProject sum of all paintings, das Vorschläge zur Item-Struktur macht.

Eigentschaften können nicht ohne Weiteres erstellt werden. Es muss vielmehr ein entsprechender Wikidata:Property_proposal/de unterbreitet werden. In aller Regel dürfte dies jedoch nur für externe Identifikatoren (z.B. Datenbank- oder Katalognummern) in Frage kommen.

Daten bearbeiten

Daten lassen sich auf Wikidata über die Website ändern. Ein Klick auf edit, add statement etc. öffnet ein editierbares Formularfeld.

Ressourcen

• Aussagen hinzufügen
• Qualifikatoren ergänzen
• Belege ergänzen
• Datenobjekt erstellen

Daten abfragen

Die Datenabfrage erfolgt mit dem Wikidata:SPARQL_query_service (erreichbar unter [7]).

Die Abfragesprache heißt SPARQL.

Während SPARQL-Queries beliebig komplex werden können, ist die Grundidee hinter einfachen (aber nützlichen Queries) relativ einfach.

Die Basis-Syntax lautet:

SELECT ?variable1 ?variable2 WHERE {
  SUBJEKT PRÄDIKAT OBJEKT .
  }

Try it!

Subjekt, Prädikat, Objekt können dabei entweder konkrete Objekte (Q-IDs, P-IDs) bzw. Werte (z.B. Zeichenfolgen) oder aber Variablen (? + String) sein. Bei der Abfrage werden alle möglichen Variablen ausgegeben, für die Aussagen wahr sind.

Q-IDs wird die Namensraumangabe wd: vorangestellt, P-IDs wdt:.

Folgender SPARQL-Query listet alle Objekte der Klasse statue (Q179700) auf:

SELECT ?statue WHERE {
  ?statue wdt:P31 wd:Q179700 .
  }

Try it!

Statuen an einem Ort (location (P276)), der in Berlin (Q64) liegt (located in the administrative territorial entity (P131)):

SELECT DISTINCT ?statue WHERE {
  ?statue wdt:P31 wd:Q179700 .
  ?statue wdt:P276 ?ort .
  ?ort wdt:P131 wd:Q64 .
  }

Try it!

Vgl. demgegenüber:

SELECT DISTINCT ?statue WHERE {
  ?statue wdt:P31 wd:Q179700 .
  ?statue wdt:P276 ?ort .
  ?ort wdt:P131* wd:Q64 .
  }

Try it!

BiB-relevante Queries

#title: Objekte mit Verweis auf Beschreibung in BiB (P1343 od. P973)
SELECT DISTINCT ?place ?placeLabel WHERE {
  {
  ?place wdt:P1343 wd:Q111792585 .
   } UNION {
      ?place wdt:P973 ?url .
   FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
    }

   SERVICE wikibase:label {
   bd:serviceParam wikibase:language "de" . 
   }
}

Objekte mit Verweis auf Beschreibung in BiB (P1343 od. P973)

#title: Klassen der Objekte mit Verweis auf Beschreibung in BiB (P1343 od. P973)
SELECT DISTINCT ?class ?classLabel (COUNT(?class) AS ?n) WHERE {
  {
  ?place wdt:P1343 wd:Q111792585 .
   } UNION {
      ?place wdt:P973 ?url .
   FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
    }
  
  ?place wdt:P31 ?class .

   SERVICE wikibase:label {
   bd:serviceParam wikibase:language "de" . 
   }
  }
  GROUP BY ?class ?classLabel ORDER BY DESC(?n)

Klassen der Objekte mit Verweis auf Beschreibung in BiB (P1343 od. P973)

#title: Denkmale in Berlin
SELECT ?object ?objectLabel ?creator ?creatorLabel ?coords ?img WHERE {
  VALUES ?werk { wd:Q860861 wd:Q4989906 } # definiert Objektkategorien
  ?object wdt:P31 ?werk ;
          wdt:P131* wd:Q64 . # im Raum Berlin
  OPTIONAl { ?object wdt:P625 ?coords . }
  OPTIONAL { ?object wdt:P18 ?img. }
  OPTIONAL { ?object wdt:P170 ?creator . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels
  }

Denkmale in Berlin

#title: Statements mit BiB-URL als Referenz
SELECT ?object ?objectLabel ?p ?URL WHERE {
  VALUES ?werk { wd:Q860861 wd:Q4989906 } # definiert Objektkategorien
  ?object wdt:P31 ?werk ;
          wdt:P131* wd:Q64 . # im Raum Berlin
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels
  }

Statements mit BiB-URL als Referenz

#title: Objekte von BiB-relevanten Klassen im Umkreis von 20 km um das Zentrum Berlins

#Problem: Kategorie "Denkmal" ist sehr umfassend und wenigs präzise
SELECT DISTINCT ?obj ?objLabel ?location
WiTH {
  #title: Klassen der Objekte mit Verweis auf Beschreibung in BiB (P1343 od. P973)
  SELECT DISTINCT ?class (COUNT(?class) AS ?n) WHERE {
  {
  ?place wdt:P1343 wd:Q111792585 .
   } UNION {
      ?place wdt:P973 ?url .
   FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
    }
  
  ?place wdt:P31 ?class .

   }
  GROUP BY ?class  ORDER BY DESC(?n) LIMIT 5
} AS %i
WHERE {
  INCLUDE %i
          wd:Q64 wdt:P625 ?berlincoords .
          SERVICE wikibase:around {
            
          ?obj wdt:P625 ?location .
            ?obj wdt:P31 ?class .
           
            bd:serviceParam wikibase:center ?berlincoords . 
     # Where the circle has a radius of XX km
     bd:serviceParam wikibase:radius "20" . 
   } .
  
          SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Objekte von BiB-relevanten Klassen im Umkreis von 20 km um das Zentrum Berlins

#title: Objekte aus ausgewählten BiB-relevanten Klassen im Umkreis von 20 km um das Zentrum Berlins ohne Verweis auf BiB

#Problem: Kategorie "Denkmal" ist sehr umfassend und wenigs präzise
SELECT DISTINCT ?obj ?objLabel ?location WHERE {
  VALUES ?classes { 
    wd:Q860861
    wd:Q179700
    wd:Q3476515
    wd:wd:Q2293362
    wd:Q17489160
    wd:Q106482879
    wd:Q245117 }
  wd:Q64 wdt:P625 ?berlincoords .
          SERVICE wikibase:around {
            ?obj wdt:P625 ?location .
            bd:serviceParam wikibase:center ?berlincoords . 
           bd:serviceParam wikibase:radius "20" . 
         } .
    
            ?obj wdt:P31 ?classes .
           
  #Von Ergebnismenge sollen subtrahiert werden:
  MINUS {
    {
  ?obj wdt:P1343 wd:Q111792585 . # Objekte mit Verweis auf BiB
   } UNION {
      ?obj wdt:P973 ?url .  # Objekte mit BiB URL in P973
   FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
    } UNION {
      ?obj ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] . # Objekte mit BiB URL in Referenz
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
   }
    }
          SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Objekte aus ausgewählten BiB-relevanten Klassen im Umkreis von 20 km um das Zentrum Berlins ohne Verweis auf BiB

#title: Objekte im Umkreis um eine geographische Koordinate finden
#Quelle: https://stackoverflow.com/questions/49302399/how-to-get-cities-around-a-location-in-wikidata

SELECT DISTINCT ?distance ?obj ?objLabel ?location WHERE {

   # Use the around service
   # Erläuterung: https://en.wikibooks.org/wiki/SPARQL/SERVICE_-_around_and_box
   SERVICE wikibase:around { 
     # Looking for items with coordinate locations(P625)
     ?obj wdt:P625 ?location . 

     # definierte Koordinate, die als Zentrum der Umkreissuche verwendet werden soll:
     # Format: "Point(lon,lat)"^^geo:wktLiteral
     bd:serviceParam wikibase:center "Point(13.339785,52.519163)"^^geo:wktLiteral   . 
     # Umkreis in km
     bd:serviceParam wikibase:radius "0.1" . 
     bd:serviceParam wikibase:distance ?distance .
   } .
  
   # Optional kann die Treffermenge auch auf bestimmte
   # Objektkategorien eingeschränkt werden
   # relevante Objektklassen (Statue, Denkmal, Skulptur)
   # ggf. auskommentieren
   # VALUES ?object { wd:Q179700 wd:Q4989906 wd:Q860861}
   # ?obj wdt:P31/wdt:P279* ?object .

   # Use the label service to get the English label
   SERVICE wikibase:label {
   bd:serviceParam wikibase:language "de" . 
   }
}
ORDER BY ?distance

Objekte im Umkreis um eine geographische Koordinate finden

ÜBUNG

Georkordinaten ergänzen

#title: Objekte mit BiB-Referenz, aber ohne Geokordinaten
SELECT DISTINCT ?object ?objectLabel ?URL WHERE {
  ?object wdt:P131* wd:Q64 . # im Raum Berlin
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  MINUS { ?object wdt:P625 ?coords } # Ziehe Objekte mit Koordinaten von der Ergebnismenge ab
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels
  }

Objekte mit BiB-Referenz, aber ohne Geokordinaten

Urheber:innen ergänzen

#title: Objekte mit BiB-Referenz, aber ohne Urheber:innen
SELECT DISTINCT ?object ?objectLabel ?URL WHERE {
  VALUES ?werk { wd:Q860861 wd:Q4989906 } # definiert Objektkategorien
  ?object wdt:P31 ?werk ;
          wdt:P131* wd:Q64 . # im Raum Berlin
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  MINUS { ?object wdt:P170 ?creator } # Ziehe Objekte mit Urheber:innen von der Ergebnismenge ab
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels
  }

Objekte mit BiB-Referenz, aber ohne Urheber:innen

Material ergänzen

#title: Objekte mit BiB-Referenz, aber ohne Materialangabe
SELECT DISTINCT ?object ?objectLabel ?URL WHERE {
  ?object wdt:P131* wd:Q64 . # im Raum Berlin
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  MINUS { ?object wdt:P186 ?material } # Ziehe Objekte mit Koordinaten von der Ergebnismenge ab
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels

Objekte mit BiB-Referenz, aber ohne Materialangabe

}

Objekte mit Commons-Kategorie, aber ohne Bild

#title: Objekte mit BiB-Referenz und Commons Category, aber ohne Bild
SELECT DISTINCT ?object ?objectLabel ?URL WHERE {
  ?object wdt:P131* wd:Q64 . # im Raum Berlin
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  ?object wdt:P373 ?cat .
  MINUS { ?object wdt:P18 ?img } # Ziehe Objekte mit Koordinaten von der Ergebnismenge ab
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels

Objekte mit BiB-Referenz und Commons Category, aber ohne Bild

}

Urheber:innen ohne GND-ID

Viele Urheber:innen sind auf

Weitere Ideen

Es lassen sich einfach weitere fehlende Angaben finden, indem im gewohnten Query bei MINUS { ?object wdt:P... ?fehlt } die entsprechende Property eingesetzt wird.

#title: Objekte mit BiB-Referenz, aber ohne Material
SELECT DISTINCT ?object ?objectLabel ?URL WHERE {
  VALUES ?werk { wd:Q860861 wd:Q4989906 } # definiert Objektkategorien
  ?object wdt:P31 ?werk ;
          wdt:P131* wd:Q64 . # im Raum Berlin
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  MINUS { ?object wdt:P186 ?material } # Ziehe Objekte mit Materialangaben von der Ergebnismenge ab
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels
  }

Objekte mit BiB-Referenz, aber ohne Material

Wie wäre es noch mit depicts (P180), inception (P571) oder instance of (P31)? Ganz mutige können es auch mit image (P18) versuchen und auf [8] nach Bildmaterial suchen. Darauf kommen wir aber später noch ausführlicher zu sprechen.

Hilfe bei SPARQL-Abfragen bietet Seite Wikidata:Request_a_query.

Block 2: Batch modifications

• Mehrere Edits in einem Aufwasch mit Quickstatements, Einführung in die Quickstatemtens Syntax

Übung: Es wird eine Tabelle mit ausgewählten Angaben aus der BiB-Datenbank bereitgestellt und in je eine Tabelle für die einzelnen TN aufgeteilt. Bearbeitung der Tabellen in einer Tabellenkalkulation, z.B. Ergänzung von BiB-URLs in described at URL (P973) oder Verweis auf Bildhauerei in Berlin (Q111792585) in described by source (P1343) samt URL in Qualifier URL (P2699), dann Upload mittels Quickstatements.

• Reconciliation und Augmentation mit OpenRefine: Liste von Objekten + Urheber:innen nach OR importieren, reconcilen, Information (z.B. Geburtsort/-datum) ergänzen, als Tabelle exportieren

• Daten aus Wikidata ziehen
  • über OpenRefine
  • über den SPARQL-Query-Service und Export (CSV oder programmatisch über Code)

Exkurs: Wikimedia Commons

• Was ist Wikimedia Commons
• Bilder hochladen (Exkurs: Batch-Upload)
• Strukturierte Daten

Daten abfragen

Konventionelle Suche

Die übliche "Freitextabfrage" liefert wegen der sehr heterogenen Metadaten eine bunte Ergebnissmenge. Eine gezielte und präzise Suche ist nur selten möglich. Informationen zur Suche

Exemplarische Suche nach dem Marx-und-Engels-Denkmal in Berlin-Mitte: Freitextsuche

Mit Kategorien lassen sich Objekte zu Gruppen zusammenfassen, hier bspw. die Kategorie für o.g. Denkmal: https://commons.wikimedia.org/wiki/Category:Marx-Engels-Denkmal_(Berlin-Mitte)

Strukturierte Daten

Zunehmend werden jedoch auch auf Wikimedia Commons – an Wikidata angelehnt – strukturierte Daten hinterlegt.

Man kann also gezielt nach Medien suchen, für die auf Commons (nicht auf Wikidata!) z.B. ein "Motiv"-Statement (P180) mit Wert Marx-Engels-Denkmal (Q63283813) vergeben wurde: https://commons.wikimedia.org/w/index.php?search=haswbstatement%3AP180%3DQ63283813&title=Special:Search&profile=advanced&fulltext=1&ns6=1

Es lassen sich auch sog. Föderierte Queries formulieren, bei denen auf strukturiete Daten in Commons und Wikidata zurückgegriffen werden kann.

Dieser Query (vgl. oben) gibt alles Wikidata-Objekte mit einer BiB-Referenz-URL und Bilddatei image (P18) aus.

#title: Statements mit BiB-URL als Referenz und verknüpfter Bilddatei
SELECT DISTINCT ?object ?URL ?img WHERE {
  VALUES ?werk { wd:Q860861 wd:Q4989906 } # definiert Objektkategorien
  ?object wdt:P31 ?werk ;
          wdt:P131* wd:Q64 . # im Raum Berlin
  ?object wdt:P18 ?img .
  ?object ?p [ prov:wasDerivedFrom [ pr:P854 ?URL ]] .
  FILTER (STRSTARTS(STR(?URL), "https://bildhauerei-in-berlin.de/") )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } # ergänzt Labels
  }

Statements mit BiB-URL als Referenz und verknüpfter Bilddatei

Wikimedia Commons hat einen eigenen SPARQL-Endpunkt und Query-Service.

Der Wikidata-Query kann dort in einen entsprechende Commons-SPARQL-Anfrage integriert werden: Query

Der letzte Query gibt alle Bilddateien auf Commons aus, die ein Wikidata-Objekt mit BiB-Referenz darstellen. Die Trefferzahl ist nicht nur fünfmal so groß. Eine entsprechende Anfrage (mit Verweis auf BiB-URLs) ließe sich innerhalb von Wikimedia Commons auch nicht formulieren.

Block 3: Workflows

Data Roundtripping?

Wie lassen sich Daten aus Wikidata in das Erschließungssystem zurückspielen? Welche Vorteile und Risiken sind hiermit verbunden? Wie sollte die Qualitätssicherung organisiert werden?

Wie lassen sich Änderungen an den Daten auf Wikidata monitoren? (Help:Watchlist)

Bilder auf Commons

Bildmaterial auf Wikimedia Commons kann eine wichtige Ergänzung zu den BiB-Bildern darstellen (ältere oder jüngere Aufnahmen, Ersatz für fehlende Bilder, besondere Perspektiven etc.). Wie lassen sich Bilder von Wikimedia Commons auf BiB nachnutzen (direkte Einbindung, Verweis)?

Wie lassen sie sich effizient finden?

Commons könnte auch eine Plattform für Citizen Science darstellen: Interessierte könnten ihre Bilder von Plastik im öffentlichen Raum dort einstellen und – je nach Kompetenz und Ressourcenverfügbarkeit – erschließen. BiB könnte die Daten nachnutzen.

Andererseits können auch Bilder von BiB auf Wikimedia Commons geladen werden. Sie werden dadurch ggf. für ein breiteres Publikum sichtbar und v.a. unmittelbar auf Wikipedia nachnutzbar. Welche Bilder sollten bevorzugt auf Wikimedia Commons eingestellt werden? Was ist zu beachten? Wie sehen die Workflows aus?

Eine BiB-ID-Property?

Aktuell gibt es keine WD-Property für die BiB-ID, d.h. keinen externen Identifikator für BiB.

Vorteile einer BiB-ID (vgl. auch hier):

• Eindeutige Verknüpfung des WD-Items mit dem Katalogisat in BiB, dadurch erleichterte Datensynchronisierung
• Erhöhte Sichtbarkeit der BiB
• Leichtere Verfügbarmachung von mit hoher Domänenexpertise erstellter Information auf BiB

Eine Property kann nicht einfach erstellt, sondern muss beantragt werden (vgl. Wikidata:Property_proposal). Sie wird nach Begutachtung des Antrags durch die Commnunity von einer Userin/einem User mit entsprechender Berechtigung eingerichtet.

Über die ID muss regelbasiert auf den Datensatz verlinkt werden können, die Datensatz-URL muss sich also über formatter URL (P1630) aus der ID ableiten lassen können.

Dies ist in vielen Fällen nicht gegeben, so auch bei BiB. Eine Änderung des URL-Schemas wäre also zu überlegen. [Anmerkung: mit ^https?:\/\/bildhauerei-in-berlin\.de\/bildwerk\/([0-9a-z\-]+)\/$ als URL match pattern (P8966) ließe sich das bestehende URL-Schema weiterverwenden - diese regex lässt allerdings sehr viel Spielraum für mögliche Abweichungen ... --Klaus Bulle DDK Bildarchiv Foto Marburg (talk) 14:15, 18 April 2024 (UTC)]

Aktuell lässt sich ein Verknüpfung z.B. über die Property described at URL (P973) dokumentieren. [9] Ggf. kann in Zukunft aus dieser Information die BiB-ID abgeleitet werden.