Wikidata:WikiProject West Bengal/Queries

Click on [Expand] to see code. Feel free to add interesting queries related to West Bengal (Q1356).

Map showing location of graves in Dutch Cemetery, Chinsurah

Items used: Dutch Cemetery (Q29032413)

Properties used: place of burial (P119)   , image of grave (P1442)   , burial plot reference (P965)   , coordinate location (P625)   , Commons category (P373)

Features used: map (Q24515275)

#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?causeDeathLabel ?graveplot ?coord ?imgGrave ?commonscat ?img WHERE {
  ?item wdt:P119 wd:Q29032413.
  ?item p:P119 ?placeofBurial.
  OPTIONAL {?item wdt:P1442 ?imgGrave. }
  OPTIONAL { ?placeofBurial pq:P965 ?graveplot. }
  OPTIONAL { ?placeofBurial pq:P625 ?coord. }
  OPTIONAL { ?placeofBurial pq:P373 ?commonscat. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Bengali Wikisource authors without any Bengali Wikipedia articles

Items used: human (Q5)

Properties used: instance of (P31)

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P31 wd:Q5 .
    [] schema:about ?item; schema:isPartOf <https://bn.wikisource.org/>; schema:name ?ws .
    MINUS { [] schema:about ?item; schema:isPartOf <https://bn.wikipedia.org/> }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "bn,en". }
  }

Try it!

Citizens of India who do not have labels in Bengali

Items used: human (Q5)   , India (Q668)

Properties used: instance of (P31)   , country of citizenship (P27)

#Missing labels in Bengali
#Search for labels in other languages that do not exist in Bangla
#Can be input for QuickStatements
SELECT ?item ?itemLabel ?itemDescription WHERE {
 ?item wdt:P31 wd:Q5.  #instance of human
 ?item wdt:P27 wd:Q668. #country of citizenship India

 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,hi,ne,as,mai,mr,pa,or,ml,te,ta,kn,". }
 FILTER(NOT EXISTS {
   ?item rdfs:label ?lang_label.
   FILTER(LANG(?lang_label) = "bn") #with missing Bangla label
 })
}
ORDER BY DESC(?itemLabel)

Try it!

Bengali Wikisource Authors who do not have occupation "writer"

Items used: human (Q5)

Properties used: instance of (P31)   , occupation (P106)

SELECT
 ?item ?itemLabel ?itemDescription ?occupationLabel
       WHERE {
         ?item wdt:P31 wd:Q5.
               FILTER NOT EXISTS { ?item wdt:P106 ?occupation . }
         ?article schema:about ?item.
         ?article schema:isPartOf <https://bn.wikisource.org/>.
         SERVICE wikibase:label { bd:serviceParam wikibase:language "bn,en".}
         }

Try it!

List of validated works in Bengali Wikisource

Items used: validated (Q20748093)

SELECT
  ?item ?itemLabel ?siteLink
       WHERE {
         ?siteLink schema:about ?item;
         schema:isPartOf <https://bn.wikisource.org/>;
         wikibase:badge wd:Q20748093.
         SERVICE wikibase:label { bd:serviceParam wikibase:language "bn,en".}
         }

Try it!

Image grid of sculptures in Indian Museum, Kolkata

Items used: sculpture (Q860861)   , Indian Museum (Q1364900)

Properties used: instance of (P31)   , location (P276)   , image (P18)   , inventory number (P217)

Features used: ImageGrid (Q24515278)

#defaultView:ImageGrid
SELECT ?item ?itemLabel ?image ?inventoryno WHERE {
  ?item wdt:P31 wd:Q860861.
  ?item wdt:P276 wd:Q1364900.
  OPTIONAL { ?item wdt:P18 ?image. }
  OPTIONAL { ?item wdt:P217 ?inventoryno. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

}

Try it!

Map showing ASI protected monuments in West Bengal

Items used: Monument of National Importance (Q17047615)   , West Bengal (Q1356)

Properties used: heritage designation (P1435)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , image (P18)   , ASI Monument ID (P1371)

Features used: map (Q24515275)

#defaultView:Map
SELECT ?item ?itemLabel ?location ?coord ?img WHERE {
  ?item wdt:P1435 wd:Q17047615.
  ?item wdt:P131 ?location.
    ?location wdt:P131 wd:Q1356.
  OPTIONAL { ?item wdt:P625 ?coord. }
  OPTIONAL { ?item wdt:P18 ?img. }
  OPTIONAL { ?item wdt:P1371 ?ASI_Monument_ID. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Map showing railway stations in West Bengal connected via railroad lines

Items used: railway station (Q55488)   , West Bengal (Q1356)   , India (Q668)   , Indian Railways (Q819425)

Properties used: instance of (P31)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , image (P18)   , Indian Railways station code (P5696)   , owned by (P127)   , adjacent station (P197)   , connecting line (P81)

Features used: map (Q24515275)

#defaultView:Map{"hide":["?coordinates", "?line", "?rgb"]}
SELECT DISTINCT ?coordinates ?line ?item ?itemLabel ?connectLabel ?image ?code ?rgb

WITH {
  SELECT ?item (SAMPLE(?coordinates) AS ?coordinates) (SAMPLE(?image) AS ?image) (sample(?lat1) as ?lat1) (sample(?lon1) as ?lon1) (sample(?code) as ?code) WHERE {
    ?item wdt:P31 wd:Q55488.
    ?item wdt:P131* wd:Q1356  .
    ?item wdt:P625 ?coordinates  .
    ?item p:P625 / psv:P625 / wikibase:geoLatitude ?lat1 .
    ?item p:P625 / psv:P625 / wikibase:geoLongitude ?lon1 .
    OPTIONAL { ?item wdt:P18 ?image }.
    OPTIONAL { ?item wdt:P5696 ?code }.
  } GROUP BY ?item
} AS %stations

WITH {
  SELECT ?nextstation (sample(?lat2) as ?lat2) (sample(?lon2) as ?lon2) WHERE {
    ?nextstation wdt:P31 wd:Q55488 .
    ?nextstation wdt:P131* wd:Q668 .
    ?nextstation p:P625 / psv:P625 / wikibase:geoLatitude ?lat2 .
    ?nextstation p:P625 / psv:P625 / wikibase:geoLongitude ?lon2 .
  } GROUP BY ?nextstation
} AS %nextstations

WITH {
  SELECT ?line ?connect ("9B0058" as ?rgb) WHERE {
    INCLUDE %stations .
    INCLUDE %nextstations .
    ?item p:P197 ?nextstationstatement .
    ?nextstationstatement ps:P197 ?nextstation .
    ?nextstationstatement pq:P81 ?connect . ?connect wdt:P127 wd:Q819425  . 
    FILTER(STR(?item) < STR(?nextstation)) .    
    BIND(CONCAT('LINESTRING (', STR(?lon1), ' ', STR(?lat1), ',', STR(?lon2), ' ', STR(?lat2), ')') AS ?str) .
    BIND(STRDT(?str, geo:wktLiteral) AS ?line) 
  }
} AS %lines 
 
WHERE {
  { INCLUDE %stations }  UNION { INCLUDE %lines  } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Bubble chart showing population growth in community development blocks of Medinipur subdivision between 2001 and 2011

Items used: community development block in India (Q2775236)   , Medinipur division (Q29289380)

Properties used: instance of (P31)   , located in the administrative territorial entity (P131)   , population (P1082)   , point in time (P585)

Features used: BubbleChart (Q24515280)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

#defaultView:BubbleChart
#?fbclid=IwAR1KBWqLU5J2-SJ3jj8Jfc7PxnXgTNXUkofDcSPM9CvstaiVo22xFYtpD_Q
SELECT DISTINCT ?vLabel ?pop WHERE {
  ?v wdt:P31 wd:Q2775236.
  ?v wdt:P131* wd:Q29289380.
  ?v p:P1082 ?popStmt2011.
  ?popStmt2011 ps:P1082 ?pop2011.
  ?popStmt2011 pq:P585 "+2011-01-01T00:00:00Z"^^xsd:dateTime.
  ?v p:P1082 ?popStmt2001.
  ?popStmt2001 ps:P1082 ?pop2001.
  ?popStmt2001 pq:P585 "+2001-01-01T00:00:00Z"^^xsd:dateTime.
  BIND((xsd:integer(?pop2011)) - (xsd:integer(?pop2001)) AS ?change)
  BIND(IF(?change > 0, ?change, 0) AS ?pop)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "bn,en". }
}
GROUP BY ?pop ?vLabel
ORDER BY DESC(?pop)

Try it!

Tree Map showing districts, sub-divisions and sub-districts in Medinipur division

Items used: Medinipur division (Q29289380)   , Purulia district (Q307474)   , subdivision of West Bengal (Q13058507)   , Purba Medinipur district (Q1431920)   , Paschim Medinipur district (Q1855537)   , Bankura district (Q2088458)   , Jhargram district (Q29168456)   , community development block in India (Q2775236)   , municipality of West Bengal (Q18918041)   , cantonment town (Q57178953)   , industrial township (Q57179730)

Properties used: located in the administrative territorial entity (P131)   , instance of (P31)

#defaultView:TreeMap
SELECT ?div ?divLabel ?dis ?disLabel ?sdiv ?sdivLabel ?cdb ?cdbLabel
{
  BIND(wd:Q29289380 as ?div).
  {BIND(wd:Q307474 as ?dis). ?sdiv wdt:P131 ?dis . ?cdb wdt:P131 ?sdiv . ?sdiv wdt:P31 wd:Q13058507 . ?cdb wdt:P31 ?entity .}
  UNION
  {BIND(wd:Q1431920 as ?dis). ?sdiv wdt:P131 ?dis . ?cdb wdt:P131 ?sdiv . ?sdiv wdt:P31 wd:Q13058507 . ?cdb wdt:P31 ?entity .}
  UNION
  {BIND(wd:Q1855537 as ?dis). ?sdiv wdt:P131 ?dis . ?cdb wdt:P131 ?sdiv . ?sdiv wdt:P31 wd:Q13058507 . ?cdb wdt:P31 ?entity .}
  UNION
  {BIND(wd:Q2088458 as ?dis). ?sdiv wdt:P131 ?dis . ?cdb wdt:P131 ?sdiv . ?sdiv wdt:P31 wd:Q13058507 . ?cdb wdt:P31 ?entity .}
  UNION
  {BIND(wd:Q29168456 as ?dis). ?sdiv wdt:P131 ?dis . ?cdb wdt:P131 ?sdiv . ?sdiv wdt:P31 wd:Q13058507 . ?cdb wdt:P31 ?entity .}
  SERVICE wikibase:label {  bd:serviceParam wikibase:language "bn,en" }
}
VALUES (?cdbLabel ?entity) {(UNDEF wd:Q2775236) (UNDEF wd:Q18918041) (UNDEF wd:Q57178953) (UNDEF wd:Q57179730)}
#

Try it!

Map showing villages of Paschim Medinipur district with relation to the nearest railway station

Items used: village in India (Q56436498)   , India (Q668)   , Paschim Medinipur district (Q1855537)

Properties used: instance of (P31)   , country (P17)   , located in the administrative territorial entity (P131)   , coordinate location (P625)

Features used: map (Q24515275)

#created by Mahir256
#defaultView:Map
SELECT ?i ?iLabel (SAMPLE(?cds_) as ?cds) (CEIL(MIN(?dist)) as ?layer) {
  ?i wdt:P31 wd:Q56436498 ; wdt:P17 wd:Q668 ; wdt:P131/wdt:P131/wdt:P131 wd:Q1855537 ; wdt:P625

Try it!

Every places within 1 km of every railway stations in West Bengal

Items used: railway station (Q55488)   , India (Q668)   , West Bengal (Q1356)

Properties used: instance of (P31)   , country (P17)   , located in the administrative territorial entity (P131)   , coordinate location (P625)

Features used: map (Q24515275)

#created by Mahir256
#defaultView:Map
SELECT ?v ?vLabel ?location ?layer {
  ?i wdt:P31 wd:Q55488 ; wdt:P17 wd:Q668 ; wdt:P131/wdt:P131* wd:Q1356 ; wdt:P625 ?cds.
  SERVICE wikibase:around {
      ?v wdt:P625 ?location .
      bd:serviceParam wikibase:center ?cds .
      bd:serviceParam wikibase:radius "1" .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "bn,en". ?i rdfs:label ?layer. ?v rdfs:label ?vLabel }
}

Try it!

Wikidata:WikiProject West Bengal/Queries

Navigation menu

Search