User:Dipsode87

Babel user information

fr-N	Cet utilisateur a pour langue maternelle le français.

es-3	Este usuario tiene un conocimiento avanzado del español.

en-3	This user has advanced knowledge of English.

ca-1	Aquest usuari té un coneixement bàsic de català.

zh-1	这位用户的中文达到初级水平。

This user is a member of
WikiProject Informatics.

This user loves OpenRefine.

This user uses QuickStatements.

This user is penguin powered.

This user contributes using Mozilla Firefox.

Bibliothécaire travaillant à la Bibliothèque nationale de France, je me consacre à l'amélioration de Wikidata dans le domaine de la préservation numérique (formats de données, outils et environnements logiciels, identifiants pérennes).

Projets[edit]

Wikidata for Digital Preservation Portal

Tableau de bord des formats de fichier[edit]

Manually update

Grouping by part of (P361)

Top groupings (Minimum 20 items)		Top Properties (used at least 0 times per grouping)
Name	Count	based on (P144)	developer (P178)	PRONOM file format ID (P2748)	Library of Congress Format Description Document ID (P3266)	File Format Wiki page ID (P3381)	official website (P856)
Office Open XML (Q279979)	40	0% (0) 🔍	5.0% (2) 🔍	2.5% (1) 🔍	0% (0) 🔍	7.5% (3) 🔍	0% (0) 🔍
C++ Standard Library (Q1022270)	34	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍
C POSIX library (Q4035705)	27	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍
C standard library (Q300914)	26	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍	0% (0) 🔍
Amateur Data Interchange Format (Q18011768)	24	4.17% (1) 🔍	0% (0) 🔍	87.5% (21) 🔍	83.33% (20) 🔍	0% (0) 🔍	0% (0) 🔍
ZIP (Q136218)	20	5.0% (1) 🔍	0% (0) 🔍	100.0% (20) 🔍	100.0% (20) 🔍	5.0% (1) 🔍	0% (0) 🔍
AutoCAD Drawing (Q1053358)	20	0% (0) 🔍	95.0% (19) 🔍	95.0% (19) 🔍	95.0% (19) 🔍	0% (0) 🔍	0% (0) 🔍
Totals (all items)	14752	3.41% (503) 🔍	13.82% (2039) 🔍	15.9% (2346) 🔍	3.42% (505) 🔍	13.22% (1950) 🔍	2.25% (332) 🔍

Identifiant ARK dans Wikidata[edit]

Requêtes SPARQL[edit]

Map of the ARK Name assigning authorities[edit]

The following query uses these:

Properties: Name Assigning Authority Number (P1870)   , coordinate location (P625)   , image (P18)

Features: map (Q24515275)  

#defaultView:Map
SELECT DISTINCT ?org ?geo ?orgLabel ?image WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?org wdt:P1870 ?naan;
    wdt:P625 ?geo.
  OPTIONAL { ?org wdt:P18 ?image. }
}

Try it!

Number of ARKs in Wikidata[edit]

The following query uses these:

Properties: ARK formatter (P8054)  

SELECT ?property ?propertyLabel (COUNT(?item) AS ?numberOfARKs) WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  # Listing the properties that have an ARK formatter property
  ?property wdt:P8054 ?string.
  # Linking to the equivalent property in the wdt: namespace
  ?property wikibase:directClaim ?prop.
  # Listing all items that have one of the properties listed above
  ?item ?prop ?ark.
}
GROUP BY ?property ?propertyLabel
ORDER BY DESC (?numberOfARKs)

Try it!

Most commonly supported file formats[edit]

This query shows a bar chart of the 1000 file formats which have the highest number of supporting applications (applications that can read data in this format).

The following query uses these:

Properties: readable file format (P1072)  

#defaultView:BarChart
SELECT ?format ?formatLabel (count(?application) as ?numberOfReadingApps) WHERE
{SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
 ?application wdt:P1072 ?format.
  }
GROUP BY ?format ?formatLabel
ORDER BY DESC (?numberOfReadingApps)
LIMIT 1000

Try it!

All Wikidata statements whose source is the COPTR registry[edit]

The following query uses these:

Items: Community Owned Digital Preservation Tool Registry (Q89014718)

Properties: stated in (P248)  

SELECT ?item ?itemLabel ?property ?propertyLabel ?value ?valueLabel WHERE
{?item ?claim ?statement;
       ?directClaim ?value.
 ?property wikibase:claim ?claim;
           wikibase:directClaim ?directClaim.
 ?statement prov:wasDerivedFrom ?ref.
 ?ref pr:P248 wd:Q89014718.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Formats with MIME type = "text/plain" and extension != "txt"[edit]

The following query uses these:

Properties: media type (P1163)  

, file extension (P1195)  

SELECT ?format ?formatLabel ?ext WHERE {
  ?format wdt:P1163 "text/plain";
          wdt:P1195 ?ext.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  FILTER(?ext != "txt")
  }

Try it!

MIME type of formats with extension "dat"[edit]

The following query uses these:

Properties: media type (P1163)  

, file extension (P1195)  

SELECT ?format ?formatLabel ?MIME WHERE {
  ?format wdt:P1163 ?MIME;
          wdt:P1195 "dat".
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }

Try it!

XML-based formats with their signature and reference URL[edit]

The following query uses these:

Items: Extensible Markup Language (Q2115)

Properties: based on (P144)  

, XML namespace URL (P7510)  

, file format identification pattern (P4152)  

, reference URL (P854)  

SELECT ?XMLformat ?XMLformatLabel ?namespace ?signature ?source WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?XMLformat wdt:P144 wd:Q2115.
  OPTIONAL {?XMLformat wdt:P7510 ?namespace.}
  OPTIONAL {?XMLformat p:P4152 ?statement.
            ?statement ps:P4152 ?signature;
                       prov:wasDerivedFrom ?reference.
           ?reference pr:P854 ?source.}
  }

Try it!

Alignement des propriétés Wikidata pour les logiciels avec PREMIS[edit]

L'objectif est d'interroger les données Wikidata (les propriétés communes des logiciels listées sur https://www.wikidata.org/wiki/Wikidata:WikiProject_Informatics/Software/Properties) et les aligner grâce à une requête CONSTRUCT au formalisme PREMIS RDF version 3, décrit sur http://www.loc.gov/standards/premis/ontology/owl-version3.html.

The following query uses these:

Items: Mozilla Firefox (Q698)

Properties: operating system (P306)  

, developer (P178)  

, depends on software (P1547)  

, GUI toolkit or framework (P1414)  

, input device (P479)  

, platform (P400)  

, software engine (P408)  

, follows (P155)  

, followed by (P156)  

, source code repository URL (P1324)  

, has part(s) (P527)  

, part of (P361)  

, software version identifier (P348)  

, digital rights management system (P1032)  

, Debian stable package (P3442)  

, formatter URL (P1630)  

, Fedora package (P3463)  

, Framalibre ID (P4107)  

, creator (P170)  

, inception (P571)  

, publication date (P577)  

, copyright license (P275)  

, copyright holder (P3931)  

prefix relSubType: <http://id.loc.gov/vocabulary/preservation/relationshipSubType/>
prefix envFuncType: <http://id.loc.gov/vocabulary/preservation/environmentFunctiontype/>
prefix evType: <http://id.loc.gov/vocabulary/preservation/eventType/>
prefix rightsRelAgRole: <http://id.loc.gov/vocabulary/preservation/rightsRelatedAgentRole/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dct: <http://purl.org/dc/terms/>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix premis: <http://www.loc.gov/premis/rdf/v3/>
prefix prov: <http://www.w3.org/ns/prov#>

CONSTRUCT {
  wd:Q698 rdf:type envFuncType:soa;
            rdfs:label ?itemLabel;
          premis:hasVersion ?version;
            dct:creator ?creator;
            relSubType:idp ?operatingSystem;
            relSubType:idp ?platform;
            relSubType:idp ?softwareEngine;
            relSubType:req ?requiredSoftware;
            relSubType:req ?gui;
            relSubType:req ?inputDevice;
    relSubType:isr ?debianPackage;
    relSubType:isr ?fedoraPackage;
            relSubType:isr ?sourceCodeRepo;
            relSubType:isr ?distributedRepresentation;
            relSubType:sup ?predecessor;
            relSubType:iss ?successor;
            relSubType:isp ?whole;
            relSubType:hsp ?part;
    skos:exactMatch ?framalibreID;
            prov:wasGeneratedBy ?publicationEvent;
            prov:wasGeneratedBy ?inceptionEvent;
          dct:rights ?license;
          dct:rights ?copyright.
  ?copyright rightsRelAgRole:rig ?copyrightOwner.
  ?operatingSystem rdf:type envFuncType:ops;
                   rdfs:label ?operatingSystemLabel.
  ?requiredSoftware rdf:type envFuncType:sof;
                    rdfs:label ?requiredSoftwareLabel.
  ?gui rdf:type envFuncType:sol;
       rdfs:label ?guiLabel.
  ?inputDevice rdf:type envFuncType:hap;
       rdfs:label ?inputDeviceLabel.
  ?platform rdf:type envFuncType:haa;
       rdfs:label ?platformLabel.
  ?software rdf:type envFuncType:soa;
       rdfs:label ?softwareEngineLabel.
  ?predecessor rdf:type envFuncType:sof;
               rdfs:label ?predecessorLabel.
  ?successor rdf:type envFuncType:sof;
             rdfs:label ?successorLabel.
  ?debianPackage rdf:type premis:Representation.
  ?sourceCodeRepo rdf:type premis:Representation.
  ?fedoraPackage rdf:type premis:Representation.
  ?distributedRepresentation rdf:type premis:Representation;
                             premis:storedAt ?distributedRepresentationLocation.
  ?distributedRepresentationLocation rdf:type premis:StorageLocation;
                                     premis:hasMedium ?physicalMedium.
  ?publicationEvent rdf:type evType:cre;
                 dct:date ?publicationDate;
                 prov:wasAssociatedWith ?creationAgent.
  ?inceptionEvent rdf:type evType:cre;
                 dct:date ?inceptionDate;
                 prov:wasAssociatedWith ?creationAgent.
  ?creationAgent rdf:type premis:Agent;
                 foaf:name ?creationAgentLabel.
}
WHERE
{VALUES ?environment {wd:Q698}
  ?environment rdfs:label ?itemLabel.
  FILTER (lang(?itemLabel)="en")
  OPTIONAL{?environment wdt:P306 ?operatingSystem.
           ?operatingSystem rdfs:label ?operatingSystemLabel.
  FILTER (lang(?operatingSystemLabel)="en")}
  OPTIONAL{?environment wdt:P178 ?creator.}
  OPTIONAL{?environment wdt:P1547 ?requiredSoftware.
           ?requiredSoftware rdfs:label ?requiredSoftwareLabel.
  FILTER (lang(?requiredSoftwareLabel)="en")}
  OPTIONAL{?environment wdt:P1414 ?gui.
           ?gui rdfs:label ?guiLabel.
  FILTER (lang(?guiLabel)="en")}
  OPTIONAL{?environment wdt:P479 ?inputDevice.
           ?inputDevice rdfs:label ?inputDeviceLabel.
  FILTER (lang(?inputDeviceLabel)="en")}
  OPTIONAL{?environment wdt:P400 ?platform.
           ?platform rdfs:label ?platformLabel.
  FILTER (lang(?platformLabel)="en")}
  OPTIONAL{?environment wdt:P408 ?softwareEngine.
           ?softwareEngine rdfs:label ?softwareEngineLabel.
  FILTER (lang(?softwareEngineLabel)="en")}
  OPTIONAL{?environment wdt:P155 ?predecessor.
           ?predecessor rdfs:label ?predecessorLabel.
  FILTER (lang(?predecessorLabel)="en")}
  OPTIONAL{?environment wdt:P156 ?successor.
           ?predecessor rdfs:label ?successorLabel.
  FILTER (lang(?successorLabel)="en")}
  OPTIONAL{?environment wdt:P1324 ?sourceCodeRepo}
 OPTIONAL{?environment wdt:P527 ?part}
 OPTIONAL{?environment wdt:P361 ?whole}
 OPTIONAL{?environment wdt:P348 ?version}
 OPTIONAL{SELECT ?physicalMedium (UUID() As ?distributedRepresentation) (UUID() As ?distributedRepresentationLocation)
                                WHERE {wd:Q698 wdt:P1032 ?physicalMedium.}
          }
 OPTIONAL{
   SELECT (IRI(REPLACE(?debianPackageBaseURI, '\\$1', ?debianPackageString)) AS ?debianPackage) WHERE {wd:Q698 wdt:P3442 ?debianPackageString.
          wd:P3442 wdt:P1630 ?debianPackageBaseURI.} }
  OPTIONAL{
   SELECT (IRI(REPLACE(?fedoraPackageBaseURI, '\\$1', ?fedoraPackageString)) AS ?fedoraPackage) WHERE {wd:Q698 wdt:P3463 ?fedoraPackageString.
          wd:P3463 wdt:P1630 ?fedoraPackageBaseURI.} }
  OPTIONAL{
   SELECT (IRI(REPLACE(?framalibreIDBaseURI, '\\$1', ?framalibreIDString)) AS ?framalibreID) WHERE {wd:Q698 wdt:P4107 ?framalibreIDString.
          wd:P4107 wdt:P1630 ?framalibreIDBaseURI.} }
   OPTIONAL{wd:Q698 wdt:P170 ?creationAgent.
           ?creationAgent rdfs:label ?creationAgentLabel.
           FILTER (lang(?creationAgentLabel)="en") }
   OPTIONAL{SELECT (UUID() as ?publicationEvent) ?publicationDate WHERE {wd:Q698 wdt:P571 ?publicationDate.} }
OPTIONAL{SELECT (UUID() as ?inceptionEvent) ?inceptionDate WHERE {wd:Q698 wdt:P577 ?inceptionDate.} }
OPTIONAL{?environment wdt:P275 ?license}
OPTIONAL{?environment wdt:P3931 ?copyrightOwner}
  }

Try it!

User:Dipsode87

Contents

Projets[edit]

Tableau de bord des formats de fichier[edit]

Identifiant ARK dans Wikidata[edit]

Requêtes SPARQL[edit]

Map of the ARK Name assigning authorities[edit]

Number of ARKs in Wikidata[edit]

Most commonly supported file formats[edit]

All Wikidata statements whose source is the COPTR registry[edit]

Formats with MIME type = "text/plain" and extension != "txt"[edit]

MIME type of formats with extension "dat"[edit]

XML-based formats with their signature and reference URL[edit]

Alignement des propriétés Wikidata pour les logiciels avec PREMIS[edit]

Navigation menu

User:Dipsode87

Projets[edit]

Tableau de bord des formats de fichier[edit]

Identifiant ARK dans Wikidata[edit]

Requêtes SPARQL[edit]

Map of the ARK Name assigning authorities[edit]

Number of ARKs in Wikidata[edit]

Most commonly supported file formats[edit]

All Wikidata statements whose source is the COPTR registry[edit]

Formats with MIME type = "text/plain" and extension != "txt"[edit]

MIME type of formats with extension "dat"[edit]

XML-based formats with their signature and reference URL[edit]

Alignement des propriétés Wikidata pour les logiciels avec PREMIS[edit]

Navigation menu

Search