User:Zygimantus/Queries
Jump to navigation
Jump to search
All coordinate-equipped items in Lithuania
Items in Lithuania that have coordinates but missing an image
Pages in ltwiki with Wikidata items without any statements
Featured articles of Lithuanian Wikipedia
Mathematicians (field of work in geometry) who are covered in other language Wikipedias but with entries missing in Lithuanian
Presidents of the Republic of Lithuania
People from Lithuania with age over 100 years and no date of death
Places in Lithuania by number of notable people born there
Lithuanian citizens by occupation
Lithuania men that have Olympedia people ID
Architects ordered by number of projects in Vilnius
Timeline of Lithuanian writers who were born between 1800 and 1900
Women scientist (loose meaning) in other language Wikipedias, but not in the Lithuanian Wikipedia
List of Lithuanian elderships (parishes)
Try it!
List of cities of Lithuania where no one famous was born and died
Counties of Lithuania
List of regional parks of Lithuania
Try it!
Rivers and canals in Lithuania.
Rivers without any mouth specified in Lithuania
Hillforts within 50 km of Kaunas in Lithuania
Lithuanian church buildings sorted by confessions
List of churchs in Lithuania
Pairs of churches in Lithuania that are within 25 metres of each other
Cemeteries in Lithuania near churches
Map of archaeological sites in Lithuania
Try it!
Lighthouses in Lithuania
Map of Lithuanian museums
Locations of bridges in Lithuania
Power plants in Lithuania
List of the hospitals in Lithuania
Towns of Lithuania with less than 1000 people that have a railway station
Railway network in Lithuania
Map of aerodromes in Lithuania
Timeline of inception of Lithuanian universities
Bubble chart of Lithuanian universities with the most people ever employed by them
===Template=== {{Sparql|query= ADD SPARQL HERE }}
General[edit]
All coordinate-equipped items in Lithuania[edit]
#title:All coordinate-equipped items in Lithuania
#defaultView:Map
SELECT ?item ?coord ?itemLabel ?layer
WHERE
{
?item wdt:P17 wd:Q37 .
?item p:P625 [ ps:P625 ?coord; psv:P625 ?coordV ] .
?item wdt:P31 ?type .
?coordV wikibase:geoLongitude ?longitude .
OPTIONAL { ?type rdfs:label ?layer. FILTER(LANG(?layer) = "en"). }
SERVICE wikibase:label {
bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
}
}
Items in Lithuania that have coordinates but missing an image[edit]
#title:Items in Lithuania that have coordinates but missing an image
SELECT ?item ?itemLabel ?coord WHERE {
?item wdt:P17 wd:Q37;
wdt:P625 ?coord.
FILTER(NOT EXISTS { ?item wdt:P18 ?image. })
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Pages in ltwiki with Wikidata items without any statements[edit]
#title:Pages in ltwiki with Wikidata items without any statements
SELECT (wd:Q29934200 as ?item) (substr(GROUP_CONCAT(?l),1,2000000) as ?all)
{
hint:Query hint:optimizer "None".
{
SELECT (CONCAT("[[",?n,"]] · ") as ?l)
{
?i wikibase:statements 0 . [ ] schema:about ?i ; schema:isPartOf <https://lt.wikipedia.org/>; schema:name ?n
}
}
}
Featured articles of Lithuanian Wikipedia[edit]
#title:Featured articles of Lithuanian Wikipedia
#defaultView:Table
SELECT ?lang ?name ?itemLabel ?sitelink ?linkcount ?item WHERE {
?item wikibase:sitelinks ?linkcount.
?sitelink schema:isPartOf <https://lt.wikipedia.org/>.
?sitelink schema:name ?name;
schema:inLanguage ?lang;
schema:about ?item;
wikibase:badge wd:Q17437796.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?linkcount)
Mathematicians (field of work in geometry) who are covered in other language Wikipedias but with entries missing in Lithuanian[edit]
#title:Mathematicians (field of work in geometry) who are covered in other language Wikipedias but with entries missing in Lithuanian
#Note: Link count is from Wikipedias only not from other projects
SELECT ?item ?itemLabel (COUNT(?wpSitelink) as ?sitelinks) WHERE {
?item wdt:P31 wd:Q5.
?item wdt:P106 wd:Q170790.
?item wdt:P101 wd:Q8087.
optional {?wpSitelink schema:about ?item . ?wpSitelink schema:isPartOf [ wikibase:wikiGroup "wikipedia" ] .}
filter not exists { ?ltwiki schema:about ?item; schema:isPartOf <https://lt.wikipedia.org/> .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,es,fr". }
}
group by ?item ?itemLabel
ORDER BY DESC(?sitelinks)
Lithuania[edit]
Presidents of the Republic of Lithuania[edit]
#title:Presidents of the Republic of Lithuania
#defaultView:Table
SELECT DISTINCT ?item ?itemLabel ?positionLabel ?start ?end WHERE
{
?item wdt:P31 wd:Q5 ;
p:P39 ?position_statement .
?position_statement ps:P39 ?position ;
pq:P580 ?start FILTER (?start >= "1919-01-01T00:00:00Z"^^xsd:dateTime) .
?position wdt:P279* wd:Q878222 .
OPTIONAL { ?position_statement pq:P582 ?x }
OPTIONAL { ?item wdt:P18 ?picture }
bind(if(bound(?x), ?x, NOW()) as ?end )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
}
ORDER BY ASC(?start) ?itemLabel
People from Lithuania with age over 100 years and no date of death[edit]
#title:People from Lithuania with age over 100 years and no date of death
SELECT DISTINCT ?item ?itemLabel ?_date_of_birth WHERE {
?item wdt:P31 wd:Q5;
wdt:P27 wd:Q37;
wdt:P569 ?_date_of_birth.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
FILTER((NOT EXISTS { ?item wdt:P570 ?date. }) && ((YEAR(?_date_of_birth)) < 1920 ))
}
Places in Lithuania by number of notable people born there[edit]
#title:Places in Lithuania by number of notable people born there
#defaultView:BubbleChart
SELECT ?place ?placeLabel ?count WHERE {
{
SELECT ?place (COUNT(?item) AS ?count) WHERE {
?item wdt:P19 ?place.
?place wdt:P17 wd:Q37.
}
GROUP BY ?place
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?count)
Lithuanian citizens by occupation[edit]
#title:Lithuanian citizens by occupation
#defaultView:BubbleChart
SELECT ?cid ?cause (count(*) as ?count)
WHERE
{
?pid wdt:P31 wd:Q5 .
?pid wdt:P27 wd:Q37 .
?pid wdt:P106 ?cid .
OPTIONAL {
?cid rdfs:label ?cause
filter (lang(?cause) = "lt")
}
}
GROUP BY ?cid ?cause
ORDER BY DESC(?count) ASC(?cause)
Lithuania men that have Olympedia people ID[edit]
#title:Lithuania men that have Olympedia people ID
SELECT ?item ?itemLabel ?born ?died ?olid WHERE {
VALUES ?lit {
wd:Q37
}
?item wdt:P27 ?lit;
wdt:P21 wd:Q6581097;
wdt:P8286 ?olid.
OPTIONAL { ?item wdt:P569 ?born. }
OPTIONAL { ?item wdt:P570 ?died. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Architects ordered by number of projects in Vilnius[edit]
#title:Architects ordered by number of projects in Vilnius
#defaultView:BubbleChart
SELECT ?archLabel (COUNT(DISTINCT ?city) AS ?count) WHERE {
?city (wdt:P131/(wdt:P131*)) wd:Q216;
wdt:P84 ?arch.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?arch ?archLabel
ORDER BY DESC (?count)
Timeline of Lithuanian writers who were born between 1800 and 1900[edit]
#title:Timeline of Lithuanian writers who were born between 1800 and 1900
#defaultView:Timeline
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?birth WHERE {
?item wdt:P106 wd:Q36180;
wdt:P27 wd:Q37;
wdt:P570 ?death;
wdt:P569 ?birth.
FILTER((?birth > "1800-01-01"^^xsd:dateTime) && (?birth < "1900-01-01"^^xsd:dateTime))
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Women scientist (loose meaning) in other language Wikipedias, but not in the Lithuanian Wikipedia[edit]
#title:Women scientist (loose meaning) in other language Wikipedias, but not in the Lithuanian Wikipedia
SELECT ?item ?itemLabel ?linkcount WHERE {
?item wdt:P31 wd:Q5;
wdt:P21 wd:Q6581072;
wdt:P106 ?occupation;
wikibase:sitelinks ?linkcount.
FILTER(?linkcount > 14 )
MINUS {
?sitelinklt schema:isPartOf <https://lt.wikipedia.org/>;
schema:about ?item.
}
?occupation (wdt:P279*) wd:Q901.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?linkcount
ORDER BY DESC (?linkcount)
List of Lithuanian elderships (parishes)[edit]
#title:List of Lithuanian elderships (parishes)
SELECT ?item ?itemLabel ?munic ?municLabel ?area ?pop WHERE {
?item wdt:P31 wd:Q2298305.
OPTIONAL { ?item wdt:P131 ?munic. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?item wdt:P2046 ?area. }
OPTIONAL { ?item wdt:P1082 ?pop. }
}
Location of Lithuanian cities with a population count greater than 10.000[edit]
#filter:Location of Lithuanian cities with a population count greater than 10.000
#defaultView:Map
SELECT DISTINCT ?city ?cityLabel ?population ?location ?lon ?lat WHERE {
# get cities (or classes based on city) in Lithuania
?city wdt:P31/wdt:P279* wd:Q515 ;
wdt:P17 wd:Q37 .
# get population and location of the city
?city wdt:P1082 ?population ;
wdt:P625 ?location .
# we're only interested in cities with a population count > 50.000
FILTER (abs(?population) > 10000)
# extract lat and lon
?city p:P625 ?coordinate.
?coordinate psv:P625 ?coordinate_node.
?coordinate_node wikibase:geoLongitude ?lon.
?coordinate_node wikibase:geoLatitude ?lat.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
List of cities of Lithuania where no one famous was born and died[edit]
#title:List of cities of Lithuania where no one famous was born and died
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?coor ?popul WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q7930989;
wdt:P17 wd:Q37.
MINUS { _:b3 ((wdt:P19|wdt:P20)/(wdt:P131*)) ?item. }
?item wdt:P625 ?coor;
wdt:P1082 ?popul.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?popul)
Counties of Lithuania[edit]
#title:Counties of Lithuania
#defaultView:Table
SELECT ?muni ?muniLabel ?capitalLabel ?area ?population WHERE {
?muni wdt:P31 wd:Q273789;
wdt:P36 ?capital;
wdt:P2046 ?area;
wdt:P1082 ?population.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?population)
List of regional parks of Lithuania[edit]
#title:List of regional parks of Lithuania
#defaultView:Table
select ?park ?parkLabel ?area ?site {
?park wdt:P31/wdt:P279* wd:Q6063204 .
?park wdt:P17 wd:Q37 .
OPTIONAL { ?park wdt:P2046 ?area . }
OPTIONAL { ?park wdt:P856 ?site . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
order by ?parkLabel
All items with a property (Kultūros vertybių registro unikalus objekto kodas)[edit]
# Sample to query all values of a property
# Property talk pages on Wikidata include basic queries adapted to each property
SELECT
?item ?itemLabel
?value ?valueLabel
?whatLabel
# valueLabel is only useful for properties with item-datatype
WHERE
{
?item wdt:P10040 ?value .
?item wdt:P31 ?what
# change P10040 to another property
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
# remove or change limit for more results
LIMIT 10
Rivers and canals in Lithuania[edit]
#title:Rivers and canals in Lithuania.
#defaultView:Map{"hide":["?coord"],"layer":"?canalLabel"}
SELECT DISTINCT ?item ?label ?canal ?canalLabel ?coord WHERE {
{SELECT * {
{SELECT * {
?item wdt:P17 wd:Q37 ;
wdt:P625 ?coord ;
rdfs:label ?label .
FILTER(LANG(?label) = "lt").
} }
{ ?item p:P177 [ ps:P177 ?canal ] } UNION { ?item p:P2505 [ ps:P2505 ?canal ] } UNION { ?item p:P206 [ ps:P206 ?canal ] }
} }
VALUES ?watercourse { wd:Q4022 wd:Q12284 }
FILTER EXISTS { ?canal wdt:P31/wdt:P279* ?watercourse }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?label ?canal ?canalLabel ?coord
ORDER BY ?canalLabel
Rivers without any mouth specified in Lithuania[edit]
#title:Rivers without any mouth specified in Lithuania
#defaultView:Table
SELECT DISTINCT ?item ?itemLabel WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q4022.
?item wdt:P17 wd:Q37.
FILTER(NOT EXISTS { ?item wdt:P403 ?mouth. })
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY (?itemLabel)
Hillforts within 50 km of Kaunas in Lithuania[edit]
#title:Hillforts within 50 km of Kaunas in Lithuania
#defaultView:Map
SELECT ?item ?itemLabel ?coordinate ?pic WHERE {
wd:Q4115712 wdt:P625 ?Center.
SERVICE wikibase:around {
?item wdt:P625 ?coordinate.
bd:serviceParam wikibase:center ?Center;
wikibase:radius "50".
}
FILTER(EXISTS { ?item (wdt:P31/(wdt:P279*)) wd:Q744099. })
OPTIONAL { ?item wdt:P18 ?pic. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Lithuanian church buildings sorted by confessions[edit]
#title:Lithuanian church buildings sorted by confessions
#defaultView:Map{"hide": ["?layer"]}
SELECT
?templom ?templomLabel (SAMPLE(?templomLocation) AS ?templomLocation_) (SAMPLE(?templomImage) AS ?templomImage_)
(IF(?ref, "Calvinist" , " ") AS ?refLabel)
(IF(?evang, "Lutheran", " ") AS ?evangLabel)
(IF(?kat, "Catholic", " ") AS ?katLabel)
(IF(?ort, "Eastern Orthodox", " ") AS ?ortLabel)
(CONCAT(?refLabel, ?evangLabel, ?katLabel, ?ortLabel) AS ?layer)
WHERE {
?templom wdt:P31/wdt:P279* wd:Q16970;
wdt:P17 wd:Q37;
BIND(EXISTS { ?templom wdt:P31 wd:Q103842783. } AS ?ref)
BIND(EXISTS { ?templom wdt:P31 wd:Q56242275. } AS ?evang)
BIND(EXISTS { ?templom wdt:P31/wdt:P279* wd:Q2031836. } AS ?ort)
BIND(EXISTS { ?templom wdt:P31/wdt:P279* wd:Q1088552. } AS ?kat)
OPTIONAL { ?templom wdt:P625 ?templomLocation. }
OPTIONAL { ?templom wdt:P18 ?templomImage. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?templom ?templomLabel ?person ?personLabel ?ref ?evang ?kat ?ort
List of churchs in Lithuania[edit]
#title:List of churchs in Lithuania
#defaultView:Map
SELECT DISTINCT ?church ?churchLabel ?coor
WHERE {
?church wdt:P31 wd:Q16970 ;
?range wd:Q37;
wdt:P625 ?coor.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Pairs of churches in Lithuania that are within 25 metres of each other[edit]
#title:Pairs of churches in Lithuania that are within 25 metres of each other
SELECT ?church ?churchLabel ?churchloc ?dist ?other ?otherLabel
WHERE
{
?church wdt:P31 wd:Q16970 . # this thing is a church
?church wdt:P17 wd:Q37 . # and it's in the UK
?church wdt:P625 ?churchloc . # and it has a location
?other wdt:P31 wd:Q16970 . # another thing is also a church
SERVICE wikibase:around {
?other wdt:P625 ?otherloc .
bd:serviceParam wikibase:center ?churchloc .
bd:serviceParam wikibase:radius "0.025" . # and is pretty much exactly on the same spot (±25m)
}
FILTER (STR(?church) > STR(?other)) # filter so each pair only shows up once
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
BIND(geof:distance(?churchloc, ?otherloc) as ?dist)
}
ORDER BY ?dist
Cemeteries in Lithuania near churches[edit]
#title:Cemeteries in Lithuania near churches
SELECT ?cemetery ?cemeteryLabel ?churchLabel ?church ?distance {
?cemetery wdt:P31/wdt:P279* wd:Q39614;
wdt:P17 wd:Q37;
wdt:P625 ?cem_coords.
SERVICE wikibase:around {
?church wdt:P625 ?chr_coords.
bd:serviceParam wikibase:center ?cem_coords.
bd:serviceParam wikibase:radius "0.02".
bd:serviceParam wikibase:distance ?distance.
}
FILTER EXISTS {
?church wdt:P31/wdt:P279* wd:Q16970.
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en". }
}
Map of archaeological sites in the United Kingdom[edit]
#title:Map of archaeological sites in Lithuania
#defaultView:Map
SELECT ?library ?libraryLabel ?coords WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?library (wdt:P31/wdt:P279*) wd:Q839954.
?library wdt:P17 wd:Q37.
?library wdt:P625 ?coords.
}
Map of castles in Lithuania[edit]
##title:Map of castles in Lithuania
#defaultView:Map{"hide": ["?coords", "?layer"]}
SELECT DISTINCT ?library ?libraryLabel ?coords ?layer WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?type rdfs:label ?layer.
?library rdfs:label ?libraryLabel }
?library wdt:P31 ?type .
OPTIONAL { ?library wdt:P18 ?image }.
?type wdt:P279* wd:Q23413.
?library wdt:P17 wd:Q37.
?library wdt:P625 ?coords.
}
A map of all lighthouses in Lithuania[edit]
#title:Lighthouses in Lithuania
#defaultView:Map
SELECT DISTINCT ?item ?name ?coor ?image ?character ?admiralty
WHERE
{
?item wdt:P31 wd:Q39715 .
?item wdt:P17 wd:Q37 .
OPTIONAL { ?item wdt:P18 ?image }
OPTIONAL { ?item wdt:P625 ?coor }
OPTIONAL { ?item wdt:P1448 ?name }
OPTIONAL { ?item wdt:P1030 ?character }
OPTIONAL { ?item wdt:P2923 ?foc }
OPTIONAL { ?item wdt:P2929 ?lys }
OPTIONAL { ?item wdt:P3562 ?admiralty }
SERVICE wikibase:label { bd:serviceParam wikibase:language "lt,en" }
}
Map of Lithuanian museums[edit]
#title:Map of Lithuanian museums
#defaultView:Map
SELECT ?museum ?museumLabel ?coord ?image WHERE {
?museum (wdt:P31/(wdt:P279*)) wd:Q33506;
wdt:P17 wd:Q37.
OPTIONAL { ?museum wdt:P625 ?coord. }
OPTIONAL { ?museum wdt:P18 ?image. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Locations of bridges in Lithuania[edit]
#title:Locations of bridges in Lithuania
#defaultView:Table
SELECT ?item ?itemLabel ?itemDescription ?length ?crossesLabel ?municLabel ?coord WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q12280;
wdt:P17 wd:Q37;
wdt:P625 ?coord;
OPTIONAL { ?item wdt:P177 ?crosses }
OPTIONAL { ?item wdt:P131 ?munic }
OPTIONAL { ?item wdt:P2043 ?length }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?length)
Power plants in Lithuania[edit]
#title:Power plants in Lithuania
#defaultView:Map
SELECT ?item ?itemLabel ?coords WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q159719;
wdt:P17 wd:Q37.
OPTIONAL { ?item wdt:P625 ?coords. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
List of the hospitals in Lithuania[edit]
#title:List of the hospitals in Lithuania
#defaultView:Map
SELECT ?item ?itemLabel ?geo WHERE {
?item wdt:P31/wdt:P279* wd:Q16917;
wdt:P17 wd:Q37;
wdt:P625 ?geo .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100
Towns of Lithuania with less than 1000 people that have a railway station[edit]
#title:Towns of Lithuania with less than 1000 people that have a railway station
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?place ?placeLabel ?population ?countryLabel ?coords ?image WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q55488;
wdt:P131 ?place.
?place wdt:P1082 ?population;
wdt:P17 ?country.
?item wdt:P17 wd:Q37.
OPTIONAL { ?item wdt:P625 ?coords. }
OPTIONAL { ?item wdt:P18 ?image. }
FILTER(?population < 1000 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY (?population)
Railway network in Lithuania[edit]
#title:Railway network in Lithuania
#defaultView:Map{"hide":["?coord1", "?coord2", "?line"]}
SELECT * WHERE {
?comm1 wdt:P31 wd:Q55488;
wdt:P17 wd:Q37;
wdt:P625 ?coord1;
wdt:P197 ?comm2.
MINUS {
?comm1 p:P31 _:b11.
_:b11 ps:P31 wd:Q55488;
pq:P582 _:b10.
}
MINUS {
?comm2 p:P31 _:b13.
_:b13 ps:P31 wd:Q55488;
pq:P582 _:b12.
}
?comm2 wdt:P625 ?coord2.
?comm1 p:P625 _:b16.
_:b16 ps:P625 _:b14;
psv:P625 _:b15.
_:b15 wikibase:geoLongitude ?coord1lon;
wikibase:geoLatitude ?coord1lat.
?comm2 p:P625 _:b19.
_:b19 ps:P625 _:b17;
psv:P625 _:b18.
_:b18 wikibase:geoLongitude ?coord2lon;
wikibase:geoLatitude ?coord2lat.
BIND(CONCAT("LINESTRING (", STR(?coord1lon), " ", STR(?coord1lat), ",", STR(?coord2lon), " ", STR(?coord2lat), ")") AS ?str)
BIND(STRDT(?str, geo:wktLiteral) AS ?line)
}
Map of aerodromes in Lithuania[edit]
#title:Map of aerodromes in Lithuania
#defaultView:Map
SELECT ?item ?itemLabel (SAMPLE(?coordinate_location) AS ?coord) WHERE {
?item (p:P31/ps:P31/(wdt:P279*)) wd:Q62447.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en". }
?item wdt:P17 wd:Q37.
MINUS { ?item wdt:P576 _:b2. }
OPTIONAL { ?item wdt:P625 ?coordinate_location. }
}
GROUP BY ?item ?itemLabel
Timeline of inception of Lithuanian universities[edit]
#title:Timeline of inception of Lithuanian universities
#defaultView:Timeline
SELECT DISTINCT ?universidad ?universidadLabel ?fecha WHERE {
?universidad wdt:P17 wd:Q37 ;
wdt:P31 wd:Q3918 ;
wdt:P571 ?fecha.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
}
Bubble chart of Lithuanian universities with the most people ever employed by them[edit]
#title:Bubble chart of Lithuanian universities with the most people ever employed by them
#defaultView:BubbleChart
SELECT DISTINCT ?uLabel (COUNT(?r) as ?pop) ?u
{
?r wdt:P31 wd:Q5.
?r wdt:P108 ?u.
?u wdt:P17 wd:Q37.
?u wdt:P31/wdt:P279* wd:Q3918.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?pop ?uLabel ?u
ORDER BY DESC(?pop)