User:Bert-packed

Babel user information
nl-N Deze gebruiker heeft het Nederlands als moedertaal. en-3 This user has advanced knowledge of English. de-1 Dieser Benutzer beherrscht Deutsch auf grundlegendem Niveau. es-0 Esta persona no tiene ningún conocimiento del español (o lo entiende con mucha dificultad). pt-0 Este utilizador não compreende português (ou compreende com dificuldades consideráveis).
Users by language

SPARQL queries

1. alle kunstwerken James Ensor met inventarisnummer, Workpid, titel en collectie

SELECT ?work ?collectionLabel ?invnr ?WORKpid ?workLabel
WHERE {
 ?work wdt:P170 wd:Q158840 .     # zoek alle items die James Ensor gemaakt heeft
 ?work p:P217 ?y .               # zoek alle items die een inventarisnummer statement hebben
 ?y v:P217 ?invnr .              # zoek voor elk inventarisnummer statement de waarde op 
 ?y pq:P195 ?collection .        # zoek voor elk inventarisnummer statement de collectie op 
 ?y prov:wasDerivedFrom ?z .     # zoek voor elk inventarisnummer statement het bronverwijzing statement op
 ?z pr:P854 ?WORKpid .           # zoek voor elk bronverwijzing statement de URL op
 SERVICE wikibase:label {bd:serviceParam wikibase:language "nl" .} # toon voor eigenschappen het label in het Nederlands
}

2. Alle kunstwerken in Groeningemuseum, met hun titel en datapid

SELECT ?work ?workLabel ?collectionLabel ?datapid 
WHERE {
 ?work wdt:P195 wd:Q1948674 .    # zoek alle items die bewaard worden in het Groeningemuseum
 ?work p:P195 ?y .               # zoek voor deze items alle collection statements
 ?y v:P195 ?collection .         # zoek voor al deze collection statemens de waarde op
 ?y prov:wasDerivedFrom ?z .     # zoek voor al deze collection statements het bronverwijzing statement op
 ?z pr:P854 ?datapid .           # zoek voor al deze bronverwijzing statement de URL op
 SERVICE wikibase:label {bd:serviceParam wikibase:language "nl" .} # toon voor eigenschappen het label in het Nederlands
       } 

3. Alle kunstwerken in het SMAK die tot de Collectie Vlaamse Gemeenschap behoren met hun datapid test!

SELECT ?work ?workLabel ?collectionLabel ?datapid 
WHERE {
 ?work p:P195/v:P195 wd:Q1540707 .    # zoek alle items die behoren tot de collectie van het SMAK
 ?work p:P195/v:P195 wd:Q2173225 .    # zoek voor al deze items welke er behoren tot de Collectie Vlaamse Gemeenschap
 ?work p:P195 ?y .               # zoek voor deze items alle collection statements
 ?y v:P195 ?collection .         # zoek voor al deze collection statements de waarde op
 ?y prov:wasDerivedFrom ?z .     # zoek voor al deze collection statements degene die een bronverwijzing hebben
 ?z pr:P854 ?datapid .           # zoek voor al deze bronverwijzing statement de URL op
 SERVICE wikibase:label {bd:serviceParam wikibase:language "nl" .} # toon voor eigenschappen het label in het Nederlands
       }

3. Alle artiesten met werken in het MSK die nog geen 70 jaar overleden zijn.

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX q: <http://www.wikidata.org/prop/qualifier/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?c ?cLabel ?dod    #  DISTINCT = haal alle dubbele namen uit de lijst.
WHERE
{
  ?p wdt:P195 wd:Q2365880 .  # Alle werken in het MSK (?p)
  ?p wdt:P170 ?c .                    #  Haal de kunstenaar op (?c)
  ?c wdt:P570 ?dod  .               # Haal de overlijdensdatum op (?dod)
  FILTER (?dod > "1946-01-01T00:00:00Z"^^xsd:dateTime) .  # filter de lijst  tot zij die nog geen 70 jaar overleden zijn
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "nl,en" .
   }
} ORDER BY ?cLabel

Deze query werkt nog niet 100%. ie. https://www.wikidata.org/wiki/Q1862458 wordt niet opgenomen in het resultaat.

Alle workpids in Muzee en hun corresponderende datapids

>>> Nog niet helemaal ok: filtert nog geen datapids uit andere collecties

SELECT ?invnr ?invnrCollectionLabel ?workpid ?datapid
WHERE {
 
 ?work p:P195 ?x .
 ?x v:P195 wd:Q1928672 .              # zoek alle items die behoren tot de collectie van Mu.ZEE
 ?work p:P217 ?y .                    # zoek voor deze items alle inventory statements
 ?y v:P217 ?invnr .                   # zoek voor al deze inventory statemens de waarde op
 ?y prov:wasDerivedFrom ?z .          # zoek voor al deze inventory statements degene die een bronverwijzing hebben
 ?z pr:P854 ?workpid .               # zoek voor al deze inventory statements de URL op   
  
 ?y pq:P195 ?invnrCollection .        # zoek voor al deze inventory statements de collection statements op

 ?x prov:wasDerivedFrom ?a .          # zoek voor al deze inventory statements degene die een bronverwijzing hebben
 ?a pr:P854 ?datapid .               # zoek voor al deze inventory statements de URL op      

 SERVICE wikibase:label {bd:serviceParam wikibase:language "nl" .} # toon voor eigenschappen het label in het Nederlands
       }

Alle creators met werk in het MSK en hun bijhorende wikipedia artikels

prefix schema: <http://schema.org/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT DISTINCT ?creator ?creatorLabel ?dob ?dod ?article WHERE {
    ?p wdt:P195 wd:Q2365880 .  # alle werken uit MSK
    ?p wdt:P170 ?creator .            # haal de creator op
    ?creator wdt:P569 ?dob .       # Haal de date of birth op
    ?creator wdt:P570 ?dod .       # haal de date of death op
    OPTIONAL {
      ?article schema:about ?creator .     # haal alle externe artikel over de creator op
      ?article schema:inLanguage "en" .  # ... in het engels ...
      FILTER (SUBSTR(str(?article), 1, 25) = "https://en.wikipedia.org/")   # filter die lijst en haal enkel de wikipedia artikels op.
    }

    SERVICE wikibase:label {   # haal het label voor de artiest op in het engels
     bd:serviceParam wikibase:language "en" .
  }
}