Wikidata:WikiProject Humanitarian Wikidata/Recent disasters
Jump to navigation
Jump to search
See also similar information from specialized sites e.g. USGS on recent earthquakes or International Best Track Archive for Climate Stewardship (IBTrACS) on recent storms.
Map
[edit]The following query uses these:
- Items: disaster (Q3839081)
, conflict (Q180684) , crime (Q83267)
- Properties: instance of (P31) , subclass of (P279) , point in time (P585) , start time (P580) , coordinate location (P625) , image (P18)
Features: map (Q24515275) 
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?image ?date ?geo ?type ?typeLabel WHERE {
# find items of some type ...
?item wdt:P31 ?type.
# ... where the type is a subclass of disaster, conflict or crime ...
{ ?type (wdt:P279*) wd:Q3839081. }
UNION
{ ?type (wdt:P279*) wd:Q180684. }
UNION
{ ?type (wdt:P279*) wd:Q83267. }
# ... with a point in time or start date ...
?item (wdt:P585|wdt:P580) ?date.
# ... not more than 1 day in the future (allowing for time zone differences) and not more than 90 days ago
BIND(NOW() - ?date AS ?distance).
FILTER(-1 <= ?distance && ?distance < 90).
# Fetch the item's position, label and image
?item wdt:P625 ?geo.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?item wdt:P18 ?image. }
}
List
[edit]This list is periodically updated by a bot. Manual changes to the list will be removed on the next update!
WDQS | PetScan | TABernacle | Find images | Recent changes | Query:SELECT DISTINCT ?item ?date WHERE { # find items of some type ... ?item wdt:P31 ?type. # ... where the type is a subclass of disaster, conflict or crime ... { ?type (wdt:P279*) wd:Q3839081. } UNION { ?type (wdt:P279*) wd:Q180684. } UNION { ?type (wdt:P279*) wd:Q83267. } # ... with a point in time or start date ... ?item (wdt:P585|wdt:P580) ?date. # ... not more than 1 day in the future (allowing for time zone differences) and not more than 90 days ago BIND(NOW() - ?date AS ?distance). FILTER(-1 <= ?distance && ?distance < 90). } # newest first ORDER BY DESC(?date) # limit to 50 results in case there are more LIMIT 50
.png)
.jpg)
.webp)
.jpg)
∑ 49 items.
End of automatically generated list.