User:Xaris333/FIFA Ranking/Control

Value

Each values must be smaller or equal 209.

• Items with ranking (P1352) with any value and with review score by (P447) --> FIFA (Q253414) as a qualifier, but with a value bigger than 209.

SELECT ?item ?value WHERE {
  ?item p:P1352 [ ps:P1352 ?value; pq:P447 wd:Q253414 ] .
  FILTER(?value > 209 ) .
}

Try it!

• Items with ranking (P1352) with any value and with determination method or standard (P459) --> FIFA World Rankings (Q180825) as a qualifier, but with a value bigger than 209.

SELECT ?item ?value WHERE {
  ?item p:P1352 [ ps:P1352 ?value; pq:P459 wd:Q180825 ] .
  FILTER(?value > 209 ) .
}

Try it!

• More general: Items with instance of (P31) --> national association football team (Q6979593) with value ranking (P1352) bigger than 209. (If not limited to FIFA Ranking).

SELECT ?item ?value WHERE {
  ?item wdt:P31 wd:Q6979593 .
  ?item p:P1352 [ ps:P1352 ?value] .
  FILTER(?value > 209 ) .
}

Try it!

With out a qualifier

• Items with ranking (P1352) with any value and with review score by (P447) --> FIFA (Q253414) as a qualifier, but with not determination method or standard (P459) as a qualifier.

SELECT ?item ?value WHERE {
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value; pq:P447 wd:Q253414 .
  MINUS { ?s pq:P459 [] }
}

Try it!

More general:

SELECT ?item ?value WHERE {
  ?item wdt:P31 wd:Q6979593 .
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value .
  MINUS { ?s pq:P459 [] }
}

Try it!

• Items with ranking (P1352) with any value and with determination method or standard (P459) --> FIFA World Rankings (Q180825) as a qualifier, but with not review score by (P447) as a qualifier.

SELECT ?item ?value WHERE {
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value; pq:P459 wd:Q180825 .
  MINUS { ?s pq:P447 [] }
}

Try it!

More general:

SELECT ?item ?value WHERE {
  ?item wdt:P31 wd:Q6979593 .
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value .
  MINUS { ?s pq:P447 [] }
}

Try it!

• Items with ranking (P1352) with any value and with review score by (P447) --> FIFA (Q253414) as a qualifier, but with not point in time (P585) as a qualifier.

SELECT ?item ?value WHERE {
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value; pq:P447 wd:Q253414 .
  MINUS { ?s pq:P585 [] }
}

Try it!

More general:

SELECT ?item ?value WHERE {
  ?item wdt:P31 wd:Q6979593 .
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value .
  MINUS { ?s pq:P585 [] }
}

Try it!

• Items with ranking (P1352) with any value and with review score by (P447) --> FIFA (Q253414) as a qualifier, but with not points for (P1358) as a qualifier. if and only if the qualifier point in time (P585) has a date later than 2011-08-23 (after that date FIFA Ranking pages have the point column).

SELECT ?item ?value ?time WHERE {
  ?item p:P1352 ?s .
  ?s ps:P1352 ?value; pq:P447 wd:Q253414; pqv:P585 [ wikibase:timeValue ?time ] .
  MINUS { ?s pq:P1358 [] }
  FILTER(?time > "+2011-08-23T00:00:00Z"^^xsd:dateTime) .  
}

Try it!

Source

Items with ranking (P1352) with any value and with review score by (P447) --> FIFA (Q253414) as a qualifier, but the source has no reference URL (P854).

SELECT ?item ?itemLabel ?rankingValue ?pointInTime WHERE {
  ?item p:P1352 ?s .
  ?s ps:P1352 ?rankingValue; pq:P447 wd:Q253414 .
  OPTIONAL { ?s pq:P585 ?pointInTime }
  MINUS { ?s prov:wasDerivedFrom [ pr:P854 [] ] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language '[AUTO_LANGUAGE],en' }
}

Try it!