Wikidata:WikiProject France/Organisations
Cette page du projet France permet d'avancer sur les entreprises et les associations dont le siège est situé en France.
Organisations enregistrées dans la base SIRENE
[edit]Liste des organisations françaises
[edit]# Liste des unités légales du répertoire SIRENE présentes dans Wikidata, avec leur nom et la date de mise à jour
SELECT ?item ?numéroSIREN ?nomSIRENE ?date_miseàjour WHERE {
?item p:P1616 [ps:P1616 ?numéroSIREN; # numéro SIREN de l'unité légale
pq:P1810 ?nomSIRENE; # nom de l'unité légale dans la base SIRENE (typographie originelle)
prov:wasDerivedFrom [ pr:P248 wd:Q3509449 ]; # source : SIRENE
prov:wasDerivedFrom [ pr:P5017 ?date_miseàjour ] # date de mise à jour de l'unité légale dans la base SIRENE
].
}ORDER BY ?numéroSIREN
Champ d'application
[edit]Cette liste comprend les unités légales inscrites au répertoire SIRENE présentes dans Wikidata, dont le numéro SIREN est référencé. Le champ d'application correspond donc à celui du répertoire SIRENE.
Champ d'application géographique :
- Entités basées en France métropolitaine (y compris la Corse) + DROM,
- Entités basées dans les COM Saint-Barthélémy, Saint-Martin et Saint-Pierre-et-Miquelon,
- Entités du secteur public administratif basées dans les COM Nouvelle-Calédonie, Polynésie française et Wallis-et-Futuna,
- Entités étrangères ayant une représentation ou activité en France.
Champ d'application temporel :
- Unités existantes ou créées postérieurement à :
- 1973 pour le secteur privé non agricole,
- 1983 pour le secteur public,
- 1993 pour le secteur privé agricole.
NB : Toutes les données ne sont pas disponibles pour les unités disparues avant 2003.
Champ d'application matériel :
- Unités légales, correspondant aux personnes physiques ou personnes morales de droit public ou privé, déclarées à l'administration française.
Exemple de format
[edit]Pour Wikimedia France (Q8423370) :
| SIREN number |
| ||||||||||||||||
| add value | |||||||||||||||||
Nomenclatures
[edit]- Catégories juridiques : nomenclature des catégories juridiques en France (Q87711223)
- Requêtes : Talk:Q87711223
- Activités : code NAF rév.2 (P10564)
- Requêtes : Property talk:P10564
Par catégorie juridique
[edit]Liste des catégories juridiques
[edit]Source : legal categories in France (Q87711223) Dernière modification : 1er septembre 2022
Exemple de format
[edit]La catégorie juridique est renseignée dans Wikidata par la propriété legal form (P1454).
Pour Wikimedia France (Q8423370) :
| legal form |
| ||||||||||||||||
| add value | |||||||||||||||||
Nombre d'organisations par catégorie juridique
[edit]Liste des organisations par catégorie juridique
[edit]Exemple de la Q98887042, code 5202 :
Liste des éléments à relier à la base Sirene
[edit]SELECT DISTINCT ?organisation ?organisationLabel WHERE {
?organisation (wdt:P31/wdt:P279*) wd:Q6881511.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
?organisation wdt:P17 wd:Q142.
MINUS { ?organisation wdt:P1616 _:b15. }
}
On peut utiliser annuaire entreprises (Q117289096) pour trouver le numéro siren, ou utiliser la réconciliation OpenRefine avec OpenCorporates (utiliser l'URL https://opencorporates.com/reconcile/fr pour restreindre aux entreprises françaises).
Les requêtes suivantes permettent de rechercher dans annuaire entreprises (Q117289096) les firmes situées en France sans code siren (P1616):
#title: List of firms in France without any value for P1616
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?search WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q6881511;
wdt:P17 wd:Q142;
rdfs:label ?itemLabel;
wikibase:sitelinks ?sitelinks.
FILTER((LANG(?itemLabel)) = "fr")
MINUS { ?item wdt:P576 _:b10. }
MINUS { ?item wdt:P1616 _:b11. }
BIND(URI(CONCAT(" https://annuaire-entreprises.data.gouv.fr/rechercher?terme=", ENCODE_FOR_URI(?itemLabel))) AS ?search)
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY DESC (?sitelinks)
Cette requête ajoute le siège et le secteur:
#title: List of firms in France without any value for P1616
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?siegeLabel ?secteurLabel ?search WHERE {
?item (wdt:P31/(wdt:P279*)) wd:Q6881511;
wdt:P17 wd:Q142;
rdfs:label ?itemLabel;
wikibase:sitelinks ?sitelinks.
FILTER((LANG(?itemLabel)) = "fr")
OPTIONAL { ?item wdt:P159 ?siege. }
OPTIONAL { ?item wdt:P452 ?secteur. }
MINUS { ?item wdt:P576 _:b10. }
MINUS { ?item wdt:P1616 _:b11. }
BIND(URI(CONCAT(" https://annuaire-entreprises.data.gouv.fr/rechercher?terme=", ENCODE_FOR_URI(?itemLabel))) AS ?search)
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY DESC (?sitelinks)
Liste des éléments situés en France ayant une valeur pour EU VAT number (P3608) et n'ayant pas de valeur pour SIREN number (P1616). En principe, cette liste devrait être vide.
#title: List of items based in France with a value for P3608 but no value for P1616
SELECT DISTINCT ?organisation ?organisationLabel ?numerotva ?siren ?url WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
?organisation wdt:P17 wd:Q142.
MINUS { ?organisation wdt:P1616 _:b15. }
?organisation wdt:P3608 ?numerotva.
BIND(SUBSTR( ?numerotva, 5, 9 ) AS ?siren)
BIND(URI(CONCAT("https://annuaire-entreprises.data.gouv.fr/entreprise/", ?siren)) AS ?url)
}
Liste des entreprises ayant une valeur de OpenCorporates ID (P1320) mais pas de valeur pour SIREN number (P1616)
#title: List of items based in France with a value for P1320 but no value for P1616
SELECT DISTINCT ?organisation ?organisationLabel ?opencorporates ?siren ?url WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
?organisation wdt:P17 wd:Q142.
MINUS { ?organisation wdt:P1616 _:b15. }
?organisation wdt:P1320 ?opencorporates.
BIND(SUBSTR(?opencorporates, 4 , 9 ) AS ?siren)
BIND(URI(CONCAT("https://annuaire-entreprises.data.gouv.fr/entreprise/", ?siren)) AS ?url)
}
Types d'organisations particuliers
[edit]Entreprises
[edit]Pour les entreprises, on peut aussi se référer au WikiProject Companies.
Liste des entreprises françaises
[edit]SELECT ?organisation ?organisationLabel ?siren WHERE {
?organisation (wdt:P31/wdt:P279*) wd:Q6881511.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
?organisation wdt:P17 wd:Q142.
OPTIONAL {?organisation wdt:P1616 ?siren.}
}
Associations
[edit]Cf. Wikidata:WikiProject France/Organisations/Associations
Administrations
[edit]Cf. Wikidata:WikiProject France/Administrations
Ressources
[edit]Le répertoire SIRENE est administré par l'INSEE et publié sur le site sirene.fr en open data, accessible suivant quatre modalités différentes :
- moteur de recherche sur sirene.fr
- téléchargement de la base de données complètes sur data.gouv.fr
- création d'un fichier personnalisé sur sirene.fr
- interrogation par l'API de l'INSEE sur api.insee.fr
Le registre national des entreprises (RNE) est administré par l'INPI et publié sur le site inpi.fr en open data, accessible suivant deux modalités différentes :
- moteur de recherche sur data.inpi.fr
- interrogation par l'API de l'INPI sur data.inpi.fr
Les données de la base SIRENE et du RNE sont réutilisées par l'Annuaire des entreprises, administré par la Direction interministérielle du numérique (DINUM), publié sur data.gouv.fr, qui est utilisé comme URL pour la propriété SIREN number (P1616).
De nombreux services en ligne privés réutilisent les données publiques SIRENE et RNE, parmi lesquels :
- BFM verif
- entreprises.lefigaro.fr
- Legaltile
- Manageo
- OpenCorporates
- Pappers
- societe.com
- societe.ninja