User talk:Bouzinac/Archive 1

Welcome to Wikidata, Bouzinac!

Wikidata is a free knowledge base that you can edit! It can be read and edited by humans and machines alike and you can go to any item page now and add to this ever-growing database!

Need some help getting started? Here are some pages you can familiarize yourself with:

• Introduction – An introduction to the project.
• Wikidata tours – Interactive tutorials to show you how Wikidata works.
• Community portal – The portal for community members.
• User options – including the 'Babel' extension, to set your language preferences.
• Contents – The main help page for editing and using the site.
• Project chat – Discussions about the project.
• Tools – A collection of user-developed tools to allow for easier completion of some tasks.

Please remember to sign your messages on talk pages by typing four tildes (~~~~); this will automatically insert your username and the date.

If you have any questions, don't hesitate to ask on Project chat. If you want to try out editing, you can use the sandbox to try. Once again, welcome, and I hope you quickly feel comfortable here, and become an active editor for Wikidata.

Best regards! Liuxinyu970226 (talk) 09:26, 28 March 2016 (UTC)

Disambiguation pages

Hi. I noticed that you put an "opposite" for a disambiguation page. These pages are about a form of word, and as such these pages don't have a meaning, so they shouldn't have opposites, etc. Thanks.  — billinghurst sDrewth 09:10, 1 January 2017 (UTC)

Aéroport et base aérienne

Bonjour,

Suite à ta demande, par curiosité, je viens de regarder et il y a actuellement 192 éléments qui sont indiqués en instance of (P31) à la fois comme airport (Q1248784) et air base (Q695850). Pourrais-tu y jetter un coup d’œil ?

SELECT ?q ?qLabel WHERE {
  ?q wdt:P31 wd:Q1248784 ; wdt:P31 wd:Q695850 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!

Try it!

Cdlt, VIGNERON (talk) 07:30, 18 July 2018 (UTC)

Bonjour, merci déjà pour tes modifs en masse. As tu moyen d'affiner cette requête avec les aéroports qui sont aujourd'hui considérés airport (Q1248784) ET air base (Q695850) (en même temps quoi). De même, si tu avais moyen d'éditer la liste des aéroports qui sont affectés le [même IATA airport code (P238)] OU le [même ICAO airport code (P239)] [exemple concret : Temindung Airport (Q1932805) et Samarinda International Airport (Q1927133)]. Je suis à la chasse des doublons et ça ressemble plus à un travail de fourmi...Autre question : si je fais une modif, j'ai l'impression que le résultat est pas immédiatement visible quand je relance une requête sparql. Merci à toi ! --Bouzinac (talk) 14:21, 18 July 2018 (UTC)

Aie, il y a aussi cohabitation avec aerodrome (Q62447). Qu'en penses-tu, est ce normal ? Y a-t-il une guideline quelque part pour ce genre de synonymes possibles ?--Bouzinac (talk) 14:31, 18 July 2018 (UTC)

Et même international airport (Q644371)...--Bouzinac (talk) 21:13, 18 July 2018 (UTC)

Bonjour,

De rien pour les modifs « en masse » (même si après plus d'un million de modifs, une cinquantaine cela ne semble pas vraiment être « en masse »), avec QuickStatements cela prend littéralement 1 minute.

Pour airport (Q1248784) et air base (Q695850) simultanément, aurais-tu un exemple d'élément où c'est le cas ? (j'ai besoin de voir la structure pour faire la requête correspondante).

Pour les éléments avec le même IATA airport code (P238), c'est un peu plus complexe mais voici déjà une première requête :

SELECT DISTINCT ?code ?item1 ?item2 ?item1Label ?item2Label WHERE {
  ?item1 wdt:P238 ?code . #1er élément avec un code AITA
  ?item2 wdt:P238 ?code . #2e élément avec le même code
  FILTER ( ?item1 != ?item2 ) #éléments différents
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". } #récupérer le libellé en français si possible sinon en anglais
}
ORDER BY ?code #trier les résultats selon le code AITA

Try it!

Try it!

(en fait ce n'est pas parfait car parfois plus de deux éléments partagent le même code, du coup, par symétrie, toute les lignes sont en double - et parfois même plus si 3 éléments partagent le même code)

Effectivement, pour éviter de trop consommer de puissance de calcul si une même requête SPARQL est lancé deux fois de suite dans un court laps de temps, la seconde fois le résultat n'est pas toujours recalculé mais c'est juste le premier calcul qui est affiché. Une astuce pour détourner cela est de modifier un tout petit peu la requête SPARQL, par exemple d'ajouter ou de retirer une espace avant un point (cela ne change rien, la syntaxe n'en tient pas compte mais c'est suffisant pour tromper le système).

Cdlt, VIGNERON (talk) 12:21, 19 July 2018 (UTC)

dédoublonnage en cours

SELECT DISTINCT ?code ?item1 ?nature1Label ?item2 ?item1Label ?item2Label WHERE {
  ?item1 wdt:P31/wdt:P279* wd:Q1248784. 
  ?item1 wdt:P238 ?code . #1er élément avec un code AITA 
  ?item2 wdt:P238 ?code . #2e élément avec le même code 
?item1 wdt:P31 ?nature1.  
  FILTER ( ?item1 != ?item2 ) #éléments différents
    minus {?item1 wdt:P31/wdt:P279* wd:Q695850.}                        # exclude military airports
  minus {?item1 wdt:P31/wdt:P279* wd:Q7373622.}
    minus {?item2 wdt:P31/wdt:P279* wd:Q695850.}                        # exclude military airports
   minus {?item2 wdt:P31/wdt:P279* wd:Q7373622.}
  minus {?item1 wdt:P576 ?date}    
  minus {?item2 wdt:P576 ?date}  
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language  "fr,en". } #récupérer le libellé en français si possible sinon en anglais
}
ORDER BY ?code #trier les résultats selon le code AITA

Try it!

Try it!

Bonjour VIGNERON (talk • contribs • logs), j'aimerais n'afficher dans ma liste de dédoublonnage que les seuls aéroports qui semblent avoir un même code en même temps (ie pour qui il n'existe pas de date de fin)

SELECT DISTINCT ?code ?item1 ?nature1Label ?item2 ?item1Label ?item2Label WHERE {
  ?item1 wdt:P31/wdt:P279* wd:Q1248784. 
  ?item1 wdt:P238 ?code . #1er élément avec un code AITA 
  ?item2 wdt:P238 ?code . #2e élément avec le même code 
   ?item1 wdt:P31 ?nature1.  
  FILTER ( ?item1 != ?item2 ) #éléments différents
    minus {?item1 wdt:P31/wdt:P279* wd:Q695850.}                        # exclude military airports
  minus {?item1 wdt:P31/wdt:P279* wd:Q7373622.}
    minus {?item2 wdt:P31/wdt:P279* wd:Q695850.}                        # exclude military airports
   minus {?item2 wdt:P31/wdt:P279* wd:Q7373622.}
  minus {?item1 wdt:P576 ?date}    
  minus {?item2 wdt:P576 ?date}  
FILTER NOT EXISTS { ?item1 pq:P582 ?x1 }# est ce bien censé retirer les codes qui possèdent une date de fin ?
  FILTER NOT EXISTS { ?item2 pq:P582 ?x2 }
  FILTER NOT EXISTS { ?code pq:P582 ?x3 }

  SERVICE wikibase:label { bd:serviceParam wikibase:language  "fr,en". } #récupérer le libellé en français si possible sinon en anglais
}
ORDER BY ?code #trier les résultats selon le code AITA

Try it!

Try it!

SELECT DISTINCT ?code ?item1 ?nature1Label ?item1Label ?item2 ?item2Label WHERE {
  ?item1 wdt:P31/wdt:P279* wd:Q1248784. 
#  ?item1 wdt:P238 ?code .        #oddly, we don't need this - see a couple of rows below
  ?item1 wdt:P31 ?nature1.        #What kind of airport, aérodrome is it?
  ?item1 p:P238 ?statement1.        #we replace the ?item1 wdt:P238 ?code . bit by getting the P238 property statement
  ?statement1 ps:P238 ?code.          #get the IATA code assicated with the property statement
  minus { ?statement1 pq:P582 [].} #minus any end dated codes
#  ?item2 wdt:P238 ?code .         #Second with code IATA
  ?item2 p:P238 ?statement2.        #we replace the ?item2 wdt:P238 ?code . bit by getting the P238 property statement
  ?statement2 ps:P238 ?code.          #get the IATA code assicated with the property statement
  minus { ?statement2 pq:P582 [].} #minus any end dated codes
  FILTER ( ?item1 != ?item2 )     #Only différents elements
  minus {?item1 wdt:P31/wdt:P279* wd:Q695850.}      # exclude military airports
  minus {?item1 wdt:P31/wdt:P279* wd:Q1311670.}     # exclude railways stations
  minus {?item1 wdt:P31/wdt:P279* wd:Q7373622.}     # exclude Royal Air Force
  minus {?item1 wdt:P31/wdt:P279* wd:Q502074.}      # exclude héliports
  minus {?item1 wdt:P576 ?date}                     # exclude destructed airports
  minus {?item2 wdt:P31/wdt:P279* wd:Q695850.}      # exclude military airports
  minus {?item2 wdt:P31/wdt:P279* wd:Q1311670.}     # exclude railways stations
  minus {?item2 wdt:P31/wdt:P279* wd:Q7373622.}     # exclude Royal Air Force
  minus {?item2 wdt:P31/wdt:P279* wd:Q502074.}      # exclude héliports
  minus {?item2 wdt:P576 ?date}                     # exclude destructed airports
  SERVICE wikibase:label { bd:serviceParam wikibase:language  "fr,en". } #récupérer le libellé en français si possible sinon en anglais
  }
ORDER BY ?code #trier les résultats selon le code AITA

Try it!

--Bouzinac (talk) 12:10, 28 July 2018 (UTC)

Try it! --Bouzinac (talk) 12:10, 28 July 2018 (UTC)

Vérifier les aéroports d'un pays et supprimer doublons, nombreux s'ils disposent pas de code IATA/ICAO

SELECT DISTINCT ?airport ?airportLabel WHERE {
  ?airport (wdt:P31/wdt:P279*) wd:Q1248784.
  ?airport ?range wd:Q142.
  filter not exists {?airport wdt:P239 ?icao .}               # there is no ICAO value
  filter not exists {?airport wdt:P238 ?iata .}               # there is no IATA value
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr,de,kk". }
}

Try it!

--Bouzinac (talk) 21:30, 6 August 2018 (UTC)

Try it! --Bouzinac (talk) 21:30, 6 August 2018 (UTC)