User:Ben Skála/queries
Jump to navigation
Jump to search
Lidé narození na území Česka, 108288 výsledků 8.4.2021, 117853 k 4.8.2021, 121647 k 17.12.2021, 140675 k 31.12.2022, 148423 k 25.9.2023, 153636 k 10.4.2024
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P31 wd:Q5 .
?item wdt:P19 ?misto .
?misto wdt:P17 wd:Q213 .
MINUS {?item wdt:P19 wd:Q81011 .}
MINUS {?item wdt:P19 wd:Q2353353 .}
MINUS {?item wdt:P19 wd:Q81720 .}
MINUS {?item wdt:P19 wd:Q4198 .}
MINUS {?item wdt:P19 wd:Q157728 .}
MINUS {?item wdt:P19 wd:Q5602 .}
MINUS {?item wdt:P19 wd:Q877899 .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
3459 seznamů bez seznam čeho
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P31 wd:Q13406463 .
MINUS { ?item wdt:P360 [] } .
?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs"
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
692 pomníků bez připomíná
SELECT DISTINCT ?item ?itemLabel ?souradnice ?obr
WHERE
{
?item wdt:P31 wd:Q4989906 .
?item wdt:P131* wd:Q213 .
?item wdt:P625 ?souradnice .
OPTIONAL { ?item wdt:P18 ?obr . }
MINUS { ?item wdt:P547 [] . }
OPTIONAL { ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
1409 bez P131
SELECT DISTINCT ?item ?itemLabel ?souradnice
WHERE
{
?item wdt:P17 wd:Q213 .
?item wdt:P625 ?souradnice .
MINUS { ?item wdt:P131 [] . }
MINUS { ?item wdt:P31 wd:Q4022 . }
MINUS { ?item wdt:P31 wd:Q47521 . }
MINUS { ?item wdt:P31 wd:Q102496 . }
MINUS { ?item wdt:P31 wd:Q46831 . }
MINUS { ?item wdt:P31 wd:Q697304 . }
MINUS { ?item wdt:P31 wd:Q55043 . }
MINUS { ?item wdt:P31 wd:Q33506 . }
MINUS { ?item wdt:P31 wd:Q728904 . }
MINUS { ?item wdt:P31 wd:Q1989839 . }
MINUS { ?item wdt:P31 wd:Q159334 . }
MINUS { ?item wdt:P31 wd:Q184644 . }
MINUS { ?item wdt:P31 wd:Q2535020 . }
MINUS { ?item wdt:P31 wd:Q4498974 . }
MINUS { ?item wdt:P31 wd:Q1574810 . }
MINUS { ?item wdt:P31 wd:Q12018178 . }
MINUS { ?item wdt:P31 wd:Q22938576 . }
MINUS { ?item wdt:P31 wd:Q164099 . }
MINUS { ?item wdt:P31 wd:Q2463705 . }
MINUS { ?item wdt:P31 wd:Q3507608 . }
MINUS { ?item wdt:P31 wd:Q3491088 . }
MINUS { ?item wdt:P31 wd:Q180958 . }
MINUS { ?item wdt:P31 wd:Q12018181 . }
MINUS { ?item wdt:P31 wd:Q12284 . }
MINUS { ?item wdt:P31 wd:Q193071 . }
MINUS { ?item wdt:P31 wd:Q82794 . }
MINUS { ?item wdt:P31 wd:Q34442 . }
MINUS { ?item wdt:P31 wd:Q2143825 . }
MINUS { ?item wdt:P31 wd:Q744913 . }
MINUS { ?item wdt:P31 wd:Q12018175 . }
MINUS { ?item wdt:P31 wd:Q12018177 . }
MINUS { ?item wdt:P31 wd:Q353027 . }
MINUS { ?item wdt:P31 wd:Q12018179 . }
MINUS { ?item wdt:P31 wd:Q38723 . }
MINUS { ?item wdt:P31 wd:Q12018173 . }
MINUS { ?item wdt:P31 wd:Q6881511 . }
MINUS { ?item wdt:P31 wd:Q47075851 . }
MINUS { ?item wdt:P31 wd:Q8068 . }
MINUS { ?item wdt:P31 wd:Q11946645 . }
MINUS { ?item wdt:P31 wd:Q3146899 . }
MINUS { ?item wdt:P31 wd:Q959038 . }
MINUS { ?item wdt:P31 wd:Q9369203 . }
MINUS { ?item wdt:P31 wd:Q4830453 . }
MINUS { ?item wdt:P31 wd:Q3001412 . }
MINUS { ?item wdt:P31 wd:Q11863106 . }
MINUS { ?item wdt:P31 wd:Q16917 . }
MINUS { ?item wdt:P31 wd:Q1414991 . }
MINUS { ?item wdt:P31 wd:Q216285 . }
MINUS { ?item wdt:P31 wd:Q10406027 . }
MINUS { ?item wdt:P31 wd:Q10624527 . }
MINUS { ?item wdt:P31 wd:Q9842 . }
MINUS { ?item wdt:P31 wd:Q4469107 . }
MINUS { ?item wdt:P31 wd:Q133346 . }
MINUS { ?item wdt:P31 wd:Q207694 . }
MINUS { ?item wdt:P31 wd:Q1078765 . }
MINUS { ?item wdt:P31 wd:Q30914189 . }
MINUS { ?item wdt:P31 wd:Q728937 . }
MINUS { ?item wdt:P31 wd:Q53130134 . }
MINUS { ?item wdt:P31 wd:Q476028 . }
MINUS { ?item wdt:P31 wd:Q2072238 . }
MINUS { ?item wdt:P31 wd:Q604177 . }
MINUS { ?item wdt:P31 wd:Q233324 . }
MINUS { ?item wdt:P31 wd:Q158454 . }
MINUS { ?item wdt:P31 wd:Q178561 . }
MINUS { ?item wdt:P31 wd:Q1664720 . }
MINUS { ?item wdt:P31 wd:Q126807 . }
MINUS { ?item wdt:P31 wd:Q3895768 . }
MINUS { ?item wdt:P31 wd:Q10861807 . }
MINUS { ?item wdt:P31 wd:Q573607 . }
MINUS { ?item wdt:P31 wd:Q1324355 . }
MINUS { ?item wdt:P31 wd:Q7075 . }
MINUS { ?item wdt:P31 wd:Q1437459 . }
MINUS { ?item wdt:P31 wd:Q6256 . }
MINUS { ?item wdt:P31 wd:Q10860585 . }
MINUS { ?item wdt:P31 wd:Q19602601 . }
MINUS { ?item wdt:P31 wd:Q15275719 . }
MINUS { ?item wdt:P31 wd:Q1758690 . }
MINUS { ?item wdt:P31 wd:Q6139189 . }
MINUS { ?item wdt:P31 wd:Q60895708. }
MINUS { ?item wdt:P31 wd:Q4287745. }
MINUS { ?item wdt:P31 wd:Q868557. }
MINUS { ?item wdt:P31 wd:Q163740. }
MINUS { ?item wdt:P31 wd:Q5193377. }
MINUS { ?item wdt:P31 wd:Q2385804. }
MINUS { ?item wdt:P31 wd:Q3918. }
MINUS { ?item wdt:P31 wd:Q3914 . }
MINUS { ?item wdt:P31 wd:Q1190554 . }
MINUS { ?item wdt:P31 wd:Q327333 . }
MINUS { ?item wdt:P31 wd:Q847017 . }
MINUS { ?item wdt:P31 wd:Q17143723. }
MINUS { ?item wdt:P31 wd:Q57314035 . }
MINUS { ?item wdt:P31 wd:Q3488547 . }
MINUS { ?item wdt:P31 wd:Q285852 . }
MINUS { ?item wdt:P31 wd:Q81755572 . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
čísla orientační na Staromáku
select ?item ?itemLabel ?co
where {
?item wdt:P669 wd:Q421678.
?item p:P669 [ pq:P670 ?co ; ps:P669 wd:Q421678 ] .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
domy na Starém Městě podle čp. (čísla řazená podle čísel), 532 výsledků k 2.12.2021
select ?item ?itemLabel ?cp
where {
?item wdt:P131 wd:Q748211.
?item wdt:P4856 ?cp .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
ORDER BY asc(xsd:integer(?cp))
drobné památky v Brně, 882 k 16.11.2021, 1365 k 9.5.2023
#defaultView:Map
SELECT distinct ?item ?itemLabel ?souradnice ?image ?layer WHERE {
?item wdt:P131* wd:Q14960 .
?item wdt:P625 ?souradnice .
{
?item wdt:P31 wd:Q5003624 .
BIND("Památník" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q179700 .
BIND("Socha" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q2309609 .
BIND("Kříž u cesty" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q20460 .
BIND("Krucifix" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q17489160 .
BIND("Busta" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q860861 .
BIND("Plastika" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q721747 .
BIND("Plaketa" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q17514 .
BIND("Graffiti" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q4989906 .
BIND("Pomník" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q483453 .
BIND("Fontána" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q12029081 .
BIND("Kašna" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q2713614 .
BIND("Mariánský sloup" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q11741382 .
BIND("Sloup Nejsvětější Trojice" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q1149963 .
BIND("Orloj" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q12661150 .
BIND("Boží muka" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q108325 .
BIND("Kaple" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q1457501 .
BIND("Hřbitovní kaple" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q14552192 .
BIND("Kaplička" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q245117 .
BIND("Reliéf" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q104829843 .
BIND("Dekorativní stěna" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q575759 .
BIND("Válečný památník" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q80793 .
BIND("Sluneční hodiny" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q1456110 .
BIND("Misijní kříž" AS ?layer) .
}
OPTIONAL{ ?item wdt:P18 ?image }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
drobné památky v Česku, 9186 výsledků k 22.11.2017, 9578 k 9.3.2018, 9622 k 4.4.2018, 10006 k 25.5.2018, 10182 k 8.8.2018, 10231 k 24.8.2018, 10575 k 5.12.2018, 10725 k 22.2.2019, 11282 k 20.6.2019, 42654 k 8.4.2021
#defaultView:Map
SELECT distinct ?item ?itemLabel ?souradnice ?image ?layer WHERE {
?item wdt:P131* wd:Q213 .
?item wdt:P625 ?souradnice .
{
?item wdt:P31 wd:Q5003624 .
BIND("Památník" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q179700 .
BIND("Socha" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q2309609 .
BIND("Krucifix" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q17489160 .
BIND("Busta" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q860861 .
BIND("Plastika" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q721747 .
BIND("Plaketa" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q17514 .
BIND("Graffiti" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q4989906 .
BIND("Pomník" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q483453 .
BIND("Fontána" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q12029081 .
BIND("Kašna" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q26789571 .
BIND("Mariánský sloup" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q26789654 .
BIND("Sloup Nejsvětější Trojice" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q1149963 .
BIND("Orloj" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q3395121 .
BIND("Boží muka" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q108325 .
BIND("Kaple" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q19270367 .
BIND("Výklenková kaple" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q1457501 .
BIND("Hřbitovní kaple" AS ?layer) .
} UNION {
?item wdt:P31 wd:Q14552192 .
BIND("Kaplička" AS ?layer) .
}
OPTIONAL{ ?item wdt:P18 ?image }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],cs". }
}
křížky aj. u silnic (přes P706 oblast)
SELECT DISTINCT ?item ?itemLabel ?souradnice ?obr
WHERE
{
?item wdt:P17 wd:Q213 .
?item wdt:P706 ?silnice .
?silnice wdt:P31 wd:Q34442 .
?item wdt:P625 ?souradnice .
OPTIONAL { ?item wdt:P18 ?obr } .
OPTIONAL { ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
lidi bez křestních jmen
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P31 wd:Q5 .
?item wdt:P19 ?mistonar .
?mistonar wdt:P131* wd:Q213 .
MINUS { ?item wdt:P735 [] } .
OPTIONAL { ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
refy dva stejné z nkčraut u dat narození, nulový výsledek (projet také další statements, datum úmrtí, místo nar., občanství...)
select distinct ?item ?statement ?nkcr where {
?item p:P569 ?statement .
?statement prov:wasDerivedFrom ?ref1, ?ref2 filter(?ref1 != ?ref2).
?ref1 pr:P691 ?nkcr .
?ref2 pr:P691 ?nkcr .
}
refy z wiki
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P19 ?misto .
?misto wdt:P17 wd:Q213 .
MINUS { ?item wdt:P19 wd:Q81011 . }
?item p:P569 ?statement1 .
?statement1 prov:wasDerivedFrom ?ref .
?ref pr:P143 [] .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
LIMIT 10
studenti UK bez vyplněné fakulty, 2112 k 8.4.2021
SELECT DISTINCT ?item ?itemLabel ?rok
WHERE
{
?item wdt:P31 wd:Q5 .
?item wdt:P19 ?misto .
?misto wdt:P17 wd:Q213 .
?item wdt:P69 wd:Q31519 .
?item wdt:P569 ?datnar .
BIND( YEAR(?datnar) AS ?rok )
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
svatby celebrit
SELECT DISTINCT ?item ?itemLabel ?roknar ?chotLabel ?od ?mistosvatbyLabel ?do ?pricinakonceLabel
WHERE
{
?item wdt:P31 wd:Q5 .
?item wdt:P19 ?misto .
?misto wdt:P17 wd:Q213 .
?item wdt:P26 ?chot .
?item p:P26 [ pq:P580 ?od ; ps:P26 ?chot ] .
OPTIONAL { ?item p:P26 [ pq:P2842 ?mistosvatby ; ps:P26 ?chot ] . }
OPTIONAL { ?item p:P26 [ pq:P582 ?do ; ps:P26 ?chot ] . }
OPTIONAL { ?item p:P26 [ pq:P1534 ?pricinakonce ; ps:P26 ?chot ] . }
?item wdt:P569 ?datum .
BIND( YEAR(?datum) AS ?roknar )
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
ORDER BY desc(xsd:integer(?roknar))
LIMIT 200
#
obce bez nkčraut
SELECT DISTINCT ?item ?itemLabel ?okresLabel ?souradnice
WHERE
{
?item wdt:P31 wd:Q5153359 .
?item wdt:P131 ?okres .
?item wdt:P625 ?souradnice .
MINUS { ?item wdt:P691 [] } .
OPTIONAL { ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
filmy z čsfd bez vyplněného žánru, 11827 z 8.4.2021
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P31 wd:Q11424 .
?item wdt:P2529 [] .
MINUS { ?item wdt:P136 [] . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
neznámá hodnota do query
SELECT DISTINCT ?item ?itemLabel ?incipit ?autorLabel ?lepsi
WHERE
{
?item wdt:P629 wd:Q172152 .
?item wdt:P1922 ?incipit .
?item wdt:P676 ?autor .
optional {?autor rdfs:label ?label filter(lang(?label) = "cs") .}
BIND(IF(isBlank(?autor), "neznámá hodnota", ?label) as ?lepsi).
OPTIONAL { ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
senátoři - kdo se dostal do druhého kola
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?obr ?obvodLabel ?stranaLabel ?hlasy ?poradi ?souradnice
WHERE
{
?item wdt:P3602 wd:Q81226406 .
OPTIONAL { ?item wdt:P18 ?obr .}
?item p:P3602 [ pq:P2501 wd:Q62790009 ; ps:P3602 wd:Q81226406 ] .
?item p:P3602 [ pq:P768 ?obvod ; ps:P3602 wd:Q81226406 ] .
?item p:P3602 [ pq:P1111 ?hlasy ; ps:P3602 wd:Q81226406 ] .
?item p:P3602 [ pq:P1352 ?poradi ; ps:P3602 wd:Q81226406 ] .
OPTIONAL { ?item p:P3602 [ pq:P102 ?strana ; ps:P3602 wd:Q81226406 ] .}
?obvod wdt:P138 ?mesto .
?mesto wdt:P625 ?souradnice .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
mapa krajů a jejich představitelů k určitému datu
SELECT ?krajLabel ?mestoLabel ?coords ?hejtmanLabel WHERE {
BIND ("+2017-01-01T01:00:00Z"^^xsd:dateTime AS ?datum).
?kraj wdt:P31 wd:Q38911.
?kraj wdt:P36 ?mesto.
?mesto wdt:P625 ?coords.
?kraj p:P6 ?hejtmanStmt.
?hejtmanStmt ps:P6 ?hejtman.
?hejtmanStmt pq:P580 ?hejtmanOd.
?hejtmanStmt pq:P582 ?hejtmanDo.
FILTER ((?hejtmanOd <= ?datum) && (?hejtmanDo >= ?datum))
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
poslanci bez refu v datu narození (často je možné refovat pomocí "ID osoby v databázi české Poslanecké sněmovny"); 497 výsledků 13.4.2021
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P39 wd:Q19803234 .
?item p:P569 ?statement1 .
MINUS { ?statement1 prov:wasDerivedFrom ?ref . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
kaple v Česku bez uvedeného patrona (3790 k 13.4.2021)
SELECT DISTINCT ?item ?itemLabel ?patronLabel
WHERE
{
?item wdt:P31 wd:Q108325 .
?item wdt:P17 wd:Q213 .
MINUS { ?item wdt:P417 ?patron . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
#
lidi narození na území Česka s datem narození "převzatým z wiki"
SELECT DISTINCT ?item ?itemLabel
WHERE
{
?item wdt:P19 ?misto .
?misto wdt:P17 wd:Q213 .
MINUS { ?item wdt:P19 wd:Q81011 . }
?item p:P569 ?statement1 .
?statement1 prov:wasDerivedFrom ?ref .
?ref pr:P143 [] .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs"}
}
LIMIT 10
Česká hudební alba vydaná např. v roce 2000
select ?item ?itemLabel
where {
?item wdt:P31 wd:Q482994 .
?item wdt:P495 wd:Q213 .
?item wdt:P577 ?date .
FILTER((?date >= "2000-01-01T00:00:00Z"^^xsd:dateTime) && (?date <= "2000-12-31T00:00:00Z"^^xsd:dateTime))
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
}
Celkový počet referencí a počet referencí z wiki
select distinct ?item (count(?ref) as ?pocet_referenci) (count(?zwiki) as ?pocet_referenci_zwiki) where {
{
select distinct ?item ?ref where {
?item wdt:P19/wdt:P17 wd:Q213 .
optional {?item p:P19/prov:wasDerivedFrom ?ref .}
}
}
optional {?item p:P19/prov:wasDerivedFrom ?ref . ?ref pr:P143 ?zwiki . }
} group by ?item order by desc(?pocet_referenci)
Položky s identickým nkčraut, výsledek by měl být nula
SELECT * WHERE {
{
SELECT ?vedidk (COUNT(?obj) AS ?count) (GROUP_CONCAT(?obj; SEPARATOR = " , ") AS ?items) WHERE {
?obj wdt:P9579 ?vedidk .
}
GROUP BY ?vedidk
}
FILTER(?count > 1)
}
order by desc (?count)