Wikidata:WikiProject India/Tasks
Jump to navigation
Jump to search
These are a list of pending tasks related to India to be worked on. Each of these tasks is a different query that should ideally be empty.
| People who died before independence of India but erroneously tagged as citizen of Republic of India |
|---|
# People who died before independence of India but erroneously tagged as citizen of Republic of India
SELECT ?item ?itemLabel ?deathLabel
WHERE
{
?item wdt:P31 wd:Q5 . # all humans
?item wdt:P27 wd:Q668. # tagged as Indian citizen
?item wdt:P570 ?death. # who died
FILTER (?death <= "1947-08-16T00:00:00Z"^^xsd:dateTime) . # before 16 August 1947
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,bn,hi,mr,gu,pa,ta,te,ml,as,or".}
}
ORDER BY (?deathLabel)
|
| #All cities and towns of India without an STD code mentioned |
|---|
#All cities and towns of India without an STD code mentioned
SELECT ?object ?objectLabel ?coord
WHERE {
?object wdt:P17 wd:Q668. #India
?object wdt:P31/wdt:P279* wd:Q486972. #Human settlement
{?object wdt:P31/wdt:P279* wd:Q515.} UNION {?object wdt:P31/wdt:P279* wd:Q3957.} #Cities and towns. Add more categories, as needed
#?object wdt:P625 ?coord. #Location has coordinates. Not necessary yet
MINUS {?object wdt:P473 ?localcode.} #Does not have an STD code mentioned
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
|
| #All cities and towns of India without a coordinate mentioned |
|---|
#All cities and towns of India without a coordinate mentioned
SELECT ?object ?objectLabel ?coord
WHERE {
?object wdt:P17 wd:Q668. #India
?object wdt:P31/wdt:P279* wd:Q486972. #Human settlement
{?object wdt:P31/wdt:P279* wd:Q515.} UNION {?object wdt:P31/wdt:P279* wd:Q3957.} #Cities and towns. Add more categories, as needed
MINUS {?object wdt:P625 ?coord.} #Filter out all Location that has coordinates.
#MINUS {?object wdt:P473 ?localcode.} #Does not have an STD code mentioned. Not necessary yet
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
|
| #All different human settlements in India that are also in another country |
|---|
#All different human settlements in India that are also in another country
SELECT ?object ?objectLabel ?country ?countryLabel ?country2 ?country2Label
WHERE {
?object wdt:P17 ?country.
?object wdt:P17 ?country2.
FILTER(STR(?country2) != STR(?country)) #Different countries
FILTER(STR(?country) = STR(wd:Q668)) #India
#MINUS { ?country wdt:P582|wdt:P576 ?ended. }
#MINUS { ?country2 wdt:P582|wdt:P576 ?ended. }
?object wdt:P31/wdt:P279* wd:Q486972. #Human settlements
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
|