Wikidata:Synia:language-lexemesense-index
Jump to navigation
Jump to search
Synia: language lexeme sense
[edit]PREFIX target: <http://www.wikidata.org/entity/Q9035>
SELECT
?description ?descriptionLabel
("#language" AS ?descriptionUrl)
?value ?valueLabel
(CONCAT("#language/", SUBSTR(STR(target:), 32)) AS ?valueUrl)
?wikidata ?wikidataLabel
(CONCAT("https://www.wikidata.org/wiki/", SUBSTR(STR(target:), 32)) AS ?wikidataUrl)
?scholia ?scholiaLabel
(CONCAT("https://scholia.toolforge.org/language/", SUBSTR(STR(target:), 32)) AS ?scholiaUrl)
?ordia ?ordiaLabel
(CONCAT("https://ordia.toolforge.org/language/", SUBSTR(STR(target:), 32)) AS ?ordiaUrl)
WHERE {
BIND(wd:Q34770 AS ?description)
BIND(target: AS ?value)
BIND(wd:Q2013 AS ?wikidata)
BIND(wd:Q45340488 AS ?scholia)
BIND(wd:Q63379419 AS ?ordia)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Senses per lexeme
[edit]PREFIX target: <http://www.wikidata.org/entity/Q9035>
SELECT
?senses_per_lexeme
?lexemes
?example_lexeme ?example_lexemeLabel
(CONCAT("#lexeme/", SUBSTR(STR(?example_lexeme), 32)) AS ?example_lexemeUrl)
WITH {
SELECT
(COUNT(?sense) AS ?senses_per_lexeme)
?lexeme
WHERE {
?lexeme dct:language target: .
OPTIONAL { ?lexeme ontolex:sense ?sense . }
}
GROUP BY ?lexeme
} AS %lexemes
WITH {
SELECT
?senses_per_lexeme
(COUNT(?lexeme) AS ?lexemes)
(SAMPLE(?lexeme) AS ?example_lexeme)
WHERE {
INCLUDE %lexemes
}
GROUP BY ?senses_per_lexeme
} AS %senses
WHERE {
INCLUDE %senses
?example_lexeme wikibase:lemma ?example_lexemeLabel .
}
ORDER BY DESC(?senses_per_lexeme)
Map
[edit]#defaultView:Map
PREFIX target: <http://www.wikidata.org/entity/Q9035>
SELECT
?geo
?location
?lexeme ?lemma
WHERE {
?lexeme wikibase:lemma ?lemma ;
ontolex:sense ?sense ;
dct:language target: .
?sense wdt:P5137 ?location .
?location wdt:P625 ?geo .
}