User:Taravyvan Adijene/SPARQL

Пружаншчына

Нарадзіліся

The following query uses these:

• Items: human (Q5)   , Pružany District (Q1885543)   

• Properties: instance of (P31)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , date of birth (P569)   , image (P18)   , VIAF ID (P214)   , IMDb ID (P345)   , coordinate location (P625)   

  # асобы, якія нарадзіліся на тэрыторыі Пружанскага раёну
  SELECT ?item ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?statements (COUNT(DISTINCT ?sitelink) AS ?linkshere) ?VIAF ?IMDb WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }   # фарматаваньне метак вываду
    BIND(xsd:integer(STRAFTER(STR(?item), "Q")) AS ?qid)                                        
    ?item wikibase:statements ?statements.                                                      # дзеля падліку сьцьверджаньняў
    OPTIONAL {
      ?sitelink schema:about ?item.
      ?sitelink schema:inLanguage ?lang.
    }                                                                                           # дзеля падліку спасылак на элемэнт
    ?item wdt:P31 wd:Q5.                                                                        # толькі людзі
    { ?item wdt:P19 wd:Q1885543. }                                                              # месца нараджэньня — Пружанскі раён
    UNION
    {
      ?item wdt:P19 ?pob.
      ?pob wdt:P131* wd:Q1885543.
    }                                                                                           # альбо месца нараджэньня знаходзіцца ў Пружанскім раёне
    OPTIONAL { ?item wdt:P569 ?birthDate. }
    OPTIONAL { ?item wdt:P19 ?pob. }
    OPTIONAL { ?item wdt:P18 ?pic. }
    OPTIONAL { ?item wdt:P214 ?VIAF. }
    OPTIONAL { ?item wdt:P345 ?IMDb. }
    OPTIONAL { ?pob wdt:P625 ?coord. }
  }
  GROUP BY ?item ?statements ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?VIAF ?IMDb
  ORDER BY DESC(?linkshere)
  

Try it!

The following query uses these:

• Items: human (Q5)   , Powiat prużański (Q4382545)   

• Properties: instance of (P31)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , date of birth (P569)   , image (P18)   , VIAF ID (P214)   , IMDb ID (P345)   , coordinate location (P625)   

  # асобы, якія нарадзіліся на тэрыторыі Пружанскага павету
  SELECT ?item ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?statements (COUNT(DISTINCT ?sitelink) AS ?linkshere) ?VIAF ?IMDb WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }   # фарматаваньне метак вываду
    BIND(xsd:integer(STRAFTER(STR(?item), "Q")) AS ?qid)                                        
    ?item wikibase:statements ?statements.                                                      # дзеля падліку сьцьверджаньняў
    OPTIONAL {
      ?sitelink schema:about ?item.
      ?sitelink schema:inLanguage ?lang.
    }                                                                                           # дзеля падліку спасылак на элемэнт
    ?item wdt:P31 wd:Q5.                                                                        # толькі людзі
    { ?item wdt:P19 wd:Q4382545. }                                                              # месца нараджэньня — Пружанскі павет (Польшча)
    UNION
    {
      ?item wdt:P19 ?pob.
      ?pob wdt:P131* wd:Q4382545.
    }                                                                                           # альбо месца нараджэньня знаходзіцца ў Пружанскім павеце
    OPTIONAL { ?item wdt:P569 ?birthDate. }
    OPTIONAL { ?item wdt:P19 ?pob. }
    OPTIONAL { ?item wdt:P18 ?pic. }
    OPTIONAL { ?item wdt:P214 ?VIAF. }
    OPTIONAL { ?item wdt:P345 ?IMDb. }
    OPTIONAL { ?pob wdt:P625 ?coord. }
  }
  GROUP BY ?item ?statements ?itemLabel ?pic ?birthDate ?pobLabel ?coord ?VIAF ?IMDb
  ORDER BY DESC(?linkshere)
  

Try it!

Населеныя пункты

The following query uses these:

• Items: Pružany District (Q1885543)   , human settlement (Q486972)   

• Properties: located in the administrative territorial entity (P131)   , instance of (P31)   , subclass of (P279)   , coordinate location (P625)   , image (P18)   

  #Населеныя пункты Пружаншчыны
  SELECT ?item ?itemLabel ?image ?coord WHERE {
    ?item wdt:P131 wd:Q1885543.
    ?item (wdt:P31/wdt:P279*) wd:Q486972.
    OPTIONAL { ?item wdt:P625 ?coord. }
    OPTIONAL { ?item wdt:P18 ?image. }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
  }
  GROUP BY ?item ?itemLabel ?image ?coord
  ORDER BY ?itemLabel ?item
  

Try it!

Славутасьці

The following query uses these:

• Items: Pružany District (Q1885543)   

• Properties: heritage designation (P1435)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , image (P18)   

Features: map (Q24515275)   

#defaultView:Map
#Усе пружанскія славутасьці
SELECT ?item ?itemLabel ?image ?coord ?катLabel WHERE {
  ?item wdt:P1435 ?кат                        # славутасьці
  { ?item wdt:P131 wd:Q1885543. }             # у Пружанскім раёне
  UNION
  {
    ?item wdt:P131 ?loc.
    ?loc wdt:P131* wd:Q1885543.
  }                                           # або ў населеным пункце Пружанскага раёну
  OPTIONAL { ?item wdt:P625 ?coord. }
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
}
GROUP BY ?item ?itemLabel ?image ?coord ?катLabel

Try it!

Сядзібы

The following query uses these:

• Items: palace (Q16560)   , castle (Q23413)   , fortress (Q57831)   , manor house (Q879050)   , estate (Q12292478)   , Pružany District (Q1885543)   

• Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , image (P18)   

Features: map (Q24515275)   

#defaultView:Map
#Усе пружанскія сядзібы
SELECT ?item ?itemLabel ?image ?coord WHERE {
  { ?item wdt:P31 wd:Q16560. }                # палацы
  UNION
  { ?item wdt:P31 wd:Q23413. }                # замкі
  UNION
  { ?item wdt:P31 wd:Q57831. }                # фартэцыі
  UNION
  { ?item wdt:P31 wd:Q879050. }               # сядзібы
  UNION
  { ?item wdt:P31 wd:Q12292478. }             # сядзібы
  { ?item wdt:P131 wd:Q1885543. }             # у Пружанскім раёне
  UNION
  {
    ?item wdt:P131 ?loc.
    ?loc wdt:P131* wd:Q1885543.
  }                                           # або ў населеным пункце Пружанскага раёну
  OPTIONAL { ?item wdt:P625 ?coord. }
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
}
GROUP BY ?item ?itemLabel ?image ?coord

Try it!

Усё, што мае каардынаты

The following query uses these:

• Items: Pružany District (Q1885543)   

• Properties: located in the administrative territorial entity (P131)   , coordinate location (P625)   

  #Нешта на Пружаншчыне з каардынатамі
  SELECT ?item ?itemLabel ?coord WHERE {
    { ?item wdt:P131 wd:Q1885543. }             # у Пружанскім раёне
    UNION
    {
      ?item wdt:P131 ?pob.
      ?pob wdt:P131* wd:Q1885543.
    }
    ?item wdt:P625 ?coord.                  # з каардынатамі
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
  }
  GROUP BY ?item ?itemLabel ?coord
  ORDER BY ?itemLabel ?item
  

Try it!

Беларусь

Асобы

Нарадзіліся ў Беларусі

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   

• Properties: instance of (P31)   , place of birth (P19)   , located in the administrative territorial entity (P131)   

  # найпапулярнейшыя ў ВікіЗьвестках асобы, народжаныя на тэрыторыі Беларусі
  SELECT ?item ?itemLabel ?statements ?itemDescription (COUNT(DISTINCT ?sitelink) AS ?linkshere) WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }   # фарматаваньне метак вываду
    BIND(xsd:integer(STRAFTER(STR(?item), "Q")) AS ?qid)                                        
    ?item wikibase:statements ?statements.                                                      # дзеля падліку сьцьверджаньняў
    OPTIONAL {
      ?sitelink schema:about ?item.
      ?sitelink schema:inLanguage ?lang.
    }                                                                                           # дзеля падліку спасылак на элемэнт
    ?item wdt:P31 wd:Q5.                                                                        # толькі людзі
    { ?item wdt:P19 wd:Q184. }                                                                  # месца нараджэньня — Беларусь
    UNION
    {
      ?item wdt:P19 ?pob.
      ?pob wdt:P131* wd:Q184.
    }                                                                                           # альбо месца нараджэньня знаходзіцца ў Беларусі
  }
  GROUP BY ?item ?statements ?itemLabel ?itemDescription
  ORDER BY DESC(?linkshere)
  LIMIT 100
  

Try it!

Нарадзіліся ў гэты дзень

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   

• Properties: instance of (P31)   , date of birth (P569)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , country of citizenship (P27)   , date of death (P570)   , coordinate location (P625)   , image (P18)   

  #Нарадзіліся ў зададзены дзень
  SELECT ?элемэнт ?элемэнтLabel ?месцаНараджэньняLabel ?каардынаты ?выява ?датаСьмерці
  WHERE
  {
      BIND(MONTH(NOW()) AS ?месяцАдбору)
      BIND(DAY(NOW()) AS ?дзеньАдбору)
  
      ?элемэнт wdt:P31 wd:Q5.                                                 # толькі людзі
      ?элемэнт wdt:P569 ?date.
      { ?элемэнт wdt:P19 wd:Q184. }                                           # месца нараджэньня — Беларусь
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
      UNION
      { ?элемэнт wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
      OPTIONAL { ?элемэнт wdt:P570 ?датаСьмерці. }
      OPTIONAL { ?элемэнт wdt:P19 ?месцаНараджэньня. }
      OPTIONAL { ?месцаНараджэньня wdt:P625 ?каардынаты. }
      OPTIONAL { ?элемэнт wdt:P18 ?выява. }
      FILTER (MONTH(?date) = ?месяцАдбору && DAY(?date) = ?дзеньАдбору)
      SERVICE wikibase:label {
          bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
      }
  }
  

Try it!

Памерлі ў дату

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   

• Properties: instance of (P31)   , date of death (P570)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , country of citizenship (P27)   , date of birth (P569)   , coordinate location (P625)   , place of death (P20)   , image (P18)   

  #Памерлі ў гэты дзень
  SELECT ?элемэнт ?элемэнтLabel ?выява ?датаНараджэньня ?месцаНараджэньняLabel ?каардынатыНараджэньня ?месцаСьмерціLabel
  WHERE
  {
      BIND(MONTH(NOW()) AS ?месяцАдбору)
      BIND(DAY(NOW()) AS ?дзеньАдбору)
  
      ?элемэнт wdt:P31 wd:Q5.                                                 # толькі людзі
      ?элемэнт wdt:P570 ?date.
      { ?элемэнт wdt:P19 wd:Q184. }                                           # месца нараджэньня — Беларусь
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
      UNION
      { ?элемэнт wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
      OPTIONAL { ?элемэнт wdt:P569 ?датаНараджэньня. }
      OPTIONAL { ?элемэнт wdt:P19 ?месцаНараджэньня. }
  #    OPTIONAL { ?месцаНараджэньня wdt:P625 ?каардынатыНараджэньня. }
      OPTIONAL { ?элемэнт wdt:P20 ?месцаСьмерці. }
  #    OPTIONAL { ?месцаСьмерці wdt:P625 ?каардынатыСьмерці. }
      OPTIONAL { ?элемэнт wdt:P18 ?выява. }
      FILTER (MONTH(?date) = ?месяцАдбору && DAY(?date) = ?дзеньАдбору)
      SERVICE wikibase:label {
          bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
      }
  }
  

Try it!

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   , Byelorussian Soviet Socialist Republic (Q2895)   , Northwestern Krai (Q1378225)   , Belarusian People's Republic (Q842199)   , Socialist Soviet Republic of Byelorussia (Q68678)   , Lithuanian–Byelorussian Soviet Socialist Republic (Q76236)   , Republic of Central Lithuania (Q523380)   

• Properties: instance of (P31)   , date of death (P570)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , country of citizenship (P27)   , place of death (P20)   , date of birth (P569)   , coordinate location (P625)   , image (P18)   , cause of death (P509)   

  #Памерлі 29—30 кастрычніка 1937
  # Навучыцца фільтраваць паўторныя элемэнты
  SELECT ?элемэнт ?элемэнтLabel ?выява (sample(?датаНараджэньня) as ?датаНараджэньня) ?месцаНараджэньняLabel ?каардынатыНараджэньня ?месцаСьмерціLabel ?прычынаLabel
  WHERE
  {
      BIND(1937 AS ?годАдбору)
      BIND(10 AS ?месяцАдбору)
      BIND(29 AS ?дзеньАдбору)
  
      ?элемэнт wdt:P31 wd:Q5.                                                 # толькі людзі
      ?элемэнт wdt:P570 ?date.
      { ?элемэнт wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
      UNION
      { ?элемэнт wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q2895. }                                # альбо месца нараджэньня знаходзіцца ў БССР
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q1378225. }                             # альбо месца нараджэньня знаходзіцца ў Паўночна-Заходнім краі
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q842199. }                              # альбо месца нараджэньня знаходзіцца ў БНР
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q68678. }                               # альбо месца нараджэньня знаходзіцца ў ССРБ
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q76236. }                               # альбо месца нараджэньня знаходзіцца ў ЛітБеле
      UNION
      { ?элемэнт wdt:P19/wdt:P131* wd:Q523380. }                              # альбо месца нараджэньня знаходзіцца ў Сярэдняй Літве
      UNION
      { ?элемэнт wdt:P20/wdt:P131* wd:Q184. }                                 # альбо месца сьмерці знаходзіцца ў Беларусі
      OPTIONAL { ?элемэнт wdt:P569 ?датаНараджэньня. }
      OPTIONAL { ?элемэнт wdt:P19 ?месцаНараджэньня. }
  #    OPTIONAL { ?месцаНараджэньня wdt:P625 ?каардынатыНараджэньня. }
      OPTIONAL { ?элемэнт wdt:P20 ?месцаСьмерці. }
  #    OPTIONAL { ?месцаСьмерці wdt:P625 ?каардынатыСьмерці. }
      OPTIONAL { ?элемэнт wdt:P18 ?выява. }
      OPTIONAL { ?элемэнт wdt:P509 ?прычына. }
      FILTER (YEAR(?date) = ?годАдбору && MONTH(?date) = ?месяцАдбору && DAY(?date) in (?дзеньАдбору, ?дзеньАдбору+1))
      SERVICE wikibase:label {
          bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
      }
  }
  GROUP BY ?элемэнт ?элемэнтLabel ?выява ?датаНараджэньня ?месцаНараджэньняLabel ?каардынатыНараджэньня ?месцаСьмерціLabel ?прычынаLabel
  # ORDER BY
  

Try it!

Тэнісісткі

The following query uses these:

• Items: tennis player (Q10833314)   , human (Q5)   , female (Q6581072)   , Belarus (Q184)   , tennis singles (Q18123880)   

• Properties: instance of (P31)   , sex or gender (P21)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , country for sport (P1532)   , image (P18)   , occupation (P106)   , ranking (P1352)   , end time (P582)   , sport (P641)   

  # Беларускія тэнісісткі
  SELECT ?item ?itemLabel ?image (sample(?рэйтынг) as ?рэйтынг)
  WHERE {
    BIND(wd:Q10833314 AS ?тэнісістка)                                  # замяніць на любую іншую прафэсію
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,pl,en". }   # фарматаваньне метак вываду
  
    ?item wdt:P31 wd:Q5.                                               # толькі людзі
    ?item wdt:P21 wd:Q6581072.                                         # жанчыны
    { ?item wdt:P19 wd:Q184. }                                         # месца нараджэньня — Беларусь
    UNION
    { ?item wdt:P19/wdt:P131* wd:Q184. }                               # альбо месца нараджэньня знаходзіцца ў Беларусі
    UNION
    { ?item wdt:P1532 wd:Q184. }                                       # альбо спартовае грамадзянства Беларусі
    ?item p:P106 ?прафэсія.                                            # маюць прафэсію
    ?прафэсія ps:P106 ?тэнісістка.                                     # …тэнісісткі
    FILTER NOT EXISTS { ?прафэсія pq:P582 ?x }                         # …бяз даты сканчэньня
    OPTIONAL { ?item wdt:P18 ?image. }                                 # выява
    OPTIONAL { ?item p:P1352 ?адзінкавы.                               # спартовы рэйтынг
               ?адзінкавы ps:P1352 ?рэйтынг.
               ?адзінкавы pq:P641 wd:Q18123880. }                      # адзінкавы
  }
  GROUP BY ?item ?itemLabel ?image ?рэйтынг
  ORDER BY ?itemLabel IF(BOUND(?рэйтынг), xsd:integer(?рэйтынг), 9999)
  

Try it!

Паводле стаці

The following query uses these:

• Items: human (Q5)   

• Properties: instance of (P31)   , sex or gender (P21)   

  # Колькасьць артыкулаў пра розныя плоці ў беларускай Вікіпэдыі
  SELECT (COUNT(?sex) as ?count) ?sexLabel
  WHERE {
    ?item wdt:P31 wd:Q5. # людзі
    ?item wdt:P21 ?sex. # з пазначанай плоцьцю
  
    ?article schema:about ?item. # якія маюць артыкул
    ?article schema:isPartOf <https://be-tarask.wikipedia.org/>. # у *беларускай* Вікіпэдыі
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "be-tarask,uk,en,ru". }
  } GROUP BY ?sexLabel
  ORDER BY DESC(?count)
  

Try it!

The following query uses these:

• Items: human (Q5)   , trans woman (Q1052281)   , trans man (Q2449503)   

• Properties: instance of (P31)   , sex or gender (P21)   , image (P18)   , country of citizenship (P27)   , occupation (P106)   , ethnic group (P172)   

  #Усе трансы ў беларускай Вікіпэдыі
  SELECT ?item ?itemLabel ?pic ?stateLabel (GROUP_CONCAT(DISTINCT ?job; SEPARATOR=", ") AS ?jobs) ?nationLabel
  WHERE {
    ?item wdt:P31 wd:Q5. # людзі
    { ?item wdt:P21 wd:Q1052281. }   # транс
    UNION
    { ?item wdt:P21 wd:Q2449503. }   # транс
    OPTIONAL { ?item wdt:P18 ?pic. }
    OPTIONAL { ?item wdt:P27 ?state. }
    OPTIONAL { ?item wdt:P106 [rdfs:label ?job]. FILTER(LANG(?job)='be-tarask'). }
    OPTIONAL { ?item wdt:P172 ?nation. }
  
    ?article schema:about ?item. # якія маюць артыкул
    ?article schema:isPartOf <https://be-tarask.wikipedia.org/>. # у *беларускай* Вікіпэдыі
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,en,ru". }
  }
  GROUP BY ?item ?itemLabel ?pic ?stateLabel ?nationLabel
  

Try it!

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   

• Properties: instance of (P31)   , place of birth (P19)   , country (P17)   , sex or gender (P21)   

  # Беларусы бяз стаці
  SELECT ?item ?itemLabel
  WHERE {
    ?item wdt:P31 wd:Q5.
    ?item wdt:P19 ?place.
    ?place wdt:P17 wd:Q184.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,uk,pl,en". }
    FILTER(NOT EXISTS { ?item wdt:P21 _:b6. })
  }
  

Try it!

Адсутныя

The following query uses these:

• Items: human (Q5)   , female (Q6581072)   , Belarus (Q184)   

• Properties: instance of (P31)   , sex or gender (P21)   , country of citizenship (P27)   

  # Беларускія жанчыны, пра якіх няма артыкулу ў нашай вікі
  SELECT ?person ?personLabel ?personDescription (COUNT(DISTINCT ?sitelink) as ?linkcount) WHERE {
    ?person wdt:P31 wd:Q5 . # чалавек
    ?person wdt:P21 wd:Q6581072 . # жанчына
    ?person wdt:P27 wd:Q184 . # зь Беларусі
    ?sitelink schema:about ?person . # старонкі Вікімэдыі пра асобы
    FILTER NOT EXISTS {
      ?links schema:about ?person . # старонкі Вікімэдыі пра асобы
      ?links schema:isPartOf <https://be-tarask.wikipedia.org/> . # акрамя беларускай Вікіпэдыі.
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en,uk,pl,ru". }
  } GROUP BY ?person ?personLabel ?personDescription
  ORDER BY DESC(?linkcount) 
  LIMIT 1000
  

Try it!

Адсутныя меткі

The following query uses these:

• Items: Belarus (Q184)   

• Properties: country of citizenship (P27)   

  # Элемэнты ВікіЗьвестак пра беларусаў, у якіх адсутнічае метка па-беларуску,
  # адсартаваныя паводле колькасьці спасылак.
  # Меткі выводзяцца мовамі, зададзенымі ў 8 радку (першая знойдзеная).
  # Калі запыт вісьне, трэба раскамэнтаваць 16 радок.
  SELECT ?item ?itemLabel ?itemDescription ?linkcount WHERE {
    ?item wdt:P27 wd:Q184.                                                      # грамадзяне Беларусі
    ?item wikibase:sitelinks ?linkcount.                                        # колькасьць спасылак
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en,uk,pl,ru". } # вывесьці метку першай знойдзенай мовай
    FILTER(?linkcount >= 2)                                                     # вывесьці толькі калі больш за 2 спасылкі
    FILTER(NOT EXISTS {
      ?item rdfs:label ?lang_label.
      FILTER((LANG(?lang_label)) = "be-tarask")                                 # калі няма па-беларуску
    })
  }
  ORDER BY DESC(?linkcount)
  # LIMIT 100
  

Try it!

Прычыны сьмерці

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   

• Properties: instance of (P31)   , cause of death (P509)   , place of birth (P19)   , country (P17)   , date of birth (P569)   , date of death (P570)   

  #Беларусы паводле прычыны сьмерці
  SELECT ?pid ?прэзыдэнт ?прычына_сьмерці ?нарадзіўся ?памёр WHERE {
      ?pid wdt:P31 wd:Q5.
      ?pid wdt:P509 ?cid.
      ?pid wdt:P19 ?place.
      ?place wdt:P17 wd:Q184.
      ?pid wdt:P569 ?нарадзіўся.
      ?pid wdt:P570 ?памёр.
  
      OPTIONAL {
          ?pid rdfs:label ?прэзыдэнт filter (lang(?прэзыдэнт) = "be-tarask") .
      }
      OPTIONAL {
          ?cid rdfs:label ?прычына_сьмерці filter (lang(?прычына_сьмерці) = "be-tarask") .
      }
  }
  

Try it!

Юбіляры

The following query uses these:

• Items: human (Q5)   , Belarus (Q184)   , Byelorussian Soviet Socialist Republic (Q2895)   , Northwestern Krai (Q1378225)   , Belarusian People's Republic (Q842199)   , Socialist Soviet Republic of Byelorussia (Q68678)   , Lithuanian–Byelorussian Soviet Socialist Republic (Q76236)   , Republic of Central Lithuania (Q523380)   

• Properties: instance of (P31)   , date of birth (P569)   , place of birth (P19)   , located in the administrative territorial entity (P131)   , country of citizenship (P27)   , place of death (P20)   , occupation (P106)   , date of death (P570)   

  #Нарадзіліся 100 гадоў таму
  SELECT ?асоба ?асобаLabel ?датаНараджэньня ?месцаНараджэньняLabel (GROUP_CONCAT(DISTINCT ?job; SEPARATOR=", ") AS ?jobs) 
  WHERE
  {
      BIND(YEAR(NOW()) AS ?годАдбору)
  
      ?асоба wdt:P31 wd:Q5.                                                 # толькі людзі
      ?асоба wdt:P569 ?date.
      { ?асоба wdt:P19 wd:Q184. }                                           # месца нараджэньня — Беларусь
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q184. }                                 # альбо месца нараджэньня знаходзіцца ў Беларусі
      UNION
      { ?асоба wdt:P27 wd:Q184. }                                           # альбо грамадзянства — Беларусь
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q2895. }                                # альбо месца нараджэньня знаходзіцца ў БССР
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q1378225. }                             # альбо месца нараджэньня знаходзіцца ў Паўночна-Заходнім краі
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q842199. }                              # альбо месца нараджэньня знаходзіцца ў БНР
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q68678. }                               # альбо месца нараджэньня знаходзіцца ў ССРБ
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q76236. }                               # альбо месца нараджэньня знаходзіцца ў ЛітБеле
      UNION
      { ?асоба wdt:P19/wdt:P131* wd:Q523380. }                              # альбо месца нараджэньня знаходзіцца ў Сярэдняй Літве
      UNION
      { ?асоба wdt:P20/wdt:P131* wd:Q184. }                                 # альбо месца сьмерці знаходзіцца ў Беларусі
  
      OPTIONAL { ?асоба wdt:P19 ?месцаНараджэньня. }
      OPTIONAL { ?асоба wdt:P106 [rdfs:label ?job]. FILTER(LANG(?job)='be-tarask'). }
  #    OPTIONAL { ?асоба wdt:P106 ?job. }
      OPTIONAL { ?асоба wdt:P569 ?датаНараджэньня. }
  #    OPTIONAL { ?асоба wdt:P570 ?датаСьмерці. }
      FILTER ((?годАдбору - YEAR(?date)) = 100)
  #    FILTER (floorMod(?годАдбору - YEAR(?date), 5) = 0)
      SERVICE wikibase:label {
          bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask,en".
      }
  }
  GROUP BY ?асоба ?асобаLabel ?датаНараджэньня ?месцаНараджэньняLabel
  

Try it!

Замкі, палацы ды фартэцыі

The following query uses these:

• Items: palace (Q16560)   , castle (Q23413)   , fortress (Q57831)   , Belarus (Q184)   

• Properties: instance of (P31)   , country (P17)   , coordinate location (P625)   , image (P18)   

Features: map (Q24515275)   

#Усе беларускія палацы
#defaultView:Map
SELECT ?item ?itemLabel ?image ?coord WHERE {
  { ?item wdt:P31 wd:Q16560. }                # палацы
  UNION
  { ?item wdt:P31 wd:Q23413. }                # замкі
  UNION
  { ?item wdt:P31 wd:Q57831. }                # фартэцыі
  ?item wdt:P17 wd:Q184.                      # у Беларусі
  OPTIONAL { ?item wdt:P625 ?coord. }
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
}

Try it!

Насельніцтва суседніх дзяржаваў

The following query uses these:

• Items: Belarus (Q184)   

• Properties: shares border with (P47)   , population (P1082)   , point in time (P585)   

  #defaultView:LineChart
  # Насельніцтва краінаў-суседак
  SELECT ?country ?year ?population ?countryLabel WHERE {
    {
      SELECT ?country ?year (AVG(?population) AS ?population) WHERE {
        {
          SELECT ?country (str(YEAR(?date)) AS ?year) ?population WHERE {
            ?country wdt:P47 wd:Q184;   # shares border with Biełaruś
                     p:P1082 ?populationStatement.
            ?populationStatement ps:P1082 ?population;
                                 pq:P585 ?date.
          }
        }
      }
      GROUP BY ?country ?year
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
  }
  

Try it!

ВікіЭкспэдыцыі

Палесьсе — славутасьці

The following query uses these:

• Items: Žytkavičy District (Q367015)   , Luniniec District (Q1885628)   , Stolin District (Q1885570)   

• Properties: heritage designation (P1435)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , image (P18)   

Features: map (Q24515275)   

#defaultView:Map
#Да вандроўкі на Палесьсе
SELECT ?item ?itemLabel ?image ?coord ?катLabel WHERE {
  ?item wdt:P1435 ?кат                        # славутасьці
  { ?item wdt:P131 wd:Q367015. }              # у Жыткавіцкім раёне
  UNION
  {
    ?item wdt:P131 ?loc.
    ?loc wdt:P131* wd:Q367015.
  }                                           # або ў населеным пункце Жыткавіцкага раёну
  UNION
  { ?item wdt:P131 wd:Q1885628. }             # у Лунінецкім раёне
  UNION
  {
    ?item wdt:P131 ?loc.
    ?loc wdt:P131* wd:Q367015.
  }                                           # або ў населеным пункце Лунінецкага раёну
  UNION
  { ?item wdt:P131 wd:Q1885570. }             # у Столінскім раёне
  UNION
  {
    ?item wdt:P131 ?loc.
    ?loc wdt:P131* wd:Q1885570.
  }                                           # або ў населеным пункце Столінскага раёну
  OPTIONAL { ?item wdt:P625 ?coord. }
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
}
GROUP BY ?item ?itemLabel ?image ?coord ?катLabel

Try it!

Палесьсе — усё з каардынатамі

The following query uses these:

• Items: Žytkavičy District (Q367015)   , Luniniec District (Q1885628)   , Stolin District (Q1885570)   

• Properties: located in the administrative territorial entity (P131)   , coordinate location (P625)   

  #Нешта на Палесьсі з каардынатамі
  SELECT ?item ?itemLabel ?coord WHERE {
    { ?item wdt:P131 wd:Q367015. }          # у Жыткавіцкім раёне
    UNION
    {
      ?item wdt:P131 ?loc.
      ?loc wdt:P131* wd:Q367015.
    }                                       # або ў населеным пункце Жыткавіцкага раёну
    UNION
    { ?item wdt:P131 wd:Q1885628. }         # у Лунінецкім раёне
    UNION
    {
      ?item wdt:P131 ?loc.
      ?loc wdt:P131* wd:Q367015.
    }                                       # або ў населеным пункце Лунінецкага раёну
    UNION
    { ?item wdt:P131 wd:Q1885570. }         # у Столінскім раёне
    UNION
    {
      ?item wdt:P131 ?loc.
      ?loc wdt:P131* wd:Q1885570.
    }                                       # або ў населеным пункце Столінскага раёну
    ?item wdt:P625 ?coord.                  # з каардынатамі
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],be-tarask". }
  }
  GROUP BY ?item ?itemLabel ?coord
  ORDER BY ?itemLabel ?item
  

Try it!

Глядзіце таксама

• User:Hsarrazin/SPARQL
• User:Ijon/Queries
• User:MKar/Query
• User:MartinPoulter/queries
• Wikidata workshops with Asaf Bartov in 2017 (Tallinn, Tartu)