User:Fnielsen/Gender

Gender

Personer beskrevet på den danske Wikipedia per køn

Kønnet bestemt udfra Wikidata annotering og tilstedeværelsen af et link fra Wikidata til Den Danske Wikipedia.

SELECT 
  ?count ?gender ?genderLabel
WHERE {
  {
    SELECT
      (COUNT(DISTINCT ?person) AS ?count) ?gender
    WHERE {
      ?person wdt:P21 ?gender .
      ?person wdt:P31 wd:Q5 .
      ?article schema:about ?person .
      ?article schema:isPartOf <https://da.wikipedia.org/> .
    }
    GROUP BY ?gender
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
}
ORDER BY DESC(?count)

Try it!

2019-01-22: Mænd 58117, kvinder: 12070, Andre: 15+3+3+2+1=24

Kvindeforhold: 12070 / (58117 + 12070 + 24) = 17.2%

Mandeforhold: 58117 / (58117 + 12070 + 24) = 82.8%

Personer på Wikisource fordelt på køn

SELECT 
  ?count ?language ?gender ?genderLabel
WHERE {
  {
    SELECT 
      (COUNT(DISTINCT ?person) AS ?count) ?gender ?language
    WHERE {
      [] schema:isPartOf / wikibase:wikiGroup "wikisource" ;
         schema:inLanguage ?language ;
         schema:about ?person .
      ?person wdt:P21 ?gender .
      VALUES ?gender { wd:Q6581097 wd:Q6581072 }
    }
    GROUP BY ?gender ?language
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
}
ORDER BY ?language ?gender

Try it!

Kvindeforhold på den danske Wikipedia per dekade

#defaultView:LineChart
SELECT
  (STR(?year_) AS ?year) 
  (COALESCE(SAMPLE(?number_of_females), 0)
   / (COALESCE(SAMPLE(?number_of_females), 0)
      + SAMPLE(?number_of_males)) AS ?female_ratio)
WITH {
  SELECT
    (MIN(?years) AS ?year_)
    ?person
  WHERE {
    ?person wdt:P31 wd:Q5 .
    ?person wdt:P21 ?gender .
    ?article schema:about ?person .
    ?article schema:isPartOf <https://da.wikipedia.org/> .
    ?person wdt:P569 ?datetime . 
    FILTER (?datetime >= "1850-01-01T00:00:00Z"^^xsd:dateTime)    
    BIND(CONCAT(SUBSTR(STR(YEAR(?datetime)), 1, 3), "0-9") AS ?years)
  }
  GROUP BY ?person
} AS %persons
WHERE {
  { 
    SELECT
      ?year_
      (COUNT(?person) AS ?number_of_females)
    WHERE {
      INCLUDE %persons
      ?person wdt:P21 wd:Q6581072 .
    }
    GROUP BY ?year_
  }
  UNION
  {
    SELECT
      ?year_
      (COUNT(?person) AS ?number_of_males)
    WHERE {
      INCLUDE %persons
      ?person wdt:P21 wd:Q6581097
    }
    GROUP BY ?year_
  }  
}
GROUP BY ?year_
ORDER BY DESC(?year)

Try it!

De yngste er typisk kongelige børn.

SELECT
  ?person ?personLabel
WHERE { 
  {
    SELECT ?person WHERE {
      ?person wdt:P31 wd:Q5 .
      ?person wdt:P21 ?gender .
      ?article schema:about ?person .
      ?article schema:isPartOf <https://da.wikipedia.org/> .
      ?person wdt:P569 ?datetime . 
      FILTER (?datetime >= "2010-01-01T00:00:00Z"^^xsd:dateTime)    
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
}

Try it!

Mulige ny Wikipedia-artikler

• Modtagere af Q61268766